stzscal.f

Go to the documentation of this file.

      SUBROUTINE stzscal( UPLO, M, N, IOFFD, ALPHA, A, LDA )
*
*  -- PBLAS auxiliary routine (version 2.0) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     April 1, 1998
*
*     .. Scalar Arguments ..
      CHARACTER*1        UPLO
      INTEGER            IOFFD, LDA, M, N
      REAL               ALPHA
*     ..
*     .. Array Arguments ..
      REAL               A( LDA, * )
*     ..
*
*  Purpose
*  =======
*
*  STZSCAL scales a two-dimensional array A by the scalar alpha.
*
*  Arguments
*  =========
*
*  UPLO    (input) CHARACTER*1
*          On entry,  UPLO  specifies  which trapezoidal part of the ar-
*          ray A is to be scaled as follows:
*             = 'L' or 'l':          the lower trapezoid of A is scaled,
*             = 'U' or 'u':          the upper trapezoid of A is scaled,
*             = 'D' or 'd':       diagonal specified by IOFFD is scaled,
*             Otherwise:                   all of the array A is scaled.
*
*  M       (input) INTEGER
*          On entry,  M  specifies the number of rows of the array A.  M
*          must be at least zero.
*
*  N       (input) INTEGER
*          On entry,  N  specifies the number of columns of the array A.
*          N must be at least zero.
*
*  IOFFD   (input) INTEGER
*          On entry, IOFFD specifies the position of the offdiagonal de-
*          limiting the upper and lower trapezoidal part of A as follows
*          (see the notes below):
*
*             IOFFD = 0  specifies the main diagonal A( i, i ),
*                        with i = 1 ... MIN( M, N ),
*             IOFFD > 0  specifies the subdiagonal   A( i+IOFFD, i ),
*                        with i = 1 ... MIN( M-IOFFD, N ),
*             IOFFD < 0  specifies the superdiagonal A( i, i-IOFFD ),
*                        with i = 1 ... MIN( M, N+IOFFD ).
*
*  ALPHA   (input) REAL
*          On entry,  ALPHA  specifies the scalar alpha, i.e., the value
*          by which the diagonal and offdiagonal entries of the array  A
*          as specified by UPLO and IOFFD are scaled.
*
*  A       (input/output) REAL array
*          On entry, A is an array of dimension  (LDA,N).  Before  entry
*          with  UPLO = 'U' or 'u', the leading m by n part of the array
*          A must contain the upper trapezoidal  part  of the matrix  as
*          specified by  IOFFD to be scaled, and the strictly lower tra-
*          pezoidal part of A is not referenced; When UPLO = 'L' or 'l',
*          the leading m by n part of the array A must contain the lower
*          trapezoidal  part  of  the matrix as specified by IOFFD to be
*          scaled,  and  the strictly upper trapezoidal part of A is not
*          referenced. On exit, the entries of the  trapezoid part of  A
*          determined by UPLO and IOFFD are scaled.
*
*  LDA     (input) INTEGER
*          On entry, LDA specifies the leading dimension of the array A.
*          LDA must be at least max( 1, M ).
*
*  Notes
*  =====
*                           N                                    N
*             ----------------------------                  -----------
*            |       d                    |                |           |
*          M |         d        'U'       |                |      'U'  |
*            |  'L'     'D'               |                |d          |
*            |             d              |              M |  d        |
*             ----------------------------                 |   'D'     |
*                                                          |      d    |
*               IOFFD < 0                                  | 'L'    d  |
*                                                          |          d|
*                  N                                       |           |
*             -----------                                   -----------
*            |    d   'U'|
*            |      d    |                                   IOFFD > 0
*          M |       'D' |
*            |          d|                              N
*            |  'L'      |                 ----------------------------
*            |           |                |          'U'               |
*            |           |                |d                           |
*            |           |                | 'D'                        |
*            |           |                |    d                       |
*            |           |                |'L'   d                     |
*             -----------                  ----------------------------
*
*  -- Written on April 1, 1998 by
*     Antoine Petitet, University  of  Tennessee, Knoxville 37996, USA.
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ONE, ZERO
      parameter( one = 1.0e+0, zero = 0.0e+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            J, JTMP, MN
*     ..
*     .. External Subroutines ..
      EXTERNAL           sscal, stzpad
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      EXTERNAL           lsame
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min
*     ..
*     .. Executable Statements ..
*
*     Quick return if possible
*
      IF( ( m.LE.0 ).OR.( n.LE.0 ).OR.( alpha.EQ.one ) )
     $   RETURN
*
*     Start the operations
*
      IF( alpha.EQ.zero ) THEN
         CALL stzpad( uplo, 'N', m, n, ioffd, zero, zero, a, lda )
         RETURN
      END IF
*
      IF( lsame( uplo, 'L' ) ) THEN
*
*        Scales the lower triangular part of the array by ALPHA.
*
         mn = max( 0, -ioffd )
         DO 10 j = 1, min( mn, n )
            CALL sscal( m, alpha, a( 1, j ), 1 )
   10    CONTINUE
         DO 20 j = mn + 1, min( m - ioffd, n )
            jtmp = j + ioffd
            IF( m.GE.jtmp )
     $         CALL sscal( m-jtmp+1, alpha, a( jtmp, j ), 1 )
   20    CONTINUE
*
      ELSE IF( lsame( uplo, 'U' ) ) THEN
*
*        Scales the upper triangular part of the array by ALPHA.
*
         mn = min( m - ioffd, n )
         DO 30 j = max( 0, -ioffd ) + 1, mn
            CALL sscal( j + ioffd, alpha, a( 1, j ), 1 )
   30    CONTINUE
         DO 40 j = max( 0, mn ) + 1, n
            CALL sscal( m, alpha, a( 1, j ), 1 )
   40    CONTINUE
*
      ELSE IF( lsame( uplo, 'D' ) ) THEN
*
*        Scales the diagonal entries by ALPHA.
*
         DO 50 j = max( 0, -ioffd ) + 1, min( m - ioffd, n )
            jtmp = j + ioffd
            a( jtmp, j ) = alpha * a( jtmp, j )
   50    CONTINUE
*
      ELSE
*
*        Scales the entire array by ALPHA.
*
         DO 60 j = 1, n
            CALL sscal( m, alpha, a( 1, j ), 1 )
   60    CONTINUE
*
      END IF
*
      RETURN
*
*     End of STZSCAL
*
      END