pdsytdrv.f

Go to the documentation of this file.

      SUBROUTINE pdsytdrv( UPLO, N, A, IA, JA, DESCA, D, E, TAU, WORK,
     $                     INFO )
*
*  -- ScaLAPACK routine (version 1.7) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     May 1, 1997
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            IA, INFO, JA, N
*     ..
*     .. Array Arguments ..
      INTEGER            DESCA( * )
      DOUBLE PRECISION   A( * ), D( * ), E( * ), TAU( * ), WORK( * )
*     ..
*
*  Purpose
*  =======
*
*  PDSYTDRV computes sub( A ) = A(IA:IA+N-1,JA:JA+N-1) from Q, the
*  symmetric tridiagonal matrix T (or D and E), and TAU, which were
*  computed by PDSYTRD:  sub( A ) := Q * T * Q'.
*
*  Notes
*  =====
*
*  Each global data object is described by an associated description
*  vector.  This vector stores the information required to establish
*  the mapping between an object element and its corresponding process
*  and memory location.
*
*  Let A be a generic term for any 2D block cyclicly distributed array.
*  Such a global array has an associated description vector DESCA.
*  In the following comments, the character _ should be read as
*  "of the global array".
*
*  NOTATION        STORED IN      EXPLANATION
*  --------------- -------------- --------------------------------------
*  DTYPE_A(global) DESCA( DTYPE_ )The descriptor type.  In this case,
*                                 DTYPE_A = 1.
*  CTXT_A (global) DESCA( CTXT_ ) The BLACS context handle, indicating
*                                 the BLACS process grid A is distribu-
*                                 ted over. The context itself is glo-
*                                 bal, but the handle (the integer
*                                 value) may vary.
*  M_A    (global) DESCA( M_ )    The number of rows in the global
*                                 array A.
*  N_A    (global) DESCA( N_ )    The number of columns in the global
*                                 array A.
*  MB_A   (global) DESCA( MB_ )   The blocking factor used to distribute
*                                 the rows of the array.
*  NB_A   (global) DESCA( NB_ )   The blocking factor used to distribute
*                                 the columns of the array.
*  RSRC_A (global) DESCA( RSRC_ ) The process row over which the first
*                                 row of the array A is distributed.
*  CSRC_A (global) DESCA( CSRC_ ) The process column over which the
*                                 first column of the array A is
*                                 distributed.
*  LLD_A  (local)  DESCA( LLD_ )  The leading dimension of the local
*                                 array.  LLD_A >= MAX(1,LOCr(M_A)).
*
*  Let K be the number of rows or columns of a distributed matrix,
*  and assume that its process grid has dimension p x q.
*  LOCr( K ) denotes the number of elements of K that a process
*  would receive if K were distributed over the p processes of its
*  process column.
*  Similarly, LOCc( K ) denotes the number of elements of K that a
*  process would receive if K were distributed over the q processes of
*  its process row.
*  The values of LOCr() and LOCc() may be determined via a call to the
*  ScaLAPACK tool function, NUMROC:
*          LOCr( M ) = NUMROC( M, MB_A, MYROW, RSRC_A, NPROW ),
*          LOCc( N ) = NUMROC( N, NB_A, MYCOL, CSRC_A, NPCOL ).
*  An upper bound for these quantities may be computed by:
*          LOCr( M ) <= ceil( ceil(M/MB_A)/NPROW )*MB_A
*          LOCc( N ) <= ceil( ceil(N/NB_A)/NPCOL )*NB_A
*
*  Arguments
*  =========
*
*  UPLO    (global input) CHARACTER
*          Specifies whether the upper or lower triangular part of the
*          symmetric matrix sub( A ) is stored:
*          = 'U':  Upper triangular
*          = 'L':  Lower triangular
*
*  N       (global input) INTEGER
*          The number of rows and columns to be operated on, i.e. the
*          order of the distributed submatrix sub( A ). N >= 0.
*
*  A       (local input/local output) DOUBLE PRECISION pointer into the
*          local memory to an array of dimension (LLD_A,LOCc(JA+N-1)).
*          This array contains the local pieces of sub( A ). On entry,
*          if UPLO='U', the diagonal and first superdiagonal of sub( A )
*          have the corresponding elements of the tridiagonal matrix T,
*          and the elements above the first superdiagonal, with the
*          array TAU, represent the orthogonal matrix Q as a product of
*          elementary reflectors, and the strictly lower triangular part
*          of sub( A ) is not referenced. If UPLO='L', the diagonal and
*          first subdiagonal of sub( A ) have the corresponding elements
*          of the tridiagonal matrix T, and the elements below the first
*          subdiagonal, with the array TAU, represent the orthogonal
*          matrix Q as a product of elementary reflectors, and the
*          strictly upper triangular part of sub( A ) is not referenced.
*          On exit, if UPLO = 'U', the upper triangular part of the
*          distributed symmetric matrix sub( A ) is recovered.
*          If UPLO='L', the lower triangular part of the distributed
*          symmetric matrix sub( A ) is recovered.
*
*  IA      (global input) INTEGER
*          The row index in the global array A indicating the first
*          row of sub( A ).
*
*  JA      (global input) INTEGER
*          The column index in the global array A indicating the
*          first column of sub( A ).
*
*  DESCA   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix A.
*
*  D       (local input) DOUBLE PRECISION array, dimension LOCc(JA+N-1)
*          The diagonal elements of the tridiagonal matrix T:
*          D(i) = A(i,i). D is tied to the distributed matrix A.
*
*  E       (local input) DOUBLE PRECISION array, dimension LOCc(JA+N-1)
*          if UPLO = 'U', LOCc(JA+N-2) otherwise. The off-diagonal
*          elements of the tridiagonal matrix T: E(i) = A(i,i+1) if
*          UPLO = 'U', E(i) = A(i+1,i) if UPLO = 'L'. E is tied to the
*          distributed matrix A.
*
*  TAU     (local input) DOUBLE PRECISION, array, dimension
*          LOCc(JA+N-1). This array contains the scalar factors TAU of
*          the elementary reflectors. TAU is tied to the distributed
*          matrix A.
*
*  WORK    (local workspace) DOUBLE PRECISION array, dimension (LWORK)
*          LWORK >= 2 * NB *( NB + NP )
*
*          where NB = MB_A = NB_A,
*          NP = NUMROC( N, NB, MYROW, IAROW, NPROW ),
*          IAROW = INDXG2P( IA, NB, MYROW, RSRC_A, NPROW ).
*
*          INDXG2P and NUMROC are ScaLAPACK tool functions;
*          MYROW, MYCOL, NPROW and NPCOL can be determined by calling
*          the subroutine BLACS_GRIDINFO.
*
*  INFO    (global output) INTEGER
*          On exit, if INFO <> 0, a discrepancy has been found between
*          the diagonal and off-diagonal elements of A and the copies
*          contained in the arrays D and E.
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            BLOCK_CYCLIC_2D, CSRC_, CTXT_, DLEN_, DTYPE_,
     $                   lld_, mb_, m_, nb_, n_, rsrc_
      parameter( block_cyclic_2d = 1, dlen_ = 9, dtype_ = 1,
     $                     ctxt_ = 2, m_ = 3, n_ = 4, mb_ = 5, nb_ = 6,
     $                     rsrc_ = 7, csrc_ = 8, lld_ = 9 )
      DOUBLE PRECISION   EIGHT, HALF, ONE, ZERO
      parameter( eight = 8.0d+0, half = 0.5d+0, one = 1.0d+0,
     $                     zero = 0.0d+0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            UPPER
      INTEGER            I, IACOL, IAROW, ICTXT, II, IPT, IPV, IPX,
     $                   ipy, j, jb, jj, jl, k, mycol, myrow, nb, np,
     $                   npcol, nprow
      DOUBLE PRECISION   ADDBND, D1, D2, E1, E2
*     ..
*     .. Local Arrays ..
      INTEGER            DESCD( DLEN_ ), DESCE( DLEN_ ), DESCV( DLEN_ ),
     $                   desct( dlen_ )
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      INTEGER            INDXG2P, NUMROC
      DOUBLE PRECISION   PDLAMCH
      EXTERNAL           indxg2p, lsame, numroc, pdlamch
*     ..
*     .. External Subroutines ..
      EXTERNAL           blacs_gridinfo, descset, infog2l, igsum2d,
     $                   pdelget, pdgemm, pdlacpy,
     $                   pdlarft, pdlaset, pdsymm,
     $                   pdsyr2k, pdtrmm
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, max, min, mod
*     ..
*     .. Executable statements ..
*
      ictxt = desca( ctxt_ )
      CALL blacs_gridinfo( ictxt, nprow, npcol, myrow, mycol )
*
      info = 0
      nb = desca( mb_ )
      upper = lsame( uplo, 'U' )
      CALL infog2l( ia, ja, desca, nprow, npcol, myrow, mycol, ii, jj,
     $              iarow, iacol )
      np = numroc( n, nb, myrow, iarow, nprow )
*
      ipt = 1
      ipv = nb * nb + ipt
      ipx = nb * np + ipv
      ipy = nb * np + ipx
*
      CALL descset( descd, 1, ja+n-1, 1, desca( nb_ ), myrow,
     $              desca( csrc_ ), desca( ctxt_ ), 1 )
*
      addbnd = eight * pdlamch( ictxt, 'eps' )
*
      IF( upper ) THEN
*
         CALL descset( desce, 1, ja+n-1, 1, desca( nb_ ), myrow,
     $                 desca( csrc_ ), desca( ctxt_ ), 1 )
*
         DO 10 j = 0, n-1
            d1 = zero
            e1 = zero
            d2 = zero
            e2 = zero
            CALL pdelget( ' ', ' ', d2, d, 1, ja+j, descd )
            CALL pdelget( 'Columnwise', ' ', d1, a, ia+j, ja+j, desca )
            IF( j.LT.(n-1) ) THEN
               CALL pdelget( ' ', ' ', e2, e, 1, ja+j+1, desce )
               CALL pdelget( 'Columnwise', ' ', e1, a, ia+j, ja+j+1,
     $                       desca )
            END IF
*
            IF( ( abs( d1 - d2 ).GT.( abs( d2 ) * addbnd ) ) .OR.
     $          ( abs( e1 - e2 ).GT.( abs( e2 ) * addbnd ) ) )
     $         info = info + 1
   10    CONTINUE
*
*        Compute the upper triangle of sub( A ).
*
         CALL descset( descv, n, nb, nb, nb, iarow, iacol, ictxt,
     $                 max( 1, np ) )
         CALL descset( desct, nb, nb, nb, nb, iarow, iacol, ictxt, nb )
*
         DO 20 k = 0, n-1, nb
            jb = min( nb, n-k )
            i = ia + k
            j = ja + k
*
*           Compute the lower triangular matrix T.
*
            CALL pdlarft( 'Backward', 'Columnwise', k+jb-1, jb, a, ia,
     $                    j, desca, tau, work( ipt ), work( ipv ) )
*
*           Copy Householder vectors into WORK( IPV ).
*
            CALL pdlacpy( 'All', k+jb-1, jb, a, ia, j, desca,
     $                    work( ipv ), 1, 1, descv )
*
            IF( k.GT.0 ) THEN
               CALL pdlaset( 'Lower', jb+1, jb, zero, one, work( ipv ),
     $                       k, 1, descv )
            ELSE
               CALL pdlaset( 'Lower', jb, jb-1, zero, one, work( ipv ),
     $                       1, 2, descv )
               CALL pdlaset( 'Ge', jb, 1, zero, zero, work( ipv ), 1,
     $                       1, descv )
            END IF
*
*           Zero out the strict upper triangular part of A.
*
            IF( k.GT.0 ) THEN
               CALL pdlaset( 'Ge', k-1, jb, zero, zero, a, ia, j,
     $                       desca )
               CALL pdlaset( 'Upper', jb-1, jb-1, zero, zero, a, i-1,
     $                       j+1, desca )
            ELSE IF( jb.GT.1 ) THEN
               CALL pdlaset( 'Upper', jb-2, jb-2, zero, zero, a, ia,
     $                       j+2, desca )
            END IF
*
*           (1) X := A * V * T'
*
            CALL pdsymm( 'Left', 'Upper', k+jb, jb, one, a, ia, ja,
     $                   desca, work( ipv ), 1, 1, descv, zero,
     $                   work( ipx ), 1, 1, descv )
            CALL pdtrmm( 'Right', 'Lower', 'Transpose', 'Non-Unit',
     $                   k+jb, jb, one, work( ipt ), 1, 1, desct,
     $                   work( ipx ), 1, 1, descv )
*
*           (2) X := X - 1/2 * V * (T * V' * X)
*
            CALL pdgemm( 'Transpose', 'No transpose', jb, jb, k+jb, one,
     $                   work( ipv ), 1, 1, descv, work( ipx ), 1, 1,
     $                   descv, zero, work( ipy ), 1, 1, desct )
            CALL pdtrmm( 'Left', 'Lower', 'No transpose', 'Non-Unit',
     $                   jb, jb, one, work( ipt ), 1, 1, desct,
     $                   work( ipy ), 1, 1, desct )
            CALL pdgemm( 'No tranpose', 'No transpose', k+jb, jb, jb,
     $                   -half, work( ipv ), 1, 1, descv, work( ipy ),
     $                   1, 1, desct, one, work( ipx ), 1, 1, descv )
*
*           (3) A := A - X * V' - V * X'
*
            CALL pdsyr2k( 'Upper', 'No transpose', k+jb, jb, -one,
     $                    work( ipv ), 1, 1, descv, work( ipx ), 1, 1,
     $                    descv, one, a, ia, ja, desca )
*
            descv( csrc_ ) = mod( descv( csrc_ ) + 1, npcol )
            desct( csrc_ ) = mod( desct( csrc_ ) + 1, npcol )
*
   20    CONTINUE
*
      ELSE
*
         CALL descset( desce, 1, ja+n-2, 1, desca( nb_ ), myrow,
     $                 desca( csrc_ ), desca( ctxt_ ), 1 )
*
         DO 30 j = 0, n-1
            d1 = zero
            e1 = zero
            d2 = zero
            e2 = zero
            CALL pdelget( ' ', ' ', d2, d, 1, ja+j, descd )
            CALL pdelget( 'Columnwise', ' ', d1, a, ia+j, ja+j, desca )
            IF( j.LT.(n-1) ) THEN
               CALL pdelget( ' ', ' ', e2, e, 1, ja+j, desce )
               CALL pdelget( 'Columnwise', ' ', e1, a, ia+j+1, ja+j,
     $                       desca )
            END IF
*
            IF( ( abs( d1 - d2 ).GT.( abs( d2 ) * addbnd ) ) .OR.
     $          ( abs( e1 - e2 ).GT.( abs( e2 ) * addbnd ) ) )
     $         info = info + 1
   30    CONTINUE
*
*        Compute the lower triangle of sub( A ).
*
         jl = max( ( ( ja+n-2 ) / nb ) * nb + 1, ja )
         iacol = indxg2p( jl, nb, mycol, desca( csrc_ ), npcol )
         CALL descset( descv, n, nb, nb, nb, iarow, iacol, ictxt,
     $                 max( 1, np ) )
         CALL descset( desct, nb, nb, nb, nb, indxg2p( ia+jl-ja+1, nb,
     $                 myrow, desca( rsrc_ ), nprow ), iacol, ictxt,
     $                 nb )
*
         DO 40 j = jl, ja, -nb
            k  = j - ja + 1
            i  = ia + k - 1
            jb = min( n-k+1, nb )
*
*           Compute upper triangular matrix T from TAU.
*
            CALL pdlarft( 'Forward', 'Columnwise', n-k, jb, a, i+1, j,
     $                    desca, tau, work( ipt ), work( ipv ) )
*
*           Copy Householder vectors into WORK( IPV ).
*
            CALL pdlacpy( 'Lower', n-k, jb, a, i+1, j, desca,
     $                    work( ipv ), k+1, 1, descv )
            CALL pdlaset( 'Upper', n-k, jb, zero, one, work( ipv ),
     $                    k+1, 1, descv )
            CALL pdlaset( 'Ge', 1, jb, zero, zero, work( ipv ), k, 1,
     $                    descv )
*
*           Zero out the strict lower triangular part of A.
*
            CALL pdlaset( 'Lower', n-k-1, jb, zero, zero, a, i+2, j,
     $                    desca )
*
*           (1) X := A * V * T'
*
            CALL pdsymm( 'Left', 'Lower', n-k+1, jb, one, a, i, j,
     $                   desca, work( ipv ), k, 1, descv, zero,
     $                   work( ipx ), k, 1, descv )
            CALL pdtrmm( 'Right', 'Upper', 'Transpose', 'Non-Unit',
     $                   n-k+1, jb, one, work( ipt ), 1, 1, desct,
     $                   work( ipx ), k, 1, descv )
*
*           (2) X := X - 1/2 * V * (T * V' * X)
*
            CALL pdgemm( 'Transpose', 'No transpose', jb, jb, n-k+1,
     $                   one, work( ipv ), k, 1, descv, work( ipx ),
     $                   k, 1, descv, zero, work( ipy ), 1, 1, desct )
            CALL pdtrmm( 'Left', 'Upper', 'No transpose', 'Non-Unit',
     $                   jb, jb, one, work( ipt ), 1, 1, desct,
     $                   work( ipy ), 1, 1, desct )
            CALL pdgemm( 'No transpose', 'No transpose', n-k+1, jb, jb,
     $                   -half, work( ipv ), k, 1, descv, work( ipy ),
     $                   1, 1, desct, one, work( ipx ), k, 1, descv )
*
*           (3) A := A - X * V' - V * X'
*
            CALL pdsyr2k( 'Lower', 'No tranpose', n-k+1, jb, -one,
     $                    work( ipv ), k, 1, descv, work( ipx ), k, 1,
     $                    descv, one, a, i, j, desca )
*
            descv( csrc_ ) = mod( descv( csrc_ ) + npcol - 1, npcol )
            desct( rsrc_ ) = mod( desct( rsrc_ ) + nprow - 1, nprow )
            desct( csrc_ ) = mod( desct( csrc_ ) + npcol - 1, npcol )
*
   40    CONTINUE
*
      END IF
*
      CALL igsum2d( ictxt, 'All', ' ', 1, 1, info, 1, -1, 0 )
*
      RETURN
*
*     End of PDSYTDRV
*
      END