pdormhr.f

Go to the documentation of this file.

      SUBROUTINE pdormhr( SIDE, TRANS, M, N, ILO, IHI, A, IA, JA, DESCA,
     $                    TAU, C, IC, JC, DESCC, WORK, LWORK, INFO )
*
*  -- ScaLAPACK routine (version 1.7) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     May 1, 1997
*
*     .. Scalar Arguments ..
      CHARACTER          SIDE, TRANS
      INTEGER            IA, IC, IHI, ILO, INFO, JA, JC, LWORK, M, N
*     ..
*     .. Array Arguments ..
      INTEGER            DESCA( * ), DESCC( * )
      DOUBLE PRECISION   A( * ), C( * ), TAU( * ), WORK( * )
*     ..
*
*  Purpose
*  =======
*
*  PDORMHR overwrites the general real M-by-N distributed matrix
*  sub( C ) = C(IC:IC+M-1,JC:JC+N-1) with
*
*                       SIDE = 'L'           SIDE = 'R'
*  TRANS = 'N':      Q * sub( C )          sub( C ) * Q
*  TRANS = 'T':      Q**T * sub( C )       sub( C ) * Q**T
*
*  where Q is a real orthogonal distributed matrix of order nq, with
*  nq = m if SIDE = 'L' and nq = n if SIDE = 'R'. Q is defined as the
*  product of IHI-ILO elementary reflectors, as returned by PDGEHRD:
*
*  Q = H(ilo) H(ilo+1) . . . H(ihi-1).
*
*  Notes
*  =====
*
*  Each global data object is described by an associated description
*  vector.  This vector stores the information required to establish
*  the mapping between an object element and its corresponding process
*  and memory location.
*
*  Let A be a generic term for any 2D block cyclicly distributed array.
*  Such a global array has an associated description vector DESCA.
*  In the following comments, the character _ should be read as
*  "of the global array".
*
*  NOTATION        STORED IN      EXPLANATION
*  --------------- -------------- --------------------------------------
*  DTYPE_A(global) DESCA( DTYPE_ )The descriptor type.  In this case,
*                                 DTYPE_A = 1.
*  CTXT_A (global) DESCA( CTXT_ ) The BLACS context handle, indicating
*                                 the BLACS process grid A is distribu-
*                                 ted over. The context itself is glo-
*                                 bal, but the handle (the integer
*                                 value) may vary.
*  M_A    (global) DESCA( M_ )    The number of rows in the global
*                                 array A.
*  N_A    (global) DESCA( N_ )    The number of columns in the global
*                                 array A.
*  MB_A   (global) DESCA( MB_ )   The blocking factor used to distribute
*                                 the rows of the array.
*  NB_A   (global) DESCA( NB_ )   The blocking factor used to distribute
*                                 the columns of the array.
*  RSRC_A (global) DESCA( RSRC_ ) The process row over which the first
*                                 row of the array A is distributed.
*  CSRC_A (global) DESCA( CSRC_ ) The process column over which the
*                                 first column of the array A is
*                                 distributed.
*  LLD_A  (local)  DESCA( LLD_ )  The leading dimension of the local
*                                 array.  LLD_A >= MAX(1,LOCr(M_A)).
*
*  Let K be the number of rows or columns of a distributed matrix,
*  and assume that its process grid has dimension p x q.
*  LOCr( K ) denotes the number of elements of K that a process
*  would receive if K were distributed over the p processes of its
*  process column.
*  Similarly, LOCc( K ) denotes the number of elements of K that a
*  process would receive if K were distributed over the q processes of
*  its process row.
*  The values of LOCr() and LOCc() may be determined via a call to the
*  ScaLAPACK tool function, NUMROC:
*          LOCr( M ) = NUMROC( M, MB_A, MYROW, RSRC_A, NPROW ),
*          LOCc( N ) = NUMROC( N, NB_A, MYCOL, CSRC_A, NPCOL ).
*  An upper bound for these quantities may be computed by:
*          LOCr( M ) <= ceil( ceil(M/MB_A)/NPROW )*MB_A
*          LOCc( N ) <= ceil( ceil(N/NB_A)/NPCOL )*NB_A
*
*  Arguments
*  =========
*
*  SIDE    (global input) CHARACTER
*          = 'L': apply Q or Q**T from the Left;
*          = 'R': apply Q or Q**T from the Right.
*
*  TRANS   (global input) CHARACTER
*          = 'N':  No transpose, apply Q;
*          = 'T':  Transpose, apply Q**T.
*
*  M       (global input) INTEGER
*          The number of rows to be operated on i.e the number of rows
*          of the distributed submatrix sub( C ). M >= 0.
*
*  N       (global input) INTEGER
*          The number of columns to be operated on i.e the number of
*          columns of the distributed submatrix sub( C ). N >= 0.
*
*  ILO     (global input) INTEGER
*  IHI     (global input) INTEGER
*          ILO and IHI must have the same values as in the previous call
*          of PDGEHRD. Q is equal to the unit matrix except in the
*          distributed submatrix Q(ia+ilo:ia+ihi-1,ia+ilo:ja+ihi-1).
*          If SIDE = 'L', 1 <= ILO <= IHI <= max(1,M);
*          if SIDE = 'R', 1 <= ILO <= IHI <= max(1,N);
*          ILO and IHI are relative indexes.
*
*  A       (local input) DOUBLE PRECISION pointer into the local memory
*          to an array of dimension (LLD_A,LOCc(JA+M-1)) if SIDE='L',
*          and (LLD_A,LOCc(JA+N-1)) if SIDE = 'R'. The vectors which
*          define the elementary reflectors, as returned by PDGEHRD.
*
*  IA      (global input) INTEGER
*          The row index in the global array A indicating the first
*          row of sub( A ).
*
*  JA      (global input) INTEGER
*          The column index in the global array A indicating the
*          first column of sub( A ).
*
*  DESCA   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix A.
*
*  TAU     (local input) DOUBLE PRECISION array, dimension LOCc(JA+M-2)
*          if SIDE = 'L', and LOCc(JA+N-2) if SIDE = 'R'. This array
*          contains the scalar factors TAU(j) of the elementary
*          reflectors H(j) as returned by PDGEHRD. TAU is tied to
*          the distributed matrix A.
*
*  C       (local input/local output) DOUBLE PRECISION pointer into the
*          local memory to an array of dimension (LLD_C,LOCc(JC+N-1)).
*          On entry, the local pieces of the distributed matrix sub(C).
*          On exit, sub( C ) is overwritten by Q*sub( C ) or Q'*sub( C )
*          or sub( C )*Q' or sub( C )*Q.
*
*  IC      (global input) INTEGER
*          The row index in the global array C indicating the first
*          row of sub( C ).
*
*  JC      (global input) INTEGER
*          The column index in the global array C indicating the
*          first column of sub( C ).
*
*  DESCC   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix C.
*
*  WORK    (local workspace/local output) DOUBLE PRECISION array,
*                                                     dimension (LWORK)
*          On exit, WORK(1) returns the minimal and optimal LWORK.
*
*  LWORK   (local or global input) INTEGER
*          The dimension of the array WORK.
*          LWORK is local input and must be at least
*
*          IAA = IA + ILO; JAA = JA+ILO-1;
*          If SIDE = 'L',
*            MI = IHI-ILO; NI = N; ICC = IC + ILO; JCC = JC;
*            LWORK >= MAX( (NB_A*(NB_A-1))/2, (NqC0 + MpC0)*NB_A ) +
*                     NB_A * NB_A
*          else if SIDE = 'R',
*            MI = M; NI = IHI-ILO; ICC = IC; JCC = JC + ILO;
*            LWORK >= MAX( (NB_A*(NB_A-1))/2, ( NqC0 + MAX( NpA0 +
*                     NUMROC( NUMROC( NI+ICOFFC, NB_A, 0, 0, NPCOL ),
*                             NB_A, 0, 0, LCMQ ), MpC0 ) )*NB_A ) +
*                     NB_A * NB_A
*          end if
*
*          where LCMQ = LCM / NPCOL with LCM = ICLM( NPROW, NPCOL ),
*
*          IROFFA = MOD( IAA-1, MB_A ), ICOFFA = MOD( JAA-1, NB_A ),
*          IAROW = INDXG2P( IAA, MB_A, MYROW, RSRC_A, NPROW ),
*          NpA0 = NUMROC( NI+IROFFA, MB_A, MYROW, IAROW, NPROW ),
*
*          IROFFC = MOD( ICC-1, MB_C ), ICOFFC = MOD( JCC-1, NB_C ),
*          ICROW = INDXG2P( ICC, MB_C, MYROW, RSRC_C, NPROW ),
*          ICCOL = INDXG2P( JCC, NB_C, MYCOL, CSRC_C, NPCOL ),
*          MpC0 = NUMROC( MI+IROFFC, MB_C, MYROW, ICROW, NPROW ),
*          NqC0 = NUMROC( NI+ICOFFC, NB_C, MYCOL, ICCOL, NPCOL ),
*
*          ILCM, INDXG2P and NUMROC are ScaLAPACK tool functions;
*          MYROW, MYCOL, NPROW and NPCOL can be determined by calling
*          the subroutine BLACS_GRIDINFO.
*
*          If LWORK = -1, then LWORK is global input and a workspace
*          query is assumed; the routine only calculates the minimum
*          and optimal size for all work arrays. Each of these
*          values is returned in the first entry of the corresponding
*          work array, and no error message is issued by PXERBLA.
*
*
*  INFO    (global output) INTEGER
*          = 0:  successful exit
*          < 0:  If the i-th argument is an array and the j-entry had
*                an illegal value, then INFO = -(i*100+j), if the i-th
*                argument is a scalar and had an illegal value, then
*                INFO = -i.
*
*  Alignment requirements
*  ======================
*
*  The distributed submatrices A(IA:*, JA:*) and C(IC:IC+M-1,JC:JC+N-1)
*  must verify some alignment properties, namely the following
*  expressions should be true:
*
*  If SIDE = 'L',
*    ( MB_A.EQ.MB_C .AND. IROFFA.EQ.IROFFC .AND. IAROW.EQ.ICROW )
*  If SIDE = 'R',
*    ( MB_A.EQ.NB_C .AND. IROFFA.EQ.ICOFFC )
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            BLOCK_CYCLIC_2D, CSRC_, CTXT_, DLEN_, DTYPE_,
     $                   lld_, mb_, m_, nb_, n_, rsrc_
      parameter( block_cyclic_2d = 1, dlen_ = 9, dtype_ = 1,
     $                     ctxt_ = 2, m_ = 3, n_ = 4, mb_ = 5, nb_ = 6,
     $                     rsrc_ = 7, csrc_ = 8, lld_ = 9 )
*     ..
*     .. Local Scalars ..
      LOGICAL            LEFT, LQUERY, NOTRAN
      INTEGER            IAA, IAROW, ICC, ICCOL, ICOFFC, ICROW, ICTXT,
     $                   iinfo, iroffa, iroffc, jaa, jcc, lcm, lcmq,
     $                   lwmin, mi, mpc0, mycol, myrow, nh, ni, npa0,
     $                   npcol, nprow, nq, nqc0
*     ..
*     .. Local Arrays ..
      INTEGER            IDUM1( 5 ), IDUM2( 5 )
*     ..
*     .. External Subroutines ..
      EXTERNAL           blacs_gridinfo, chk1mat, pchk2mat, pdormqr,
     $                   pxerbla
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      INTEGER            ILCM, INDXG2P, NUMROC
      EXTERNAL           ilcm, indxg2p, lsame, numroc
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble, ichar, max, min, mod
*     ..
*     .. Executable Statements ..
*
*     Get grid parameters
*
      ictxt = desca( ctxt_ )
      CALL blacs_gridinfo( ictxt, nprow, npcol, myrow, mycol )
*
*     Test the input parameters
*
      info = 0
      nh = ihi - ilo
      IF( nprow.EQ.-1 ) THEN
         info = -(1000+ctxt_)
      ELSE
         left = lsame( side, 'L' )
         notran = lsame( trans, 'N' )
         iaa = ia + ilo
         jaa = ja + ilo - 1
*
*        NQ is the order of Q
*
         IF( left ) THEN
            nq = m
            mi = nh
            ni = n
            icc = ic + ilo
            jcc = jc
            CALL chk1mat( m, 3, m, 3, ia, ja, desca, 10, info )
         ELSE
            nq = n
            mi = m
            ni = nh
            icc = ic
            jcc = jc + ilo
            CALL chk1mat( n, 4, n, 4, ia, ja, desca, 10, info )
         END IF
         CALL chk1mat( m, 3, n, 4, ic, jc, descc, 15, info )
         IF( info.EQ.0 ) THEN
            iroffa = mod( iaa-1, desca( mb_ ) )
            iroffc = mod( icc-1, descc( mb_ ) )
            icoffc = mod( jcc-1, descc( nb_ ) )
            iarow = indxg2p( iaa, desca( mb_ ), myrow, desca( rsrc_ ),
     $                       nprow )
            icrow = indxg2p( icc, descc( mb_ ), myrow, descc( rsrc_ ),
     $                       nprow )
            iccol = indxg2p( jcc, descc( nb_ ), mycol, descc( csrc_ ),
     $                       npcol )
            mpc0 = numroc( mi+iroffc, descc( mb_ ), myrow, icrow,
     $                     nprow )
            nqc0 = numroc( ni+icoffc, descc( nb_ ), mycol, iccol,
     $                     npcol )
*
            IF( left ) THEN
               lwmin = max( ( desca( nb_ ) * ( desca( nb_ ) - 1 ) ) / 2,
     $                      ( mpc0 + nqc0 ) * desca( nb_ ) ) +
     $                 desca( nb_ ) * desca( nb_ )
            ELSE
               npa0 = numroc( ni+iroffa, desca( mb_ ), myrow, iarow,
     $                        nprow )
               lcm = ilcm( nprow, npcol )
               lcmq = lcm / npcol
               lwmin =  max( ( desca( nb_ ) * ( desca( nb_ ) - 1 ) )
     $                  / 2, ( nqc0 + max( npa0 + numroc( numroc(
     $                  ni+icoffc, desca( nb_ ), 0, 0, npcol ),
     $                  desca( nb_ ), 0, 0, lcmq ), mpc0 ) ) *
     $                  desca( nb_ ) ) + desca( nb_ ) * desca( nb_ )
            END IF
*
            work( 1 ) = dble( lwmin )
            lquery = ( lwork.EQ.-1 )
            IF( .NOT.left .AND. .NOT.lsame( side, 'R' ) ) THEN
               info = -1
            ELSE IF( .NOT.lsame( trans, 'N' ) .AND.
     $         .NOT.lsame( trans, 'T' ) ) THEN
               info = -2
            ELSE IF( ilo.LT.1 .OR. ilo.GT.max( 1, nq ) ) THEN
               info = -5
            ELSE IF( ihi.LT.min( ilo, nq ) .OR. ihi.GT.nq ) THEN
               info = -6
            ELSE IF( .NOT.left .AND. desca( mb_ ).NE.descc( nb_ ) ) THEN
               info = -(1000+nb_)
            ELSE IF( left .AND. iroffa.NE.iroffc ) THEN
               info = -13
            ELSE IF( left .AND. iarow.NE.icrow ) THEN
               info = -13
            ELSE IF( .NOT.left .AND. iroffa.NE.icoffc ) THEN
               info = -14
            ELSE IF( left .AND. desca( mb_ ).NE.descc( mb_ ) ) THEN
               info = -(1500+mb_)
            ELSE IF( ictxt.NE.descc( ctxt_ ) ) THEN
               info = -(1500+ctxt_)
            ELSE IF( lwork.LT.lwmin .AND. .NOT.lquery ) THEN
               info = -17
            END IF
         END IF
*
         IF( left ) THEN
            idum1( 1 ) = ichar( 'L' )
         ELSE
            idum1( 1 ) = ichar( 'R' )
         END IF
         idum2( 1 ) = 1
         IF( notran ) THEN
            idum1( 2 ) = ichar( 'N' )
         ELSE
            idum1( 2 ) = ichar( 'T' )
         END IF
         idum2( 2 ) = 2
         idum1( 3 ) = ilo
         idum2( 3 ) = 5
         idum1( 4 ) = ihi
         idum2( 4 ) = 6
         IF( lwork.EQ.-1 ) THEN
            idum1( 5 ) = -1
         ELSE
            idum1( 5 ) = 1
         END IF
         idum2( 5 ) = 17
         IF( left ) THEN
            CALL pchk2mat( m, 3, m, 3, ia, ja, desca, 10, m, 3, n, 4,
     $                     ic, jc, descc, 15, 5, idum1, idum2, info )
         ELSE
            CALL pchk2mat( n, 4, n, 4, ia, ja, desca, 10, m, 3, n, 4,
     $                     ic, jc, descc, 15, 5, idum1, idum2, info )
         END IF
      END IF
*
      IF( info.NE.0 ) THEN
         CALL pxerbla( ictxt, 'PDORMHR', -info )
         RETURN
      ELSE IF( lquery ) THEN
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( m.EQ.0 .OR. n.EQ.0 .OR. nh.EQ.0 )
     $   RETURN
*
      CALL pdormqr( side, trans, mi, ni, nh, a, iaa, jaa, desca, tau,
     $              c, icc, jcc, descc, work, lwork, iinfo )
*
      work( 1 ) = dble( lwmin )
*
      RETURN
*
*     End of PDORMHR
*
      END