pdlaread.f

Go to the documentation of this file.

      SUBROUTINE pdlaread( FILNAM, A, DESCA, IRREAD, ICREAD, WORK )
*
*  -- ScaLAPACK tools routine (version 1.8) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*
*     written by Antoine Petitet, August 1995 (petitet@cs.utk.edu)
*     adapted by Julie Langou, April 2007 (julie@cs.utk.edu)
*
*     .. Scalar Arguments ..
      INTEGER            ICREAD, IRREAD
*     ..
*     .. Array Arguments ..
      CHARACTER*(*)      FILNAM
      INTEGER            DESCA( * )
      DOUBLE PRECISION   A( * ), WORK( * )
*     ..
*
*  Purpose
*  =======
*
*  PDLAREAD reads from a file named FILNAM a matrix and distribute
*  it to the process grid.
*
*  Only the process of coordinates {IRREAD, ICREAD} read the file.
*
*  WORK must be of size >= MB_ = DESCA( MB_ ).
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            NIN
      parameter( nin = 11 )
      INTEGER            BLOCK_CYCLIC_2D, CSRC_, CTXT_, DLEN_, DT_,
     $                   LLD_, MB_, M_, NB_, N_, RSRC_
      parameter( block_cyclic_2d = 1, dlen_ = 9, dt_ = 1,
     $                     ctxt_ = 2, m_ = 3, n_ = 4, mb_ = 5, nb_ = 6,
     $                     rsrc_ = 7, csrc_ = 8, lld_ = 9 )
*     ..
*     .. Local Scalars ..
      INTEGER            H, I, IB, ICTXT, ICURCOL, ICURROW, II, J, JB,
     $                   JJ, K, LDA, M, MYCOL, MYROW, N, NPCOL, NPROW
*     ..
*     .. Local Arrays ..
      INTEGER            IWORK( 2 )
*     ..
*     .. External Subroutines ..
      EXTERNAL           blacs_gridinfo, infog2l, dgerv2d, dgesd2d,
     $                   igebs2d, igebr2d
*     ..
*     .. External Functions ..
      INTEGER            ICEIL
      EXTERNAL           iceil
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          min, mod
*     ..
*     .. Executable Statements ..
*
*     Get grid parameters
*
      ictxt = desca( ctxt_ )
      CALL blacs_gridinfo( ictxt, nprow, npcol, myrow, mycol )
*
      IF( myrow.EQ.irread .AND. mycol.EQ.icread ) THEN
         OPEN( nin, file=filnam, status='OLD' )
         READ( nin, fmt = * ) ( iwork( i ), i = 1, 2 )
         CALL igebs2d( ictxt, 'All', ' ', 2, 1, iwork, 2 )
      ELSE
         CALL igebr2d( ictxt, 'All', ' ', 2, 1, iwork, 2, irread,
     $                 icread )
      END IF
      m = iwork( 1 )
      n = iwork( 2 )
*
      IF( m.LE.0 .OR. n.LE.0 )
     $   RETURN
*
      IF( m.GT.desca( m_ ).OR. n.GT.desca( n_ ) ) THEN
         IF( myrow.EQ.0 .AND. mycol.EQ.0 ) THEN
            WRITE( *, fmt = * ) 'PDLAREAD: Matrix too big to fit in'
            WRITE( *, fmt = * ) 'Abort ...'
         END IF
         CALL blacs_abort( ictxt, 0 )
      END IF
*
      ii = 1
      jj = 1
      icurrow = desca( rsrc_ )
      icurcol = desca( csrc_ )
      lda = desca( lld_ )
*
*     Loop over column blocks
*
      DO 50 j = 1, n, desca( nb_ )
         jb = min(  desca( nb_ ), n-j+1 )
         DO 40 h = 0, jb-1
*
*           Loop over block of rows
*
            DO 30 i = 1, m, desca( mb_ )
               ib = min( desca( mb_ ), m-i+1 )
               IF( icurrow.EQ.irread .AND. icurcol.EQ.icread ) THEN
                  IF( myrow.EQ.irread .AND. mycol.EQ.icread ) THEN
                     DO 10 k = 0, ib-1
                        READ( nin, fmt = * ) a( ii+k+(jj+h-1)*lda )
   10                CONTINUE
                  END IF
               ELSE
                  IF( myrow.EQ.icurrow .AND. mycol.EQ.icurcol ) THEN
                     CALL dgerv2d( ictxt, ib, 1, a( ii+(jj+h-1)*lda ),
     $                             lda, irread, icread )
                   ELSE IF( myrow.EQ.irread .AND. mycol.EQ.icread ) THEN
                     DO 20 k = 1, ib
                        READ( nin, fmt = * ) work( k )
   20                CONTINUE
                     CALL dgesd2d( ictxt, ib, 1, work, desca( mb_ ),
     $                             icurrow, icurcol )
                  END IF
               END IF
               IF( myrow.EQ.icurrow )
     $            ii = ii + ib
               icurrow = mod( icurrow+1, nprow )
   30       CONTINUE
*
            ii = 1
            icurrow = desca( rsrc_ )
   40    CONTINUE
*
         IF( mycol.EQ.icurcol )
     $      jj = jj + jb
         icurcol = mod( icurcol+1, npcol )
*
   50 CONTINUE
*
      IF( myrow.EQ.irread .AND. mycol.EQ.icread ) THEN
         CLOSE( nin )
      END IF
*
      RETURN
*
*     End of PDLAREAD
*
      SUBROUTINE pdlaread( FILNAM, A, DESCA, IRREAD, ICREAD, WORK ) …
      END