ScaLAPACK 2.1  2.1
ScaLAPACK: Scalable Linear Algebra PACKage
pcgeqr2.f
Go to the documentation of this file.
1  SUBROUTINE pcgeqr2( M, N, A, IA, JA, DESCA, TAU, WORK, LWORK,
2  $ INFO )
3 *
4 * -- ScaLAPACK routine (version 1.7) --
5 * University of Tennessee, Knoxville, Oak Ridge National Laboratory,
6 * and University of California, Berkeley.
7 * May 25, 2001
8 *
9 * .. Scalar Arguments ..
10  INTEGER IA, INFO, JA, LWORK, M, N
11 * ..
12 * .. Array Arguments ..
13  INTEGER DESCA( * )
14  COMPLEX A( * ), TAU( * ), WORK( * )
15 * ..
16 *
17 * Purpose
18 * =======
19 *
20 * PCGEQR2 computes a QR factorization of a complex distributed M-by-N
21 * matrix sub( A ) = A(IA:IA+M-1,JA:JA+N-1) = Q * R.
22 *
23 * Notes
24 * =====
25 *
26 * Each global data object is described by an associated description
27 * vector. This vector stores the information required to establish
28 * the mapping between an object element and its corresponding process
29 * and memory location.
30 *
31 * Let A be a generic term for any 2D block cyclicly distributed array.
32 * Such a global array has an associated description vector DESCA.
33 * In the following comments, the character _ should be read as
34 * "of the global array".
35 *
36 * NOTATION STORED IN EXPLANATION
37 * --------------- -------------- --------------------------------------
38 * DTYPE_A(global) DESCA( DTYPE_ )The descriptor type. In this case,
39 * DTYPE_A = 1.
40 * CTXT_A (global) DESCA( CTXT_ ) The BLACS context handle, indicating
41 * the BLACS process grid A is distribu-
42 * ted over. The context itself is glo-
43 * bal, but the handle (the integer
44 * value) may vary.
45 * M_A (global) DESCA( M_ ) The number of rows in the global
46 * array A.
47 * N_A (global) DESCA( N_ ) The number of columns in the global
48 * array A.
49 * MB_A (global) DESCA( MB_ ) The blocking factor used to distribute
50 * the rows of the array.
51 * NB_A (global) DESCA( NB_ ) The blocking factor used to distribute
52 * the columns of the array.
53 * RSRC_A (global) DESCA( RSRC_ ) The process row over which the first
54 * row of the array A is distributed.
55 * CSRC_A (global) DESCA( CSRC_ ) The process column over which the
56 * first column of the array A is
57 * distributed.
58 * LLD_A (local) DESCA( LLD_ ) The leading dimension of the local
59 * array. LLD_A >= MAX(1,LOCr(M_A)).
60 *
61 * Let K be the number of rows or columns of a distributed matrix,
62 * and assume that its process grid has dimension p x q.
63 * LOCr( K ) denotes the number of elements of K that a process
64 * would receive if K were distributed over the p processes of its
65 * process column.
66 * Similarly, LOCc( K ) denotes the number of elements of K that a
67 * process would receive if K were distributed over the q processes of
68 * its process row.
69 * The values of LOCr() and LOCc() may be determined via a call to the
70 * ScaLAPACK tool function, NUMROC:
71 * LOCr( M ) = NUMROC( M, MB_A, MYROW, RSRC_A, NPROW ),
72 * LOCc( N ) = NUMROC( N, NB_A, MYCOL, CSRC_A, NPCOL ).
73 * An upper bound for these quantities may be computed by:
74 * LOCr( M ) <= ceil( ceil(M/MB_A)/NPROW )*MB_A
75 * LOCc( N ) <= ceil( ceil(N/NB_A)/NPCOL )*NB_A
76 *
77 * Arguments
78 * =========
79 *
80 * M (global input) INTEGER
81 * The number of rows to be operated on, i.e. the number of rows
82 * of the distributed submatrix sub( A ). M >= 0.
83 *
84 * N (global input) INTEGER
85 * The number of columns to be operated on, i.e. the number of
86 * columns of the distributed submatrix sub( A ). N >= 0.
87 *
88 * A (local input/local output) COMPLEX pointer into the
89 * local memory to an array of dimension (LLD_A, LOCc(JA+N-1)).
90 * On entry, the local pieces of the M-by-N distributed matrix
91 * sub( A ) which is to be factored. On exit, the elements on
92 * and above the diagonal of sub( A ) contain the min(M,N) by N
93 * upper trapezoidal matrix R (R is upper triangular if M >= N);
94 * the elements below the diagonal, with the array TAU,
95 * represent the unitary matrix Q as a product of elementary
96 * reflectors (see Further Details).
97 *
98 * IA (global input) INTEGER
99 * The row index in the global array A indicating the first
100 * row of sub( A ).
101 *
102 * JA (global input) INTEGER
103 * The column index in the global array A indicating the
104 * first column of sub( A ).
105 *
106 * DESCA (global and local input) INTEGER array of dimension DLEN_.
107 * The array descriptor for the distributed matrix A.
108 *
109 * TAU (local output) COMPLEX, array, dimension
110 * LOCc(JA+MIN(M,N)-1). This array contains the scalar factors
111 * TAU of the elementary reflectors. TAU is tied to the
112 * distributed matrix A.
113 *
114 * WORK (local workspace/local output) COMPLEX array,
115 * dimension (LWORK)
116 * On exit, WORK(1) returns the minimal and optimal LWORK.
117 *
118 * LWORK (local or global input) INTEGER
119 * The dimension of the array WORK.
120 * LWORK is local input and must be at least
121 * LWORK >= Mp0 + MAX( 1, Nq0 ), where
122 *
123 * IROFF = MOD( IA-1, MB_A ), ICOFF = MOD( JA-1, NB_A ),
124 * IAROW = INDXG2P( IA, MB_A, MYROW, RSRC_A, NPROW ),
125 * IACOL = INDXG2P( JA, NB_A, MYCOL, CSRC_A, NPCOL ),
126 * Mp0 = NUMROC( M+IROFF, MB_A, MYROW, IAROW, NPROW ),
127 * Nq0 = NUMROC( N+ICOFF, NB_A, MYCOL, IACOL, NPCOL ),
128 *
129 * and NUMROC, INDXG2P are ScaLAPACK tool functions;
130 * MYROW, MYCOL, NPROW and NPCOL can be determined by calling
131 * the subroutine BLACS_GRIDINFO.
132 *
133 * If LWORK = -1, then LWORK is global input and a workspace
134 * query is assumed; the routine only calculates the minimum
135 * and optimal size for all work arrays. Each of these
136 * values is returned in the first entry of the corresponding
137 * work array, and no error message is issued by PXERBLA.
138 *
139 * INFO (local output) INTEGER
140 * = 0: successful exit
141 * < 0: If the i-th argument is an array and the j-entry had
142 * an illegal value, then INFO = -(i*100+j), if the i-th
143 * argument is a scalar and had an illegal value, then
144 * INFO = -i.
145 *
146 * Further Details
147 * ===============
148 *
149 * The matrix Q is represented as a product of elementary reflectors
150 *
151 * Q = H(ja) H(ja+1) . . . H(ja+k-1), where k = min(m,n).
152 *
153 * Each H(i) has the form
154 *
155 * H(j) = I - tau * v * v'
156 *
157 * where tau is a complex scalar, and v is a complex vector with
158 * v(1:i-1) = 0 and v(i) = 1; v(i+1:m) is stored on exit in
159 * A(ia+i:ia+m-1,ja+i-1), and tau in TAU(ja+i-1).
160 *
161 * =====================================================================
162 *
163 * .. Parameters ..
164  INTEGER BLOCK_CYCLIC_2D, CSRC_, CTXT_, DLEN_, DTYPE_,
165  $ lld_, mb_, m_, nb_, n_, rsrc_
166  parameter( block_cyclic_2d = 1, dlen_ = 9, dtype_ = 1,
167  $ ctxt_ = 2, m_ = 3, n_ = 4, mb_ = 5, nb_ = 6,
168  $ rsrc_ = 7, csrc_ = 8, lld_ = 9 )
169  COMPLEX ONE
170  parameter( one = ( 1.0e+0, 0.0e+0 ) )
171 * ..
172 * .. Local Scalars ..
173  LOGICAL LQUERY
174  CHARACTER COLBTOP, ROWBTOP
175  INTEGER I, II, IACOL, IAROW, ICTXT, J, JJ, K, LWMIN,
176  $ mp, mycol, myrow, npcol, nprow, nq
177  COMPLEX AJJ, ALPHA
178 * ..
179 * .. External Subroutines ..
180  EXTERNAL blacs_abort, blacs_gridinfo, cgebr2d,
181  $ cgebs2d, chk1mat, clarfg, cscal,
182  $ infog2l, pcelset, pclarfc,
183  $ pclarfg, pb_topget, pb_topset, pxerbla
184 * ..
185 * .. External Functions ..
186  INTEGER INDXG2P, NUMROC
187  EXTERNAL indxg2p, numroc
188 * ..
189 * .. Intrinsic Functions ..
190  INTRINSIC cmplx, conjg, max, min, mod, real
191 * ..
192 * .. Executable Statements ..
193 *
194 * Get grid parameters
195 *
196  ictxt = desca( ctxt_ )
197  CALL blacs_gridinfo( ictxt, nprow, npcol, myrow, mycol )
198 *
199 * Test the input parameters
200 *
201  info = 0
202  IF( nprow.EQ.-1 ) THEN
203  info = -(600+ctxt_)
204  ELSE
205  CALL chk1mat( m, 1, n, 2, ia, ja, desca, 6, info )
206  IF( info.EQ.0 ) THEN
207  iarow = indxg2p( ia, desca( mb_ ), myrow, desca( rsrc_ ),
208  $ nprow )
209  iacol = indxg2p( ja, desca( nb_ ), mycol, desca( csrc_ ),
210  $ npcol )
211  mp = numroc( m+mod( ia-1, desca( mb_ ) ), desca( mb_ ),
212  $ myrow, iarow, nprow )
213  nq = numroc( n+mod( ja-1, desca( nb_ ) ), desca( nb_ ),
214  $ mycol, iacol, npcol )
215  lwmin = mp + max( 1, nq )
216 *
217  work( 1 ) = cmplx( real( lwmin ) )
218  lquery = ( lwork.EQ.-1 )
219  IF( lwork.LT.lwmin .AND. .NOT.lquery )
220  $ info = -9
221  END IF
222  END IF
223 *
224  IF( info.NE.0 ) THEN
225  CALL pxerbla( ictxt, 'PCGEQR2', -info )
226  CALL blacs_abort( ictxt, 1 )
227  RETURN
228  ELSE IF( lquery ) THEN
229  RETURN
230  END IF
231 *
232 * Quick return if possible
233 *
234  IF( m.EQ.0 .OR. n.EQ.0 )
235  $ RETURN
236 *
237  CALL pb_topget( ictxt, 'Broadcast', 'Rowwise', rowbtop )
238  CALL pb_topget( ictxt, 'Broadcast', 'Columnwise', colbtop )
239  CALL pb_topset( ictxt, 'Broadcast', 'Rowwise', 'I-ring' )
240  CALL pb_topset( ictxt, 'Broadcast', 'Columnwise', ' ' )
241 *
242  IF( desca( m_ ).EQ.1 ) THEN
243  CALL infog2l( ia, ja, desca, nprow, npcol, myrow, mycol, ii,
244  $ jj, iarow, iacol )
245  IF( myrow.EQ.iarow ) THEN
246  nq = numroc( ja+n-1, desca( nb_ ), mycol, desca( csrc_ ),
247  $ npcol )
248  i = ii+(jj-1)*desca( lld_ )
249  IF( mycol.EQ.iacol ) THEN
250  ajj = a( i )
251  CALL clarfg( 1, ajj, a( i ), 1, tau( jj ) )
252  IF( n.GT.1 ) THEN
253  alpha = one - conjg( tau( jj ) )
254  CALL cgebs2d( ictxt, 'Rowwise', ' ', 1, 1, alpha, 1 )
255  CALL cscal( nq-jj, alpha, a( i+desca( lld_ ) ),
256  $ desca( lld_ ) )
257  END IF
258  CALL cgebs2d( ictxt, 'Columnwise', ' ', 1, 1, tau( jj ),
259  $ 1 )
260  a( i ) = ajj
261  ELSE
262  IF( n.GT.1 ) THEN
263  CALL cgebr2d( ictxt, 'Rowwise', ' ', 1, 1, alpha,
264  $ 1, iarow, iacol )
265  CALL cscal( nq-jj+1, alpha, a( i ), desca( lld_ ) )
266  END IF
267  END IF
268  ELSE IF( mycol.EQ.iacol ) THEN
269  CALL cgebr2d( ictxt, 'Columnwise', ' ', 1, 1, tau( jj ), 1,
270  $ iarow, iacol )
271  END IF
272 *
273  ELSE
274 *
275  k = min( m, n )
276  DO 10 j = ja, ja+k-1
277  i = ia + j - ja
278 *
279 * Generate elementary reflector H(j) to annihilate
280 * A(i+1:ia+m-1,j)
281 *
282  CALL pclarfg( m-j+ja, ajj, i, j, a, min( i+1, ia+m-1 ), j,
283  $ desca, 1, tau )
284  IF( j.LT.ja+n-1 ) THEN
285 *
286 * Apply H(j)' to A(i:ia+m-1,j+1:ja+n-1) from the left
287 *
288  CALL pcelset( a, i, j, desca, one )
289 *
290  CALL pclarfc( 'Left', m-j+ja, n-j+ja-1, a, i, j, desca,
291  $ 1, tau, a, i, j+1, desca, work )
292  END IF
293  CALL pcelset( a, i, j, desca, ajj )
294 *
295  10 CONTINUE
296 *
297  END IF
298 *
299  CALL pb_topset( ictxt, 'Broadcast', 'Rowwise', rowbtop )
300  CALL pb_topset( ictxt, 'Broadcast', 'Columnwise', colbtop )
301 *
302  work( 1 ) = cmplx( real( lwmin ) )
303 *
304  RETURN
305 *
306 * End of PCGEQR2
307 *
308  END
cmplx
float cmplx[2]
Definition: pblas.h:132
max
#define max(A, B)
Definition: pcgemr.c:180
pclarfg
subroutine pclarfg(N, ALPHA, IAX, JAX, X, IX, JX, DESCX, INCX, TAU)
Definition: pclarfg.f:3
infog2l
subroutine infog2l(GRINDX, GCINDX, DESC, NPROW, NPCOL, MYROW, MYCOL, LRINDX, LCINDX, RSRC, CSRC)
Definition: infog2l.f:3
pclarfc
subroutine pclarfc(SIDE, M, N, V, IV, JV, DESCV, INCV, TAU, C, IC, JC, DESCC, WORK)
Definition: pclarfc.f:3
pcelset
subroutine pcelset(A, IA, JA, DESCA, ALPHA)
Definition: pcelset.f:2
chk1mat
subroutine chk1mat(MA, MAPOS0, NA, NAPOS0, IA, JA, DESCA, DESCAPOS0, INFO)
Definition: chk1mat.f:3
pcgeqr2
subroutine pcgeqr2(M, N, A, IA, JA, DESCA, TAU, WORK, LWORK, INFO)
Definition: pcgeqr2.f:3
pxerbla
subroutine pxerbla(ICTXT, SRNAME, INFO)
Definition: pxerbla.f:2
min
#define min(A, B)
Definition: pcgemr.c:181