pzunmrq.f

Go to the documentation of this file.

      SUBROUTINE pzunmrq( SIDE, TRANS, M, N, K, A, IA, JA, DESCA, TAU,
     $                    C, IC, JC, DESCC, WORK, LWORK, INFO )
*
*  -- ScaLAPACK routine (version 1.7) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     May 25, 2001
*
*     .. Scalar Arguments ..
      CHARACTER          SIDE, TRANS
      INTEGER            IA, IC, INFO, JA, JC, K, LWORK, M, N
*     ..
*     .. Array Arguments ..
      INTEGER            DESCA( * ), DESCC( * )
      COMPLEX*16         A( * ), C( * ), TAU( * ), WORK( * )
*     ..
*
*  Purpose
*  =======
*
*  PZUNMRQ overwrites the general complex M-by-N distributed matrix
*  sub( C ) = C(IC:IC+M-1,JC:JC+N-1) with
*
*                       SIDE = 'L'           SIDE = 'R'
*  TRANS = 'N':      Q * sub( C )          sub( C ) * Q
*  TRANS = 'C':      Q**H * sub( C )       sub( C ) * Q**H
*
*  where Q is a complex unitary distributed matrix defined as the
*  product of K elementary reflectors
*
*        Q = H(1)' H(2)' . . . H(k)'
*
*  as returned by PZGERQF. Q is of order M if SIDE = 'L' and of order N
*  if SIDE = 'R'.
*
*  Notes
*  =====
*
*  Each global data object is described by an associated description
*  vector.  This vector stores the information required to establish
*  the mapping between an object element and its corresponding process
*  and memory location.
*
*  Let A be a generic term for any 2D block cyclicly distributed array.
*  Such a global array has an associated description vector DESCA.
*  In the following comments, the character _ should be read as
*  "of the global array".
*
*  NOTATION        STORED IN      EXPLANATION
*  --------------- -------------- --------------------------------------
*  DTYPE_A(global) DESCA( DTYPE_ )The descriptor type.  In this case,
*                                 DTYPE_A = 1.
*  CTXT_A (global) DESCA( CTXT_ ) The BLACS context handle, indicating
*                                 the BLACS process grid A is distribu-
*                                 ted over. The context itself is glo-
*                                 bal, but the handle (the integer
*                                 value) may vary.
*  M_A    (global) DESCA( M_ )    The number of rows in the global
*                                 array A.
*  N_A    (global) DESCA( N_ )    The number of columns in the global
*                                 array A.
*  MB_A   (global) DESCA( MB_ )   The blocking factor used to distribute
*                                 the rows of the array.
*  NB_A   (global) DESCA( NB_ )   The blocking factor used to distribute
*                                 the columns of the array.
*  RSRC_A (global) DESCA( RSRC_ ) The process row over which the first
*                                 row of the array A is distributed.
*  CSRC_A (global) DESCA( CSRC_ ) The process column over which the
*                                 first column of the array A is
*                                 distributed.
*  LLD_A  (local)  DESCA( LLD_ )  The leading dimension of the local
*                                 array.  LLD_A >= MAX(1,LOCr(M_A)).
*
*  Let K be the number of rows or columns of a distributed matrix,
*  and assume that its process grid has dimension p x q.
*  LOCr( K ) denotes the number of elements of K that a process
*  would receive if K were distributed over the p processes of its
*  process column.
*  Similarly, LOCc( K ) denotes the number of elements of K that a
*  process would receive if K were distributed over the q processes of
*  its process row.
*  The values of LOCr() and LOCc() may be determined via a call to the
*  ScaLAPACK tool function, NUMROC:
*          LOCr( M ) = NUMROC( M, MB_A, MYROW, RSRC_A, NPROW ),
*          LOCc( N ) = NUMROC( N, NB_A, MYCOL, CSRC_A, NPCOL ).
*  An upper bound for these quantities may be computed by:
*          LOCr( M ) <= ceil( ceil(M/MB_A)/NPROW )*MB_A
*          LOCc( N ) <= ceil( ceil(N/NB_A)/NPCOL )*NB_A
*
*  Arguments
*  =========
*
*  SIDE    (global input) CHARACTER
*          = 'L': apply Q or Q**H from the Left;
*          = 'R': apply Q or Q**H from the Right.
*
*  TRANS   (global input) CHARACTER
*          = 'N':  No transpose, apply Q;
*          = 'C':  Conjugate transpose, apply Q**H.
*
*  M       (global input) INTEGER
*          The number of rows to be operated on i.e the number of rows
*          of the distributed submatrix sub( C ). M >= 0.
*
*  N       (global input) INTEGER
*          The number of columns to be operated on i.e the number of
*          columns of the distributed submatrix sub( C ). N >= 0.
*
*  K       (global input) INTEGER
*          The number of elementary reflectors whose product defines the
*          matrix Q.  If SIDE = 'L', M >= K >= 0, if SIDE = 'R',
*          N >= K >= 0.
*
*  A       (local input) COMPLEX*16 pointer into the local memory
*          to an array of dimension (LLD_A,LOCc(JA+M-1)) if SIDE='L',
*          and (LLD_A,LOCc(JA+N-1)) if SIDE='R', where
*          LLD_A >= MAX(1,LOCr(IA+K-1)); On entry, the i-th row must
*          contain the vector which defines the elementary reflector
*          H(i), IA <= i <= IA+K-1, as returned by PZGERQF in the
*          K rows of its distributed matrix argument A(IA:IA+K-1,JA:*).
*          A(IA:IA+K-1,JA:*) is modified by the routine but restored on
*          exit.
*
*  IA      (global input) INTEGER
*          The row index in the global array A indicating the first
*          row of sub( A ).
*
*  JA      (global input) INTEGER
*          The column index in the global array A indicating the
*          first column of sub( A ).
*
*  DESCA   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix A.
*
*  TAU     (local input) COMPLEX*16, array, dimension LOCc(IA+K-1).
*          This array contains the scalar factors TAU(i) of the
*          elementary reflectors H(i) as returned by PZGERQF.
*          TAU is tied to the distributed matrix A.
*
*  C       (local input/local output) COMPLEX*16 pointer into the
*          local memory to an array of dimension (LLD_C,LOCc(JC+N-1)).
*          On entry, the local pieces of the distributed matrix sub(C).
*          On exit, sub( C ) is overwritten by Q*sub( C ) or Q'*sub( C )
*          or sub( C )*Q' or sub( C )*Q.
*
*  IC      (global input) INTEGER
*          The row index in the global array C indicating the first
*          row of sub( C ).
*
*  JC      (global input) INTEGER
*          The column index in the global array C indicating the
*          first column of sub( C ).
*
*  DESCC   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix C.
*
*  WORK    (local workspace/local output) COMPLEX*16 array,
*                                                     dimension (LWORK)
*          On exit, WORK(1) returns the minimal and optimal LWORK.
*
*  LWORK   (local or global input) INTEGER
*          The dimension of the array WORK.
*          LWORK is local input and must be at least
*          if SIDE = 'L',
*            LWORK >= MAX( (MB_A*(MB_A-1))/2, ( MpC0 + MAX( MqA0 +
*                     NUMROC( NUMROC( M+IROFFC, MB_A, 0, 0, NPROW ),
*                             MB_A, 0, 0, LCMP ), NqC0 ) )*MB_A ) +
*                     MB_A * MB_A
*          else if SIDE = 'R',
*            LWORK >= MAX( (MB_A*(MB_A-1))/2, (MpC0 + NqC0)*MB_A ) +
*                     MB_A * MB_A
*          end if
*
*          where LCMP = LCM / NPROW with LCM = ICLM( NPROW, NPCOL ),
*
*          IROFFA = MOD( IA-1, MB_A ), ICOFFA = MOD( JA-1, NB_A ),
*          IACOL = INDXG2P( JA, NB_A, MYCOL, CSRC_A, NPCOL ),
*          MqA0 = NUMROC( M+ICOFFA, NB_A, MYCOL, IACOL, NPCOL ),
*
*          IROFFC = MOD( IC-1, MB_C ), ICOFFC = MOD( JC-1, NB_C ),
*          ICROW = INDXG2P( IC, MB_C, MYROW, RSRC_C, NPROW ),
*          ICCOL = INDXG2P( JC, NB_C, MYCOL, CSRC_C, NPCOL ),
*          MpC0 = NUMROC( M+IROFFC, MB_C, MYROW, ICROW, NPROW ),
*          NqC0 = NUMROC( N+ICOFFC, NB_C, MYCOL, ICCOL, NPCOL ),
*
*          ILCM, INDXG2P and NUMROC are ScaLAPACK tool functions;
*          MYROW, MYCOL, NPROW and NPCOL can be determined by calling
*          the subroutine BLACS_GRIDINFO.
*
*          If LWORK = -1, then LWORK is global input and a workspace
*          query is assumed; the routine only calculates the minimum
*          and optimal size for all work arrays. Each of these
*          values is returned in the first entry of the corresponding
*          work array, and no error message is issued by PXERBLA.
*
*
*  INFO    (global output) INTEGER
*          = 0:  successful exit
*          < 0:  If the i-th argument is an array and the j-entry had
*                an illegal value, then INFO = -(i*100+j), if the i-th
*                argument is a scalar and had an illegal value, then
*                INFO = -i.
*
*  Alignment requirements
*  ======================
*
*  The distributed submatrices A(IA:*, JA:*) and C(IC:IC+M-1,JC:JC+N-1)
*  must verify some alignment properties, namely the following
*  expressions should be true:
*
*  If SIDE = 'L',
*    ( NB_A.EQ.MB_C .AND. ICOFFA.EQ.IROFFC )
*  If SIDE = 'R',
*    ( NB_A.EQ.NB_C .AND. ICOFFA.EQ.ICOFFC .AND. IACOL.EQ.ICCOL )
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            BLOCK_CYCLIC_2D, CSRC_, CTXT_, DLEN_, DTYPE_,
     $                   lld_, mb_, m_, nb_, n_, rsrc_
      parameter( block_cyclic_2d = 1, dlen_ = 9, dtype_ = 1,
     $                     ctxt_ = 2, m_ = 3, n_ = 4, mb_ = 5, nb_ = 6,
     $                     rsrc_ = 7, csrc_ = 8, lld_ = 9 )
*     ..
*     .. Local Scalars ..
      LOGICAL            LEFT, LQUERY, NOTRAN, RIGHT, TRAN
      CHARACTER          COLBTOP, ROWBTOP, TRANST
      INTEGER            I, I1, I2, I3, IACOL, IB, ICCOL, ICOFFA,
     $                   icoffc, icrow, ictxt, iinfo, ipw, iroffc, lcm,
     $                   lcmp, lwmin, mi, mpc0, mqa0, mycol, myrow, ni,
     $                   npcol, nprow, nq, nqc0
*     ..
*     .. Local Arrays ..
      INTEGER            IDUM1( 4 ), IDUM2( 4 )
*     ..
*     .. External Subroutines ..
      EXTERNAL           blacs_gridinfo, chk1mat, pchk2mat, pb_topget,
     $                   pb_topset, pxerbla, pzlarfb, pzlarft,
     $                   pzunmr2
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      INTEGER            ICEIL, ILCM, INDXG2P, NUMROC
      EXTERNAL           iceil, ilcm, indxg2p, lsame, numroc
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble, dcmplx, ichar, max, min, mod
*     ..
*     .. Executable Statements ..
*
*     Get grid parameters
*
      ictxt = desca( ctxt_ )
      CALL blacs_gridinfo( ictxt, nprow, npcol, myrow, mycol )
*
*     Test the input parameters
*
      info = 0
      IF( nprow.EQ.-1 ) THEN
         info = -(900+ctxt_)
      ELSE
         IF( lsame( side, 'L' ) ) THEN
            left = .true.
            right = .false.
         ELSE
            left = .false.
            right = .true.
         END IF
         IF( lsame( trans, 'N' ) ) THEN
            notran = .true.
            tran = .false.
         ELSE
            notran = .false.
            tran = .true.
         END IF
*
*        NQ is the order of Q
*
         IF( left ) THEN
            nq = m
            CALL chk1mat( k, 5, m, 3, ia, ja, desca, 9, info )
         ELSE
            nq = n
            CALL chk1mat( k, 5, n, 4, ia, ja, desca, 9, info )
         END IF
         CALL chk1mat( m, 3, n, 4, ic, jc, descc, 14, info )
         IF( info.EQ.0 ) THEN
            icoffa = mod( ja-1, desca( nb_ ) )
            iroffc = mod( ic-1, descc( mb_ ) )
            icoffc = mod( jc-1, descc( nb_ ) )
            iacol = indxg2p( ja, desca( nb_ ), mycol, desca( csrc_ ),
     $                       npcol )
            icrow = indxg2p( ic, descc( mb_ ), myrow, descc( rsrc_ ),
     $                       nprow )
            iccol = indxg2p( jc, descc( nb_ ), mycol, descc( csrc_ ),
     $                       npcol )
            mpc0 = numroc( m+iroffc, descc( mb_ ), myrow, icrow, nprow )
            nqc0 = numroc( n+icoffc, descc( nb_ ), mycol, iccol, npcol )
*
            IF( left ) THEN
               mqa0 = numroc( m+icoffa, desca( nb_ ), mycol, iacol,
     $                        npcol )
               lcm = ilcm( nprow, npcol )
               lcmp = lcm / nprow
               lwmin =  max( ( desca( mb_ ) * ( desca( mb_ ) - 1 ) )
     $                  / 2, ( mpc0 + max( mqa0 + numroc( numroc(
     $                  m+iroffc, desca( mb_ ), 0, 0, nprow ),
     $                  desca( mb_ ), 0, 0, lcmp ), nqc0 ) ) *
     $                  desca( mb_ ) ) + desca( mb_ ) * desca( mb_ )
            ELSE
               lwmin = max( ( desca( mb_ ) * ( desca( mb_ ) - 1 ) ) / 2,
     $                      ( mpc0 + nqc0 ) * desca( mb_ ) ) +
     $                 desca( mb_ ) * desca( mb_ )
            END IF
*
            work( 1 ) = dcmplx( dble( lwmin ) )
            lquery = ( lwork.EQ.-1 )
            IF( .NOT.left .AND. .NOT.lsame( side, 'R' ) ) THEN
               info = -1
            ELSE IF( .NOT.notran .AND. .NOT.lsame( trans, 'C' ) ) THEN
               info = -2
            ELSE IF( k.LT.0 .OR. k.GT.nq ) THEN
               info = -5
            ELSE IF( left .AND. desca( nb_ ).NE.descc( mb_ ) ) THEN
               info = -(900+nb_)
            ELSE IF( left .AND. icoffa.NE.iroffc ) THEN
               info = -12
            ELSE IF( .NOT.left .AND. icoffa.NE.icoffc ) THEN
               info = -13
            ELSE IF( .NOT.left .AND. iacol.NE.iccol ) THEN
               info = -13
            ELSE IF( .NOT.left .AND. desca( nb_ ).NE.descc( nb_ ) ) THEN
               info = -(1400+nb_)
            ELSE IF( ictxt.NE.descc( ctxt_ ) ) THEN
               info = -(1400+ctxt_)
            ELSE IF( lwork.LT.lwmin .AND. .NOT.lquery ) THEN
               info = -16
            END IF
         END IF
         IF( left ) THEN
            idum1( 1 ) = ichar( 'L' )
         ELSE
            idum1( 1 ) = ichar( 'R' )
         END IF
         idum2( 1 ) = 1
         IF( notran ) THEN
            idum1( 2 ) = ichar( 'N' )
         ELSE
            idum1( 2 ) = ichar( 'C' )
         END IF
         idum2( 2 ) = 2
         idum1( 3 ) = k
         idum2( 3 ) = 5
         IF( lwork.EQ.-1 ) THEN
            idum1( 4 ) = -1
         ELSE
            idum1( 4 ) = 1
         END IF
         idum2( 4 ) = 16
         IF( left ) THEN
            CALL pchk2mat( k, 5, m, 3, ia, ja, desca, 9, m, 3, n, 4,
     $                     ic, jc, descc, 14, 4, idum1, idum2, info )
         ELSE
            CALL pchk2mat( k, 5, n, 4, ia, ja, desca, 9, m, 3, n, 4,
     $                     ic, jc, descc, 14, 4, idum1, idum2, info )
         END IF
      END IF
*
      IF( info.NE.0 ) THEN
         CALL pxerbla( ictxt, 'PZUNMRQ', -info )
         RETURN
      ELSE IF( lquery ) THEN
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( m.EQ.0 .OR. n.EQ.0 .OR. k.EQ.0 )
     $   RETURN
*
      CALL pb_topget( ictxt, 'Broadcast', 'Rowwise', rowbtop )
      CALL pb_topget( ictxt, 'Broadcast', 'Columnwise', colbtop )
*
      IF( ( left .AND. .NOT.notran ) .OR.
     $    ( .NOT.left .AND. notran ) ) THEN
         i1 = min( iceil( ia, desca( mb_ ) ) * desca( mb_ ), ia+k-1 )
     $                    + 1
         i2 = ia + k - 1
         i3 = desca( mb_ )
      ELSE
         i1 = max( ( (ia+k-2) / desca( mb_ ) ) * desca( mb_ ) + 1, ia )
         i2 = min( iceil( ia, desca( mb_ ) ) * desca( mb_ ), ia+k-1 )
     $                    + 1
         i3 = -desca( mb_ )
      END IF
*
      IF( left ) THEN
         ni = n
      ELSE
         mi = m
         CALL pb_topset( ictxt, 'Broadcast', 'Rowwise', ' ' )
         IF( notran ) THEN
            CALL pb_topset( ictxt, 'Broadcast', 'Columnwise', 'I-ring' )
         ELSE
            CALL pb_topset( ictxt, 'Broadcast', 'Columnwise', 'D-ring' )
         END IF
      END IF
*
      IF( notran ) THEN
         transt = 'C'
      ELSE
         transt = 'N'
      END IF
*
      IF( ( left .AND. .NOT.notran ) .OR.
     $    ( .NOT.left .AND. notran ) ) THEN
         ib = i1 - ia
         IF( left ) THEN
            mi = m - k + ib
         ELSE
            ni = n - k + ib
         END IF
         CALL pzunmr2( side, trans, mi, ni, ib, a, ia, ja, desca, tau,
     $                 c, ic, jc, descc, work, lwork, iinfo )
      END IF
*
      ipw = desca( mb_ )*desca( mb_ ) + 1
      DO 10 i = i1, i2, i3
         ib = min( desca( mb_ ), k-i+ia )
*
*        Form the triangular factor of the block reflector
*        H = H(i+ib-1) . . . H(i+1) H(i)
*
         CALL pzlarft( 'Backward', 'Rowwise', nq-k+i+ib-ia, ib,
     $                 a, i, ja, desca, tau, work, work( ipw ) )
         IF( left ) THEN
*
*           H or H' is applied to C(ic:ic+m-k+i+ib-ia-1,jc:jc+n-1)
*
            mi = m - k + i + ib - ia
         ELSE
*
*           H or H' is applied to C(ic:ic+m-1,jc:jc+n-k+i+ib-ia-1)
*
            ni = n - k + i + ib - ia
         END IF
*
*        Apply H or H'
*
         CALL pzlarfb( side, transt, 'Backward', 'Rowwise', mi, ni,
     $                ib, a, i, ja, desca, work, c, ic, jc, descc,
     $                work( ipw ) )
   10 CONTINUE
*
      IF( ( right .AND. tran ) .OR.
     $    ( left .AND. notran ) ) THEN
         ib = i2 - ia
         IF( left ) THEN
            mi = m - k + ib
         ELSE
            ni = n - k + ib
         END IF
         CALL pzunmr2( side, trans, mi, ni, ib, a, ia, ja, desca, tau,
     $                 c, ic, jc, descc, work, lwork, iinfo )
      END IF
*
      CALL pb_topset( ictxt, 'Broadcast', 'Rowwise', rowbtop )
      CALL pb_topset( ictxt, 'Broadcast', 'Columnwise', colbtop )
*
      work( 1 ) = dcmplx( dble( lwmin ) )
*
      RETURN
*
*     End of PZUNMRQ
*
      END