pcpotrrv.f

Go to the documentation of this file.

      SUBROUTINE pcpotrrv( UPLO, N, A, IA, JA, DESCA, WORK )
*
*  -- ScaLAPACK routine (version 1.7) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     May 28, 2001
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            IA, JA, N
*     ..
*     .. Array Arguments ..
      INTEGER            DESCA( * )
      COMPLEX            A( * ),  WORK( * )
*     ..
*
*  Purpose
*  =======
*
*  PCPOTRRV recomputes sub( A ) = A(IA:IA+N-1,JA:JA+N-1) from L or U
*  computed by PCPOTRF. The routine performs the Cholesky factorization
*  in reverse.
*
*  Notes
*  =====
*
*  Each global data object is described by an associated description
*  vector.  This vector stores the information required to establish
*  the mapping between an object element and its corresponding process
*  and memory location.
*
*  Let A be a generic term for any 2D block cyclicly distributed array.
*  Such a global array has an associated description vector DESCA.
*  In the following comments, the character _ should be read as
*  "of the global array".
*
*  NOTATION        STORED IN      EXPLANATION
*  --------------- -------------- --------------------------------------
*  DTYPE_A(global) DESCA( DTYPE_ )The descriptor type.  In this case,
*                                 DTYPE_A = 1.
*  CTXT_A (global) DESCA( CTXT_ ) The BLACS context handle, indicating
*                                 the BLACS process grid A is distribu-
*                                 ted over. The context itself is glo-
*                                 bal, but the handle (the integer
*                                 value) may vary.
*  M_A    (global) DESCA( M_ )    The number of rows in the global
*                                 array A.
*  N_A    (global) DESCA( N_ )    The number of columns in the global
*                                 array A.
*  MB_A   (global) DESCA( MB_ )   The blocking factor used to distribute
*                                 the rows of the array.
*  NB_A   (global) DESCA( NB_ )   The blocking factor used to distribute
*                                 the columns of the array.
*  RSRC_A (global) DESCA( RSRC_ ) The process row over which the first
*                                 row of the array A is distributed.
*  CSRC_A (global) DESCA( CSRC_ ) The process column over which the
*                                 first column of the array A is
*                                 distributed.
*  LLD_A  (local)  DESCA( LLD_ )  The leading dimension of the local
*                                 array.  LLD_A >= MAX(1,LOCr(M_A)).
*
*  Let K be the number of rows or columns of a distributed matrix,
*  and assume that its process grid has dimension p x q.
*  LOCr( K ) denotes the number of elements of K that a process
*  would receive if K were distributed over the p processes of its
*  process column.
*  Similarly, LOCc( K ) denotes the number of elements of K that a
*  process would receive if K were distributed over the q processes of
*  its process row.
*  The values of LOCr() and LOCc() may be determined via a call to the
*  ScaLAPACK tool function, NUMROC:
*          LOCr( M ) = NUMROC( M, MB_A, MYROW, RSRC_A, NPROW ),
*          LOCc( N ) = NUMROC( N, NB_A, MYCOL, CSRC_A, NPCOL ).
*  An upper bound for these quantities may be computed by:
*          LOCr( M ) <= ceil( ceil(M/MB_A)/NPROW )*MB_A
*          LOCc( N ) <= ceil( ceil(N/NB_A)/NPCOL )*NB_A
*
*  Arguments
*  =========
*
*  UPLO    (global input) CHARACTER
*          Specifies whether the upper or lower triangular part of the
*          hermitian distributed matrix sub( A ) is stored:
*          stored:
*          = 'U':  Upper triangular
*          = 'L':  Lower triangular
*
*  N       (global input) INTEGER
*          The number of rows and columns to be operated on, i.e. the
*          order of the distributed submatrix sub( A ). N >= 0.
*
*  A       (local input/local output) COMPLEX pointer into the
*          local memory to an array of dimension (LLD_A, LOCc(JA+N-1)).
*          On entry, the local pieces of the factors L or U of the
*          distributed matrix sub( A ) from the Cholesky factorization.
*          On exit, the original distributed matrix sub( A ) is
*          restored.
*
*  IA      (global input) INTEGER
*          The row index in the global array A indicating the first
*          row of sub( A ).
*
*  JA      (global input) INTEGER
*          The column index in the global array A indicating the
*          first column of sub( A ).
*
*  DESCA   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix A.
*
*  WORK    (local workspace) COMPLEX array, dimension (LWORK)
*          LWORK >= MB_A*NB_A.
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            BLOCK_CYCLIC_2D, CSRC_, CTXT_, DLEN_, DTYPE_,
     $                   LLD_, MB_, M_, NB_, N_, RSRC_
      parameter( block_cyclic_2d = 1, dlen_ = 9, dtype_ = 1,
     $                     ctxt_ = 2, m_ = 3, n_ = 4, mb_ = 5, nb_ = 6,
     $                     rsrc_ = 7, csrc_ = 8, lld_ = 9 )
      REAL               ONE
      parameter( one = 1.0e+0 )
      COMPLEX            CONE, ZERO
      parameter( cone = ( 1.0e+0, 0.0e+0 ),
     $                     zero = ( 0.0e+0, 0.0e+0 ) )
*     ..
*     .. Local Scalars ..
      LOGICAL            UPPER
      CHARACTER          COLBTOP, ROWBTOP
      INTEGER            IACOL, IAROW, ICTXT, IL, J, JB, JL, JN, MYCOL,
     $                   MYROW, NPCOL, NPROW
*     .. Local Arrays ..
      INTEGER            DESCW( DLEN_ )
*     ..
*     .. External Subroutines ..
      EXTERNAL           blacs_gridinfo, descset, pclacpy, pclaset,
     $                   pcherk, pctrmm, pb_topget, pb_topset
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      INTEGER            ICEIL, INDXG2P
      EXTERNAL           iceil, indxg2p, lsame
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          min, mod
*     ..
*     .. Executable Statements ..
*
*     Get grid parameters
*
      ictxt = desca( ctxt_ )
      CALL blacs_gridinfo( ictxt, nprow, npcol, myrow, mycol )
*
      CALL pb_topget( ictxt, 'Broadcast', 'Rowwise', rowbtop )
      CALL pb_topget( ictxt, 'Broadcast', 'Columnwise', colbtop )
*
      upper = lsame( uplo, 'U' )
      jn = min( iceil( ja, desca( nb_ ) ) * desca( nb_ ), ja+n-1 )
      jl = max( ( ( ja+n-2 ) / desca( nb_ ) ) * desca( nb_ ) + 1, ja )
      il = max( ( ( ia+n-2 ) / desca( mb_ ) ) * desca( mb_ ) + 1, ia )
      iarow = indxg2p( il, desca( mb_ ), myrow, desca( rsrc_ ), nprow )
      iacol = indxg2p( jl, desca( nb_ ), mycol, desca( csrc_ ), npcol )
*
*     Define array descriptor for working array WORK
*
      CALL descset( descw, desca( mb_ ), desca( nb_ ), desca( mb_ ),
     $              desca( nb_ ), iarow, iacol, ictxt, desca( mb_ ) )
*
      IF ( upper ) THEN
*
*       Compute A from the Cholesky factor U : A = U'*U.
*
        CALL pb_topset( ictxt, 'Broadcast', 'Rowwise', ' ' )
        CALL pb_topset( ictxt, 'Broadcast', 'Columnwise', 'S-ring' )
*
        DO 10 j = jl, jn+1, -desca( nb_ )
*
           jb = min( ja+n-j, desca( nb_ ) )
*
*          Update the trailing matrix, A = A + U'*U
*
           CALL pcherk( 'Upper', 'Conjugate Transpose', ja+n-j-jb, jb,
     $                  one, a, il, j+jb, desca, one, a, il+jb, j+jb,
     $                  desca )
*
*          Copy current diagonal block of A into workspace
*
           CALL pclacpy( 'All', jb, jb, a, il, j, desca, work, 1, 1,
     $                   descw )
*
*          Zero strict lower triangular part of diagonal block, to make
*          it U1.
*
           CALL pclaset( 'Lower', jb-1, jb, zero, zero, a, il+1, j,
     $                   desca )
*
*          Update the row panel U with the triangular matrix
*
           CALL pctrmm( 'Left', 'Upper', 'Conjugate Transpose',
     $                  'Non-Unit', jb, n-j+ja, cone, work, 1, 1,
     $                  descw, a, il, j, desca )
*
*          Restore the strict lower triangular part of diagonal block.
*
           CALL pclacpy( 'Lower', jb-1, jb, work, 2, 1, descw, a,
     $                    il+1, j, desca )
*
           il = il - desca( mb_ )
           descw( rsrc_ ) = mod( descw( rsrc_ ) + nprow - 1, nprow )
           descw( csrc_ ) = mod( descw( csrc_ ) + npcol - 1, npcol )
*
   10   CONTINUE
*
*       Handle first block separately
*
        jb = min( jn-ja+1, desca( nb_ ) )
*
*       Update the trailing matrix, A = A + U'*U
*
        CALL pcherk( 'Upper', 'Conjugate Transpose', n-jb, jb, one, a,
     $               ia, ja+jb, desca, one, a, ia+jb, ja+jb, desca )
*
*       Copy current diagonal block of A into workspace
*
        CALL pclacpy( 'All', jb, jb, a, ia, ja, desca, work, 1, 1,
     $                descw )
*
*       Zero strict lower triangular part of diagonal block, to make
*       it U1.
*
        CALL pclaset( 'Lower', jb-1, jb, zero, zero, a, ia+1, ja,
     $                desca )
*
*       Update the row panel U with the triangular matrix
*
        CALL pctrmm( 'Left', 'Upper', 'Conjugate Transpose', 'Non-Unit',
     $               jb, n, cone, work, 1, 1, descw, a, ia, ja, desca )
*
*       Restore the strict lower triangular part of diagonal block.
*
        CALL pclacpy( 'Lower', jb-1, jb, work, 2, 1, descw, a, ia+1,
     $                ja, desca )
*
      ELSE
*
*       Compute A from the Cholesky factor L : A = L*L'.
*
        CALL pb_topset( ictxt, 'Broadcast', 'Rowwise', 'S-ring' )
        CALL pb_topset( ictxt, 'Broadcast', 'Columnwise', ' ' )
*
        DO 20 j = jl, jn+1, -desca( nb_ )
*
           jb = min( ja+n-j, desca( nb_ ) )
*
*          Update the trailing matrix, A = A + L*L'
*
           CALL pcherk( 'Lower', 'No Transpose', ia+n-il-jb, jb, one, a,
     $                  il+jb, j, desca, one, a, il+jb, j+jb, desca )
*
*          Copy current diagonal block of A into workspace
*
           CALL pclacpy( 'All', jb, jb, a, il, j, desca, work, 1, 1,
     $                   descw )
*
*          Zero strict upper triangular part of diagonal block, to make
*          it L1.
*
           CALL pclaset( 'Upper', jb, jb-1, zero, zero, a, il, j+1,
     $                   desca )
*
*          Update the column panel L with the triangular matrix
*
           CALL pctrmm( 'Right', 'Lower', 'Conjugate transpose',
     $                   'Non-Unit', ia+n-il, jb, cone, work, 1, 1,
     $                   descw, a, il, j, desca )
*
*          Restore the strict upper triangular part of diagonal block.
*
           CALL pclacpy( 'Upper', jb, jb-1, work, 1, 2, descw, a,
     $                   il, j+1, desca )
*
           il = il - desca( mb_ )
           descw( rsrc_ ) = mod( descw( rsrc_ ) + nprow - 1, nprow )
           descw( csrc_ ) = mod( descw( csrc_ ) + npcol - 1, npcol )
*
   20   CONTINUE
*
*       Handle first block separately
*
        jb = min( jn-ja+1, desca( nb_ ) )
*
*       Update the trailing matrix, A = A + L*L'
*
        CALL pcherk( 'Lower', 'No Transpose', n-jb, jb, one, a,
     $               ia+jb, ja, desca, one, a, ia+jb, ja+jb, desca )
*
*       Copy current diagonal block of A into workspace
*
        CALL pclacpy( 'All', jb, jb, a, ia, ja, desca, work, 1, 1,
     $                descw )
*
*       Zero strict upper triangular part of diagonal block, to make
*       it L1.
*
        CALL pclaset( 'Upper', jb, jb-1, zero, zero, a, ia, ja+1,
     $                desca )
*
*       Update the column panel L with the triangular matrix
*
        CALL pctrmm( 'Right', 'Lower', 'Conjugate transpose',
     $                'Non-Unit', n, jb, cone, work, 1, 1, descw, a,
     $                ia, ja, desca )
*
*       Restore the strict upper triangular part of diagonal block.
*
        CALL pclacpy( 'Upper', jb, jb-1, work, 1, 2, descw, a, ia,
     $                ja+1, desca )
*
      END IF
*
      CALL pb_topset( ictxt, 'Broadcast', 'Rowwise', rowbtop )
      CALL pb_topset( ictxt, 'Broadcast', 'Columnwise', colbtop )
*
      RETURN
*
*     End of PCPOTRRV
*
      END