pdormbr.f

Go to the documentation of this file.

      SUBROUTINE pdormbr( VECT, SIDE, TRANS, M, N, K, A, IA, JA, DESCA,
     $                    TAU, C, IC, JC, DESCC, WORK, LWORK, INFO )
*
*  -- ScaLAPACK routine (version 1.7) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     May 1, 1997
*
*     .. Scalar Arguments ..
      CHARACTER          SIDE, TRANS, VECT
      INTEGER            IA, IC, INFO, JA, JC, K, LWORK, M, N
*     ..
*     .. Array Arguments ..
      INTEGER            DESCA( * ), DESCC( * )
      DOUBLE PRECISION   A( * ), C( * ), TAU( * ), WORK( * )
*     ..
*
*  Purpose
*  =======
*
*  If VECT = 'Q', PDORMBR overwrites the general real distributed M-by-N
*  matrix sub( C ) = C(IC:IC+M-1,JC:JC+N-1) with
*
*                       SIDE = 'L'           SIDE = 'R'
*  TRANS = 'N':      Q * sub( C )          sub( C ) * Q
*  TRANS = 'T':      Q**T * sub( C )       sub( C ) * Q**T
*
*  If VECT = 'P', PDORMBR overwrites sub( C ) with
*
*                       SIDE = 'L'           SIDE = 'R'
*  TRANS = 'N':      P * sub( C )          sub( C ) * P
*  TRANS = 'T':      P**T * sub( C )       sub( C ) * P**T
*
*  Here Q and P**T are the orthogonal distributed matrices determined by
*  PDGEBRD when reducing a real distributed matrix A(IA:*,JA:*) to
*  bidiagonal form: A(IA:*,JA:*) = Q * B * P**T. Q and P**T are defined
*  as products of elementary reflectors H(i) and G(i) respectively.
*
*  Let nq = m if SIDE = 'L' and nq = n if SIDE = 'R'. Thus nq is the
*  order of the orthogonal matrix Q or P**T that is applied.
*
*  If VECT = 'Q', A(IA:*,JA:*) is assumed to have been an NQ-by-K
*  matrix:
*  if nq >= k, Q = H(1) H(2) . . . H(k);
*  if nq < k, Q = H(1) H(2) . . . H(nq-1).
*
*  If VECT = 'P', A(IA:*,JA:*) is assumed to have been a K-by-NQ
*  matrix:
*  if k < nq, P = G(1) G(2) . . . G(k);
*  if k >= nq, P = G(1) G(2) . . . G(nq-1).
*
*  Notes
*  =====
*
*  Each global data object is described by an associated description
*  vector.  This vector stores the information required to establish
*  the mapping between an object element and its corresponding process
*  and memory location.
*
*  Let A be a generic term for any 2D block cyclicly distributed array.
*  Such a global array has an associated description vector DESCA.
*  In the following comments, the character _ should be read as
*  "of the global array".
*
*  NOTATION        STORED IN      EXPLANATION
*  --------------- -------------- --------------------------------------
*  DTYPE_A(global) DESCA( DTYPE_ )The descriptor type.  In this case,
*                                 DTYPE_A = 1.
*  CTXT_A (global) DESCA( CTXT_ ) The BLACS context handle, indicating
*                                 the BLACS process grid A is distribu-
*                                 ted over. The context itself is glo-
*                                 bal, but the handle (the integer
*                                 value) may vary.
*  M_A    (global) DESCA( M_ )    The number of rows in the global
*                                 array A.
*  N_A    (global) DESCA( N_ )    The number of columns in the global
*                                 array A.
*  MB_A   (global) DESCA( MB_ )   The blocking factor used to distribute
*                                 the rows of the array.
*  NB_A   (global) DESCA( NB_ )   The blocking factor used to distribute
*                                 the columns of the array.
*  RSRC_A (global) DESCA( RSRC_ ) The process row over which the first
*                                 row of the array A is distributed.
*  CSRC_A (global) DESCA( CSRC_ ) The process column over which the
*                                 first column of the array A is
*                                 distributed.
*  LLD_A  (local)  DESCA( LLD_ )  The leading dimension of the local
*                                 array.  LLD_A >= MAX(1,LOCr(M_A)).
*
*  Let K be the number of rows or columns of a distributed matrix,
*  and assume that its process grid has dimension p x q.
*  LOCr( K ) denotes the number of elements of K that a process
*  would receive if K were distributed over the p processes of its
*  process column.
*  Similarly, LOCc( K ) denotes the number of elements of K that a
*  process would receive if K were distributed over the q processes of
*  its process row.
*  The values of LOCr() and LOCc() may be determined via a call to the
*  ScaLAPACK tool function, NUMROC:
*          LOCr( M ) = NUMROC( M, MB_A, MYROW, RSRC_A, NPROW ),
*          LOCc( N ) = NUMROC( N, NB_A, MYCOL, CSRC_A, NPCOL ).
*  An upper bound for these quantities may be computed by:
*          LOCr( M ) <= ceil( ceil(M/MB_A)/NPROW )*MB_A
*          LOCc( N ) <= ceil( ceil(N/NB_A)/NPCOL )*NB_A
*
*  Arguments
*  =========
*
*  VECT    (global input) CHARACTER
*          = 'Q': apply Q or Q**T;
*          = 'P': apply P or P**T.
*
*  SIDE    (global input) CHARACTER
*          = 'L': apply Q, Q**T, P or P**T from the Left;
*          = 'R': apply Q, Q**T, P or P**T from the Right.
*
*  TRANS   (global input) CHARACTER
*          = 'N':  No transpose, apply Q or P;
*          = 'T':  Transpose, apply Q**T or P**T.
*
*  M       (global input) INTEGER
*          The number of rows to be operated on i.e the number of rows
*          of the distributed submatrix sub( C ). M >= 0.
*
*  N       (global input) INTEGER
*          The number of columns to be operated on i.e the number of
*          columns of the distributed submatrix sub( C ). N >= 0.
*
*  K       (global input) INTEGER
*          If VECT = 'Q', the number of columns in the original
*          distributed matrix reduced by PDGEBRD.
*          If VECT = 'P', the number of rows in the original
*          distributed matrix reduced by PDGEBRD.
*          K >= 0.
*
*  A       (local input) DOUBLE PRECISION pointer into the local memory
*          to an array of dimension (LLD_A,LOCc(JA+MIN(NQ,K)-1)) if
*          VECT='Q', and (LLD_A,LOCc(JA+NQ-1)) if VECT = 'P'. NQ = M
*          if SIDE = 'L', and NQ = N otherwise. The vectors which
*          define the elementary reflectors H(i) and G(i), whose
*          products determine the matrices Q and P, as returned by
*          PDGEBRD.
*          If VECT = 'Q', LLD_A >= max(1,LOCr(IA+NQ-1));
*          if VECT = 'P', LLD_A >= max(1,LOCr(IA+MIN(NQ,K)-1)).
*
*  IA      (global input) INTEGER
*          The row index in the global array A indicating the first
*          row of sub( A ).
*
*  JA      (global input) INTEGER
*          The column index in the global array A indicating the
*          first column of sub( A ).
*
*  DESCA   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix A.
*
*  TAU     (local input) DOUBLE PRECISION array, dimension
*          LOCc(JA+MIN(NQ,K)-1) if VECT = 'Q', LOCr(IA+MIN(NQ,K)-1) if
*          VECT = 'P', TAU(i) must contain the scalar factor of the
*          elementary  reflector H(i) or G(i), which determines Q or P,
*          as returned by PDGEBRD in its array argument TAUQ or TAUP.
*          TAU is tied to the distributed matrix A.
*
*  C       (local input/local output) DOUBLE PRECISION pointer into the
*          local memory to an array of dimension (LLD_C,LOCc(JC+N-1)).
*          On entry, the local pieces of the distributed matrix sub(C).
*          On exit, if VECT='Q', sub( C ) is overwritten by Q*sub( C )
*          or Q'*sub( C ) or sub( C )*Q' or sub( C )*Q; if VECT='P,
*          sub( C ) is overwritten by P*sub( C ) or P'*sub( C ) or
*          sub( C )*P or sub( C )*P'.
*
*  IC      (global input) INTEGER
*          The row index in the global array C indicating the first
*          row of sub( C ).
*
*  JC      (global input) INTEGER
*          The column index in the global array C indicating the
*          first column of sub( C ).
*
*  DESCC   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix C.
*
*  WORK    (local workspace/local output) DOUBLE PRECISION array,
*                                                     dimension (LWORK)
*          On exit, WORK(1) returns the minimal and optimal LWORK.
*
*  LWORK   (local or global input) INTEGER
*          The dimension of the array WORK.
*          LWORK is local input and must be at least
*          If SIDE = 'L',
*            NQ = M;
*            if( (VECT = 'Q' and NQ >= K) or (VECT <> 'Q' and NQ > K) ),
*               IAA=IA; JAA=JA; MI=M; NI=N; ICC=IC; JCC=JC;
*            else
*               IAA=IA+1; JAA=JA; MI=M-1; NI=N; ICC=IC+1; JCC=JC;
*            end if
*          else if SIDE = 'R',
*            NQ = N;
*            if( (VECT = 'Q' and NQ >= K) or (VECT <> 'Q' and NQ > K) ),
*               IAA=IA; JAA=JA; MI=M; NI=N; ICC=IC; JCC=JC;
*            else
*               IAA=IA; JAA=JA+1; MI=M; NI=N-1; ICC=IC; JCC=JC+1;
*            end if
*          end if
*
*          If VECT = 'Q',
*            If SIDE = 'L',
*              LWORK >= MAX( (NB_A*(NB_A-1))/2, (NqC0 + MpC0)*NB_A ) +
*                       NB_A * NB_A
*            else if SIDE = 'R',
*              LWORK >= MAX( (NB_A*(NB_A-1))/2, ( NqC0 + MAX( NpA0 +
*                       NUMROC( NUMROC( NI+ICOFFC, NB_A, 0, 0, NPCOL ),
*                               NB_A, 0, 0, LCMQ ), MpC0 ) )*NB_A ) +
*                       NB_A * NB_A
*            end if
*          else if VECT <> 'Q',
*            if SIDE = 'L',
*              LWORK >= MAX( (MB_A*(MB_A-1))/2, ( MpC0 + MAX( MqA0 +
*                       NUMROC( NUMROC( MI+IROFFC, MB_A, 0, 0, NPROW ),
*                               MB_A, 0, 0, LCMP ), NqC0 ) )*MB_A ) +
*                       MB_A * MB_A
*            else if SIDE = 'R',
*              LWORK >= MAX( (MB_A*(MB_A-1))/2, (MpC0 + NqC0)*MB_A ) +
*                       MB_A * MB_A
*            end if
*          end if
*
*          where LCMP = LCM / NPROW, LCMQ = LCM / NPCOL, with
*          LCM = ICLM( NPROW, NPCOL ),
*
*          IROFFA = MOD( IAA-1, MB_A ), ICOFFA = MOD( JAA-1, NB_A ),
*          IAROW = INDXG2P( IAA, MB_A, MYROW, RSRC_A, NPROW ),
*          IACOL = INDXG2P( JAA, NB_A, MYCOL, CSRC_A, NPCOL ),
*          MqA0 = NUMROC( MI+ICOFFA, NB_A, MYCOL, IACOL, NPCOL ),
*          NpA0 = NUMROC( NI+IROFFA, MB_A, MYROW, IAROW, NPROW ),
*
*          IROFFC = MOD( ICC-1, MB_C ), ICOFFC = MOD( JCC-1, NB_C ),
*          ICROW = INDXG2P( ICC, MB_C, MYROW, RSRC_C, NPROW ),
*          ICCOL = INDXG2P( JCC, NB_C, MYCOL, CSRC_C, NPCOL ),
*          MpC0 = NUMROC( MI+IROFFC, MB_C, MYROW, ICROW, NPROW ),
*          NqC0 = NUMROC( NI+ICOFFC, NB_C, MYCOL, ICCOL, NPCOL ),
*
*          INDXG2P and NUMROC are ScaLAPACK tool functions;
*          MYROW, MYCOL, NPROW and NPCOL can be determined by calling
*          the subroutine BLACS_GRIDINFO.
*
*          If LWORK = -1, then LWORK is global input and a workspace
*          query is assumed; the routine only calculates the minimum
*          and optimal size for all work arrays. Each of these
*          values is returned in the first entry of the corresponding
*          work array, and no error message is issued by PXERBLA.
*
*
*  INFO    (global output) INTEGER
*          = 0:  successful exit
*          < 0:  If the i-th argument is an array and the j-entry had
*                an illegal value, then INFO = -(i*100+j), if the i-th
*                argument is a scalar and had an illegal value, then
*                INFO = -i.
*
*  Alignment requirements
*  ======================
*
*  The distributed submatrices A(IA:*, JA:*) and C(IC:IC+M-1,JC:JC+N-1)
*  must verify some alignment properties, namely the following
*  expressions should be true:
*
*  If VECT = 'Q',
*    If SIDE = 'L',
*      ( MB_A.EQ.MB_C .AND. IROFFA.EQ.IROFFC .AND. IAROW.EQ.ICROW )
*     If SIDE = 'R',
*      ( MB_A.EQ.NB_C .AND. IROFFA.EQ.ICOFFC )
*  else
*     If SIDE = 'L',
*       ( MB_A.EQ.MB_C .AND. ICOFFA.EQ.IROFFC )
*     If SIDE = 'R',
*       ( NB_A.EQ.NB_C .AND. ICOFFA.EQ.ICOFFC .AND. IACOL.EQ.ICCOL )
*  end if
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            BLOCK_CYCLIC_2D, CSRC_, CTXT_, DLEN_, DTYPE_,
     $                   lld_, mb_, m_, nb_, n_, rsrc_
      parameter( block_cyclic_2d = 1, dlen_ = 9, dtype_ = 1,
     $                     ctxt_ = 2, m_ = 3, n_ = 4, mb_ = 5, nb_ = 6,
     $                     rsrc_ = 7, csrc_ = 8, lld_ = 9 )
*     ..
*     .. Local Scalars ..
      LOGICAL            APPLYQ, LEFT, LQUERY, NOTRAN
      CHARACTER          TRANST
      INTEGER            IAA, IACOL, IAROW, ICC, ICCOL, ICOFFA, ICOFFC,
     $                   icrow, ictxt, iinfo, iroffa, iroffc, jaa, jcc,
     $                   lcm, lcmp, lcmq, lwmin, mi, mpc0, mqa0, mycol,
     $                   myrow, ni, npa0, npcol, nprow, nq, nqc0
*     ..
*     .. Local Arrays ..
      INTEGER            IDUM1( 5 ), IDUM2( 5 )
*     ..
*     .. External Subroutines ..
      EXTERNAL           blacs_gridinfo, chk1mat, pchk2mat, pdormlq,
     $                   pdormqr, pxerbla
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      INTEGER            ILCM, INDXG2P, NUMROC
      EXTERNAL           ilcm, indxg2p, lsame, numroc
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble, ichar, max, mod
*     ..
*     .. Executable Statements ..
*
*     Get grid parameters
*
      ictxt = desca( ctxt_ )
      CALL blacs_gridinfo( ictxt, nprow, npcol, myrow, mycol )
*
*     Test the input parameters
*
      info = 0
      IF( nprow.EQ.-1 ) THEN
         info = -(1000+ctxt_)
      ELSE
         applyq = lsame( vect, 'Q' )
         left = lsame( side, 'L' )
         notran = lsame( trans, 'N' )
*
*        NQ is the order of Q or P
*
         IF( left ) THEN
            nq = m
            IF( ( applyq .AND. nq.GE.k ) .OR.
     $          ( .NOT.applyq .AND. nq.GT.k ) ) THEN
               iaa = ia
               jaa = ja
               mi = m
               ni = n
               icc = ic
               jcc = jc
            ELSE
               iaa = ia + 1
               jaa = ja
               mi = m - 1
               ni = n
               icc = ic + 1
               jcc = jc
            END IF
*
            IF( applyq ) THEN
               CALL chk1mat( m, 4, k, 6, ia, ja, desca, 10, info )
            ELSE
               CALL chk1mat( k, 6, m, 4, ia, ja, desca, 10, info )
            END IF
         ELSE
            nq = n
            IF( ( applyq .AND. nq.GE.k ) .OR.
     $          ( .NOT.applyq .AND. nq.GT.k ) ) THEN
               iaa = ia
               jaa = ja
               mi = m
               ni = n
               icc = ic
               jcc = jc
            ELSE
               iaa = ia
               jaa = ja + 1
               mi = m
               ni = n - 1
               icc = ic
               jcc = jc + 1
            END IF
*
            IF( applyq ) THEN
               CALL chk1mat( n, 5, k, 6, ia, ja, desca, 10, info )
            ELSE
               CALL chk1mat( k, 6, n, 5, ia, ja, desca, 10, info )
            END IF
         END IF
         CALL chk1mat( m, 4, n, 5, ic, jc, descc, 15, info )
*
         IF( info.EQ.0 ) THEN
            iroffa = mod( iaa-1, desca( mb_ ) )
            icoffa = mod( jaa-1, desca( nb_ ) )
            iroffc = mod( icc-1, descc( mb_ ) )
            icoffc = mod( jcc-1, descc( nb_ ) )
            iacol = indxg2p( jaa, desca( nb_ ), mycol, desca( csrc_ ),
     $                       npcol )
            iarow = indxg2p( iaa, desca( mb_ ), myrow, desca( rsrc_ ),
     $                       nprow )
            icrow = indxg2p( icc, descc( mb_ ), myrow, descc( rsrc_ ),
     $                       nprow )
            iccol = indxg2p( jcc, descc( nb_ ), mycol, descc( csrc_ ),
     $                       npcol )
            mpc0 = numroc( mi+iroffc, descc( mb_ ), myrow, icrow,
     $                     nprow )
            nqc0 = numroc( ni+icoffc, descc( nb_ ), mycol, iccol,
     $                     npcol )
*
            IF( applyq ) THEN
               IF( left ) THEN
                  lwmin = max( ( desca( nb_ ) * ( desca( nb_ ) - 1 ) )
     $                    / 2, ( mpc0 + nqc0 ) * desca( nb_ ) ) +
     $                    desca( nb_ ) * desca( nb_ )
               ELSE
                  npa0 = numroc( ni+iroffa, desca( mb_ ), myrow, iarow,
     $                           nprow )
                  lcm = ilcm( nprow, npcol )
                  lcmq = lcm / npcol
                  lwmin =  max( ( desca( nb_ ) * ( desca( nb_ ) - 1 ) )
     $                     / 2, ( nqc0 + max( npa0 + numroc( numroc(
     $                     ni+icoffc, desca( nb_ ), 0, 0, npcol ),
     $                     desca( nb_ ), 0, 0, lcmq ), mpc0 ) ) *
     $                     desca( nb_ ) ) + desca( nb_ ) * desca( nb_ )
               END IF
            ELSE
*
               IF( left ) THEN
                  mqa0 = numroc( mi+icoffa, desca( nb_ ), mycol, iacol,
     $                           npcol )
                  lcm = ilcm( nprow, npcol )
                  lcmp = lcm / nprow
                  lwmin =  max( ( desca( mb_ ) * ( desca( mb_ ) - 1 ) )
     $                     / 2, ( mpc0 + max( mqa0 + numroc( numroc(
     $                     mi+iroffc, desca( mb_ ), 0, 0, nprow ),
     $                     desca( mb_ ), 0, 0, lcmp ), nqc0 ) ) *
     $                     desca( mb_ ) ) + desca( mb_ ) * desca( mb_ )
               ELSE
                  lwmin = max( ( desca( mb_ ) * ( desca( mb_ ) - 1 ) )
     $                    / 2, ( mpc0 + nqc0 ) * desca( mb_ ) ) +
     $                    desca( mb_ ) * desca( mb_ )
               END IF
*
            END IF
*
            work( 1 ) = dble( lwmin )
            lquery = ( lwork.EQ.-1 )
            IF( .NOT.applyq .AND. .NOT.lsame( vect, 'P' ) ) THEN
               info = -1
            ELSE IF( .NOT.left .AND. .NOT.lsame( side, 'R' ) ) THEN
               info = -2
            ELSE IF( .NOT.notran .AND. .NOT.lsame( trans, 'T' ) ) THEN
               info = -3
            ELSE IF( k.LT.0 ) THEN
               info = -6
            ELSE IF( applyq .AND. .NOT.left .AND.
     $               desca( mb_ ).NE.descc( nb_ ) ) THEN
               info = -(1000+nb_)
            ELSE IF( applyq .AND. left .AND. iroffa.NE.iroffc ) THEN
               info = -13
            ELSE IF( applyq .AND. left .AND. iarow.NE.icrow ) THEN
               info = -13
            ELSE IF( .NOT.applyq .AND. left .AND.
     $               icoffa.NE.iroffc ) THEN
               info = -13
            ELSE IF( .NOT.applyq .AND. .NOT.left .AND.
     $               iacol.NE.iccol ) THEN
               info = -14
            ELSE IF( applyq .AND. .NOT.left .AND.
     $               iroffa.NE.icoffc ) THEN
               info = -14
            ELSE IF( .NOT.applyq .AND. .NOT.left .AND.
     $               icoffa.NE.icoffc ) THEN
               info = -14
            ELSE IF( applyq .AND. left .AND.
     $               desca( mb_ ).NE.descc( mb_ ) ) THEN
               info = -(1500+mb_)
            ELSE IF( .NOT.applyq .AND. left .AND.
     $               desca( mb_ ).NE.descc( mb_ ) ) THEN
               info = -(1500+mb_)
            ELSE IF( applyq .AND. .NOT.left .AND.
     $               desca( mb_ ).NE.descc( nb_ ) ) THEN
               info = -(1500+nb_)
            ELSE IF( .NOT.applyq .AND. .NOT.left .AND.
     $               desca( nb_ ).NE.descc( nb_ ) ) THEN
               info = -(1500+nb_)
            ELSE IF( lwork.LT.lwmin .AND. .NOT.lquery ) THEN
               info = -17
            END IF
         END IF
*
         IF( applyq ) THEN
            idum1( 1 ) = ichar( 'Q' )
         ELSE
            idum1( 1 ) = ichar( 'P' )
         END IF
         idum2( 1 ) = 1
         IF( left ) THEN
            idum1( 2 ) = ichar( 'L' )
         ELSE
            idum1( 2 ) = ichar( 'R' )
         END IF
         idum2( 2 ) = 2
         IF( notran ) THEN
            idum1( 3 ) = ichar( 'N' )
         ELSE
            idum1( 3 ) = ichar( 'T' )
         END IF
         idum2( 3 ) = 3
         idum1( 4 ) = k
         idum2( 4 ) = 6
         IF( lwork.EQ.-1 ) THEN
            idum1( 5 ) = -1
         ELSE
            idum1( 5 ) = 1
         END IF
         idum2( 5 ) = 17
         IF( applyq ) THEN
            IF( left ) THEN
               CALL pchk2mat( m, 4, k, 6, ia, ja, desca, 10, m, 4, n,
     $                        5, ic, jc, descc, 15, 5, idum1, idum2,
     $                        info )
            ELSE
               CALL pchk2mat( n, 5, k, 6, ia, ja, desca, 10, m, 4, n,
     $                        5, ic, jc, descc, 15, 5, idum1, idum2,
     $                        info )
            END IF
         ELSE
            IF( left ) THEN
               CALL pchk2mat( k, 6, m, 4, ia, ja, desca, 10, m, 4, n,
     $                        5, ic, jc, descc, 15, 5, idum1, idum2,
     $                        info )
            ELSE
               CALL pchk2mat( k, 6, n, 5, ia, ja, desca, 10, m, 4, n,
     $                        5, ic, jc, descc, 15, 5, idum1, idum2,
     $                        info )
            END IF
         END IF
      END IF
*
      IF( info.NE.0 ) THEN
         CALL pxerbla( ictxt, 'PDORMBR', -info )
         RETURN
      ELSE IF( lquery ) THEN
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( m.EQ.0 .OR. n.EQ.0 )
     $   RETURN
*
      IF( applyq ) THEN
*
*        Apply Q
*
         IF( nq.GE.k ) THEN
*
*           Q was determined by a call to PDGEBRD with nq >= k
*
            CALL pdormqr( side, trans, m, n, k, a, ia, ja, desca, tau,
     $                    c, ic, jc, descc, work, lwork, iinfo )
         ELSE IF( nq.GT.1 ) THEN
*
*           Q was determined by a call to PDGEBRD with nq < k
*
            CALL pdormqr( side, trans, mi, ni, nq-1, a, ia+1, ja, desca,
     $                    tau, c, icc, jcc, descc, work, lwork, iinfo )
         END IF
      ELSE
*
*        Apply P
*
         IF( notran ) THEN
            transt = 'T'
         ELSE
            transt = 'N'
         END IF
         IF( nq.GT.k ) THEN
*
*           P was determined by a call to PDGEBRD with nq > k
*
            CALL pdormlq( side, transt, m, n, k, a, ia, ja, desca, tau,
     $                    c, ic, jc, descc, work, lwork, iinfo )
         ELSE IF( nq.GT.1 ) THEN
*
*           P was determined by a call to PDGEBRD with nq <= k
*
            CALL pdormlq( side, transt, mi, ni, nq-1, a, ia, ja+1,
     $                    desca, tau, c, icc, jcc, descc, work, lwork,
     $                    iinfo )
         END IF
      END IF
*
      work( 1 ) = dble( lwmin )
*
      RETURN
*
*     End of PDORMBR
*
      END