pcgetrrv.f

Go to the documentation of this file.

      SUBROUTINE pcgetrrv( M, N, A, IA, JA, DESCA, IPIV, WORK )
*
*  -- ScaLAPACK routine (version 1.7) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     May 28, 2001
*
*     .. Scalar Arguments ..
      INTEGER            IA, JA, M, N
*     ..
*     .. Array Arguments ..
      INTEGER            DESCA( * ), IPIV( * )
      COMPLEX            A( * ), WORK( * )
*     ..
*
*  Purpose
*  =======
*
*  PCGETRRV reforms sub( A ) = A(IA:IA+M-1,JA:JA+N-1) from the
*  triangular matrices L and U returned by PCGETRF.  It multiplies
*  an upper triangular matrix stored in the upper triangle of sub( A )
*  times the unit lower triangular matrix stored in the lower triangle.
*  To accomplish this, the routine basically performs the PCGETRF
*  routine in reverse.
*
*  It computes L*U first, and then apply P: P*L*U => sub( A ). In the
*  J-th loop, the block column (or column panel), which has the lower
*  triangular unit matrix L is multiplied with the block row (or row
*  panel), which contains the upper triangular matrix U.
*
*                     ( L1 )             ( 0  0 )   ( L1*U1   L1*U2   )
*   A` = L * U + A` = (    ) * (U1 U2) + (      ) = (                 )
*                     ( L2 )             ( 0  A`)   ( L2*U1  L2*U2+A` )
*
*  where L1 is a lower unit triangular matrix and U1 is an upper
*  triangular matrix.
*
*  Notes
*  =====
*
*  Each global data object is described by an associated description
*  vector.  This vector stores the information required to establish
*  the mapping between an object element and its corresponding process
*  and memory location.
*
*  Let A be a generic term for any 2D block cyclicly distributed array.
*  Such a global array has an associated description vector DESCA.
*  In the following comments, the character _ should be read as
*  "of the global array".
*
*  NOTATION        STORED IN      EXPLANATION
*  --------------- -------------- --------------------------------------
*  DTYPE_A(global) DESCA( DTYPE_ )The descriptor type.  In this case,
*                                 DTYPE_A = 1.
*  CTXT_A (global) DESCA( CTXT_ ) The BLACS context handle, indicating
*                                 the BLACS process grid A is distribu-
*                                 ted over. The context itself is glo-
*                                 bal, but the handle (the integer
*                                 value) may vary.
*  M_A    (global) DESCA( M_ )    The number of rows in the global
*                                 array A.
*  N_A    (global) DESCA( N_ )    The number of columns in the global
*                                 array A.
*  MB_A   (global) DESCA( MB_ )   The blocking factor used to distribute
*                                 the rows of the array.
*  NB_A   (global) DESCA( NB_ )   The blocking factor used to distribute
*                                 the columns of the array.
*  RSRC_A (global) DESCA( RSRC_ ) The process row over which the first
*                                 row of the array A is distributed.
*  CSRC_A (global) DESCA( CSRC_ ) The process column over which the
*                                 first column of the array A is
*                                 distributed.
*  LLD_A  (local)  DESCA( LLD_ )  The leading dimension of the local
*                                 array.  LLD_A >= MAX(1,LOCr(M_A)).
*
*  Let K be the number of rows or columns of a distributed matrix,
*  and assume that its process grid has dimension p x q.
*  LOCr( K ) denotes the number of elements of K that a process
*  would receive if K were distributed over the p processes of its
*  process column.
*  Similarly, LOCc( K ) denotes the number of elements of K that a
*  process would receive if K were distributed over the q processes of
*  its process row.
*  The values of LOCr() and LOCc() may be determined via a call to the
*  ScaLAPACK tool function, NUMROC:
*          LOCr( M ) = NUMROC( M, MB_A, MYROW, RSRC_A, NPROW ),
*          LOCc( N ) = NUMROC( N, NB_A, MYCOL, CSRC_A, NPCOL ).
*  An upper bound for these quantities may be computed by:
*          LOCr( M ) <= ceil( ceil(M/MB_A)/NPROW )*MB_A
*          LOCc( N ) <= ceil( ceil(N/NB_A)/NPCOL )*NB_A
*
*  Arguments
*  =========
*
*  M       (global input) INTEGER
*          The number of rows to be operated on, i.e. the number of rows
*          of the distributed submatrix sub( A ). M >= 0.
*
*  N       (global input) INTEGER
*          The number of columns to be operated on, i.e. the number of
*          columns of the distributed submatrix sub( A ). N >= 0.
*
*  A       (local input/local output) COMPLEX pointer into the
*          local memory to an array of dimension (LLD_A, LOCc(JA+N-1)).
*          On entry, the local pieces of the distributed matrix sub( A )
*          contains the the factors L and U from the factorization
*          sub( A ) = P*L*U; the unit diagonal elements of L are not
*          stored. On exit, the original distributed matrix sub( A )
*          is restored.
*
*  IA      (global input) INTEGER
*          The row index in the global array A indicating the first
*          row of sub( A ).
*
*  JA      (global input) INTEGER
*          The column index in the global array A indicating the
*          first column of sub( A ).
*
*  DESCA   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix A.
*
*  IPIV    (local input) INTEGER array, dimension ( LOCr(M_A)+MB_A )
*          This array contains the pivoting information.
*          IPIV(i) -> The global row local row i was swapped with.
*          This array is tied to the distributed matrix A.
*
*  WORK    (local workspace) COMPLEX array of dimension (LWORK)
*          LWORK >= MpA0 * NB_A + NqA0 * MB_A, where
*
*          IROFFA = MOD( IA-1, MB_A ), ICOFFA = MOD( JA-1, NB_A ),
*          IAROW = INDXG2P( IA, MB_A, MYROW, RSRC_A, NPROW ),
*          IACOL = INDXG2P( JA, NB_A, MYCOL, CSRC_A, NPCOL ),
*          MpA0 = NUMROC( M+IROFFA, MB_A, MYROW, IAROW, NPROW ),
*          NqA0 = NUMROC( N+ICOFFA, NB_A, MYCOL, IACOL, NPCOL ),
*
*          WORK is used to store a block of columns of L, and a block of
*          rows of U. INDXG2P and NUMROC are ScaLAPACK tool functions;
*          MYROW, MYCOL, NPROW and NPCOL can be determined by calling
*          the subroutine BLACS_GRIDINFO.
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            BLOCK_CYCLIC_2D, CSRC_, CTXT_, DLEN_, DTYPE_,
     $                   LLD_, MB_, M_, NB_, N_, RSRC_
      parameter( block_cyclic_2d = 1, dlen_ = 9, dtype_ = 1,
     $                     ctxt_ = 2, m_ = 3, n_ = 4, mb_ = 5, nb_ = 6,
     $                     rsrc_ = 7, csrc_ = 8, lld_ = 9 )
      COMPLEX            ONE, ZERO
      parameter( one = 1.0e+0, zero = 0.0e+0 )
*     ..
*     .. Local Scalars ..
      CHARACTER          COLBTOP, ROWBTOP
      INTEGER            IACOL, IAROW, ICTXT, IL, IPL, IPU, IROFF, J,
     $                   JB, JL, JN, MN, MP, MYCOL, MYROW, NPCOL, NPROW
*     .. Local Arrays ..
      INTEGER            DESCIP( DLEN_ ), DESCL( DLEN_ ),
     $                   DESCU( DLEN_ ), IDUM( 1 )
*     ..
*     .. External Subroutines ..
      EXTERNAL           blacs_gridinfo, descset, pcgemm, pclacpy,
     $                   pclapiv, pclaset, pb_topget, pb_topset
*     ..
*     .. External Functions ..
      INTEGER            ICEIL, INDXG2P, NUMROC
      EXTERNAL           iceil, indxg2p, numroc
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min, mod
*     ..
*     .. Executable Statements ..
*
*     Get grid parameters.
*
      ictxt = desca( ctxt_ )
      CALL blacs_gridinfo( ictxt, nprow, npcol, myrow, mycol )
*
      iroff = mod( ia-1, desca( mb_ ) )
      iarow = indxg2p( ia, desca( mb_ ), myrow, desca( rsrc_ ), nprow )
      mp = numroc( m+iroff, desca( mb_ ), myrow, iarow, nprow )
      ipl = 1
      ipu = ipl + mp * desca( nb_ )
      CALL pb_topget( ictxt, 'Broadcast', 'Rowwise', rowbtop )
      CALL pb_topget( ictxt, 'Broadcast', 'Columnwise', colbtop )
      CALL pb_topset( ictxt, 'Broadcast', 'Rowwise', 'S-ring' )
      CALL pb_topset( ictxt, 'Broadcast', 'Columnwise', ' ' )
*
*     Define array descriptors for L and U
*
      mn = min( m, n )
      il = max( ( ( ia+mn-2 ) / desca( mb_ ) ) * desca( mb_ ) + 1, ia )
      jl = max( ( ( ja+mn-2 ) / desca( nb_ ) ) * desca( nb_ ) + 1, ja )
      jn = min( iceil( ja, desca( nb_ ) )*desca( nb_ ), ja+mn-1 )
      iarow = indxg2p( il, desca( mb_ ), myrow, desca( rsrc_ ), nprow )
      iacol = indxg2p( jl, desca( nb_ ), mycol, desca( csrc_ ), npcol )
*
      CALL descset( descl, ia+m-il, desca( nb_ ), desca( mb_ ),
     $              desca( nb_ ), iarow, iacol, ictxt, max( 1, mp ) )
*
      CALL descset( descu, desca( mb_ ), ja+n-jl, desca( mb_ ),
     $              desca( nb_ ), iarow, iacol, ictxt, desca( mb_ ) )
*
      CALL descset( descip, desca( m_ ) + desca( mb_ )*nprow, 1,
     $              desca( mb_ ), 1, desca( rsrc_ ), mycol, ictxt,
     $              numroc( desca( m_ ), desca( mb_ ), myrow,
     $                      desca( rsrc_ ), nprow ) + desca( mb_ ) )
*
*
      DO 10 j = jl, jn+1, -desca( nb_ )
*
         jb = min( ja+mn-j, desca( nb_ ) )
*
*        Copy unit lower triangular part of sub( A ) into WORK
*
         CALL pclacpy( 'Lower', m-il+ia, jb, a, il, j, desca,
     $                 work( ipl ), 1, 1, descl )
         CALL pclaset( 'Upper', m-il+ia, jb, zero, one, work( ipl ),
     $                 1, 1, descl )
*
*        Copy upper triangular part of sub( A ) into WORK(IPU)
*
         CALL pclacpy( 'Upper', jb, ja+n-j, a, il, j, desca,
     $                 work( ipu ), 1, 1, descu )
         CALL pclaset( 'Lower', jb-1, ja+n-j, zero, zero,
     $                 work( ipu ), 2, 1, descu )
*
*        Zero the strict lower triangular piece of the current block.
*
         CALL pclaset( 'Lower', ia+m-il-1, jb, zero, zero, a, il+1, j,
     $                 desca )
*
*        Zero the upper triangular piece of the current block.
*
         CALL pclaset( 'Upper', jb, ja+n-j, zero, zero, a, il, j,
     $                 desca )
*
*        Update the matrix sub( A ).
*
         CALL pcgemm( 'No transpose', 'No transpose', ia+m-il,
     $                ja+n-j, jb, one, work( ipl ), 1, 1, descl,
     $                work( ipu ), 1, 1, descu, one, a, il, j, desca )
*
         il = il - desca( mb_ )
         descl( m_ ) = descl( m_ ) + descl( mb_ )
         descl( rsrc_ ) = mod( descl( rsrc_ ) + nprow - 1, nprow )
         descl( csrc_ ) = mod( descl( csrc_ ) + npcol - 1, npcol )
         descu( n_ ) = descu( n_ ) + descu( nb_ )
         descu( rsrc_ ) = descl( rsrc_ )
         descu( csrc_ ) = descl( csrc_ )
*
   10 CONTINUE
*
*     Handle first block separately
*
      jb = min( jn-ja+1, desca( nb_ ) )
*
*     Copy unit lower triangular part of sub( A ) into WORK
*
      CALL pclacpy( 'Lower', m, jb, a, ia, ja, desca, work( ipl ),
     $              1, 1, descl )
      CALL pclaset( 'Upper', m, jb, zero, one, work( ipl ), 1, 1,
     $              descl )
*
*     Copy upper triangular part of sub( A ) into WORK(IPU)
*
      CALL pclacpy( 'Upper', jb, n, a, ia, ja, desca, work( ipu ), 1,
     $              1, descu )
      CALL pclaset( 'Lower', jb-1, n, zero, zero, work( ipu ), 2, 1,
     $              descu )
*
*     Zero the strict lower triangular piece of the current block.
*
      CALL pclaset( 'Lower', m-1, jb, zero, zero, a, ia+1, ja, desca )
*
*     Zero the upper triangular piece of the current block.
*
      CALL pclaset( 'Upper', jb, n, zero, zero, a, ia, ja, desca )
*
*     Update the matrix sub( A ).
*
      CALL pcgemm( 'No transpose', 'No transpose', m, n, jb, one,
     $             work( ipl ), 1, 1, descl, work( ipu ), 1, 1,
     $             descu, one, a, ia, ja, desca )
*
*     Apply pivots so that sub( A ) = P*L*U
*
      CALL pclapiv( 'Backward', 'Row', 'Col', min( m, n ), n, a, ia, ja,
     $              desca, ipiv, ia, 1, descip, idum )
*
      CALL pb_topset( ictxt, 'Broadcast', 'Rowwise', rowbtop )
      CALL pb_topset( ictxt, 'Broadcast', 'Columnwise', colbtop )
*
      RETURN
*
*     End of PCGETRRV
*
      END