pclagsy.f

Go to the documentation of this file.

*
*
      SUBROUTINE pclaghe( N, K, D, A, IA, JA, DESCA, ISEED, ORDER, WORK,
     $                    LWORK, INFO )
*
*
*  -- ScaLAPACK routine (version 1.7) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     May 1, 1997
*
*     .. Scalar Arguments ..
      INTEGER            IA, INFO, JA, K, LWORK, N, ORDER
*     ..
*     .. Array Arguments ..
      INTEGER            DESCA( * ), ISEED( 4 )
      REAL               D( * )
      COMPLEX            A( * ), WORK( * )
*     ..
*
*  Notes
*  =====
*
*  Each global data object is described by an associated description
*  vector.  This vector stores the information required to establish
*  the mapping between an object element and its corresponding process
*  and memory location.
*
*  Let A be a generic term for any 2D block cyclicly distributed array.
*  Such a global array has an associated description vector DESCA.
*  In the following comments, the character _ should be read as
*  "of the global array".
*
*  NOTATION        STORED IN      EXPLANATION
*  --------------- -------------- --------------------------------------
*  DTYPE_A(global) DESCA( DTYPE_ )The descriptor type.  In this case,
*                                 DTYPE_A = 1.
*  CTXT_A (global) DESCA( CTXT_ ) The BLACS context handle, indicating
*                                 the BLACS process grid A is distribu-
*                                 ted over. The context itself is glo-
*                                 bal, but the handle (the integer
*                                 value) may vary.
*  M_A    (global) DESCA( M_ )    The number of rows in the global
*                                 array A.
*  N_A    (global) DESCA( N_ )    The number of columns in the global
*                                 array A.
*  MB_A   (global) DESCA( MB_ )   The blocking factor used to distribute
*                                 the rows of the array.
*  NB_A   (global) DESCA( NB_ )   The blocking factor used to distribute
*                                 the columns of the array.
*  RSRC_A (global) DESCA( RSRC_ ) The process row over which the first
*                                 row of the array A is distributed.
*  CSRC_A (global) DESCA( CSRC_ ) The process column over which the
*                                 first column of the array A is
*                                 distributed.
*  LLD_A  (local)  DESCA( LLD_ )  The leading dimension of the local
*                                 array.  LLD_A >= MAX(1,LOCr(M_A)).
*
*  Let K be the number of rows or columns of a distributed matrix,
*  and assume that its process grid has dimension p x q.
*  LOCr( K ) denotes the number of elements of K that a process
*  would receive if K were distributed over the p processes of its
*  process column.
*  Similarly, LOCc( K ) denotes the number of elements of K that a
*  process would receive if K were distributed over the q processes of
*  its process row.
*  The values of LOCr() and LOCc() may be determined via a call to the
*  ScaLAPACK tool function, NUMROC:
*          LOCr( M ) = NUMROC( M, MB_A, MYROW, RSRC_A, NPROW ),
*          LOCc( N ) = NUMROC( N, NB_A, MYCOL, CSRC_A, NPCOL ).
*  An upper bound for these quantities may be computed by:
*          LOCr( M ) <= ceil( ceil(M/MB_A)/NPROW )*MB_A
*          LOCc( N ) <= ceil( ceil(N/NB_A)/NPCOL )*NB_A
*
*  Purpose
*  =======
*
*  PCLAGHE generates a real Hermitian matrix A, by pre- and post-
*  multiplying a real diagonal matrix D with a random orthogonal matrix:
*  A = U*D*U'.
*
*  This is just a quick implementation which will be replaced in the
*  future.  The random orthogonal matrix is computed by creating a
*  random matrix and running QR on it.  This requires vastly more
*  computation than necessary, but not significantly more communication
*  than is used in the rest of this rouinte, and hence is not that much
*  slower than an efficient solution.
*
*  Arguments
*  =========
*
*  N       (global input) INTEGER
*          The size of the matrix A.  N >= 0.
*
*  K       (global input) INTEGER
*          The number of nonzero subdiagonals within the band of A.
*          0 <= K <= N-1.
*          ### K must be 0 or N-1, 0 < K < N-1 is not supported yet.
*
*  D       (global input) COMPLEX array, dimension (N)
*          The diagonal elements of the diagonal matrix D.
*
*  A       (local output) COMPLEX array
*          Global dimension (N, N), local dimension (NP, NQ)
*          The generated n by n Hermitian matrix A (the full matrix is
*          stored).
*
*  IA      (global input) INTEGER
*          A's global row index, which points to the beginning of the
*          submatrix which is to be operated on.
*
*  JA      (global input) INTEGER
*          A's global column index, which points to the beginning of
*          the submatrix which is to be operated on.
*
*  DESCA   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix A.
*
*  ISEED   (global input/output) INTEGER array, dimension (4)
*          On entry, the seed of the random number generator; the array
*          elements must be between 0 and 4095, and ISEED(4) must be
*          odd.
*          On exit, the seed is updated and will remain identical on
*          all processes in the context.
*
*  ORDER   (global input) INTEGER
*          Number of reflectors in the matrix Q
*          At present, ORDER .NE. N is not supported
*
*  WORK    (local workspace) COMPLEX array, dimension (LWORK)
*
*  LWORK   (local input) INTEGER dimension of WORK
*        LWORK >= SIZETMS as returned by PCLASIZESEP
*
*
*  INFO    (local output) INTEGER
*          = 0:  successful exit
*          < 0:  If the i-th argument is an array and the j-entry had
*                an illegal value, then INFO = -(i*100+j), if the i-th
*                argument is a scalar and had an illegal value, then
*                INFO = -i.
*
*
*     .. Parameters ..
      INTEGER            BLOCK_CYCLIC_2D, DLEN_, DTYPE_, CTXT_, M_, N_,
     $                   mb_, nb_, rsrc_, csrc_, lld_
      parameter( block_cyclic_2d = 1, dlen_ = 9, dtype_ = 1,
     $                   ctxt_ = 2, m_ = 3, n_ = 4, mb_ = 5, nb_ = 6,
     $                   rsrc_ = 7, csrc_ = 8, lld_ = 9 )
      COMPLEX            CZERO
      parameter( czero = 0.0e+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            CSRC_A, I, IACOL, IAROW, ICOFFA, II, IIROW,
     $                   indaa, indtau, indwork, ipostpad, iprepad,
     $                   iroffa, isizeheevx, isizesubtst, isizetst,
     $                   jjcol, ldaa, lii, liii, ljj, ljjj, lwmin, maxi,
     $                   mb_a, mycol, myrow, nb_a, np, npcol, nprow, nq,
     $                   rsizechk, rsizeheevx, rsizeqtq, rsizesubtst,
     $                   rsizetst, rsrc_a, sizeheevx, sizemqrleft,
     $                   sizemqrright, sizeqrf, sizesubtst, sizetms,
     $                   sizetst, sizeheevd, rsizeheevd, isizeheevd
*     ..
*     .. External Subroutines ..
      EXTERNAL           blacs_gridinfo, chk1mat, claset, pcgeqrf,
     $                   pclasizesep, pcmatgen, pcunmqr, pxerbla
*     ..
*     .. External Functions ..
      INTEGER            INDXG2P, NUMROC
      EXTERNAL           indxg2p, numroc
*     ..
*     .. Intrinsic Functions ..
*
      INTRINSIC          max, min, mod
*     ..
*     .. Executable Statements ..
*       This is just to keep ftnchek happy
      IF( block_cyclic_2d*csrc_*ctxt_*dlen_*dtype_*lld_*mb_*m_*nb_*n_*
     $    rsrc_.LT.0 )RETURN
*
*     Initialize grid information
*
      CALL blacs_gridinfo( desca( ctxt_ ), nprow, npcol, myrow, mycol )
*
*     Check LWORK
*
      info = 0
      IF( nprow.EQ.-1 ) THEN
         info = -( 700+ctxt_ )
      ELSE
         CALL chk1mat( n, 1, n, 1, ia, ja, desca, 7, info )
      END IF
*
      ldaa = desca( lld_ )
      mb_a = desca( mb_ )
      nb_a = desca( nb_ )
      rsrc_a = desca( rsrc_ )
      csrc_a = desca( csrc_ )
      iarow = indxg2p( ia, mb_a, myrow, rsrc_a, nprow )
      iacol = indxg2p( ja, nb_a, mycol, csrc_a, npcol )
      iroffa = mod( ia-1, mb_a )
      icoffa = mod( ja-1, nb_a )
      np = numroc( n+iroffa, mb_a, myrow, iarow, nprow )
      nq = numroc( n+icoffa, nb_a, mycol, iacol, npcol )
      iprepad = 0
      ipostpad = 0
      CALL pclasizesep( desca, iprepad, ipostpad, sizemqrleft,
     $                  sizemqrright, sizeqrf, sizetms, rsizeqtq,
     $                  rsizechk, sizeheevx, rsizeheevx, isizeheevx,
     $                  sizeheevd, rsizeheevd, isizeheevd,
     $                  sizesubtst, rsizesubtst, isizesubtst, sizetst,
     $                  rsizetst, isizetst )
      lwmin = sizetms
*
*     Test the input arguments
*
      IF( info.EQ.0 ) THEN
         IF( k.LT.0 .OR. k.GT.n-1 ) THEN
            info = -2
         ELSE IF( n.NE.order ) THEN
            info = -9
         ELSE IF( lwork.LT.lwmin ) THEN
            info = -11
         END IF
      END IF
      IF( info.LT.0 ) THEN
         CALL pxerbla( desca( ctxt_ ), 'PCLAGHE', -info )
         RETURN
      END IF
*
      indaa = 1
      indtau = indaa + ldaa*max( 1, nq )
      indwork = indtau + max( 1, nq )
*
      IF( k.NE.0 ) THEN
         CALL claset( 'A', ldaa, nq, czero, czero, work( indaa ), ldaa )
*
*
*        Build a random matrix
*
*
         CALL pcmatgen( desca( ctxt_ ), 'N', 'N', n, order,
     $                  desca( mb_ ), desca( nb_ ), work( indaa ),
     $                  desca( lld_ ), desca( rsrc_ ), desca( csrc_ ),
     $                  iseed( 1 ), 0, np, 0, nq, myrow, mycol, nprow,
     $                  npcol )
         CALL pcgeqrf( n, order, work( indaa ), ia, ja, desca,
     $                 work( indtau ), work( indwork ), sizeqrf, info )
*
      END IF
*
*     Build a diagonal matrix A with the eigenvalues specified in D
*
      CALL claset( 'A', np, nq, czero, czero, a, desca( lld_ ) )
*
      iirow = 0
      jjcol = 0
      lii = 1
      ljj = 1
*
      DO 20 ii = 1, n, desca( mb_ )
         maxi = min( n, ii+desca( mb_ )-1 )
         IF( ( myrow.EQ.iirow ) .AND. ( mycol.EQ.jjcol ) ) THEN
            liii = lii
            ljjj = ljj
            DO 10 i = ii, maxi
               a( liii+( ljjj-1 )*desca( lld_ ) ) = d( i )
               liii = liii + 1
               ljjj = ljjj + 1
   10       CONTINUE
         END IF
         IF( myrow.EQ.iirow )
     $      lii = lii + desca( mb_ )
         IF( mycol.EQ.jjcol )
     $      ljj = ljj + desca( mb_ )
         iirow = mod( iirow+1, nprow )
         jjcol = mod( jjcol+1, npcol )
   20 CONTINUE
*
*     A = Q * A
*
      IF( k.NE.0 ) THEN
*
         CALL pcunmqr( 'L', 'Conjugate transpose', n, n, order,
     $                 work( indaa ), ia, ja, desca, work( indtau ), a,
     $                 ia, ja, desca, work( indwork ), sizemqrleft,
     $                 info )
*
*
*        A = A * Q'
*
*
         CALL pcunmqr( 'R', 'N', n, n, order, work( indaa ), ia, ja,
     $                 desca, work( indtau ), a, ia, ja, desca,
     $                 work( indwork ), sizemqrright, info )
*
      END IF
*
*     End of PCLAGHE
*
      END