pslatms.f

Go to the documentation of this file.

*
*
      SUBROUTINE pslatms( M, N, DIST, ISEED, SYM, D, MODE, COND, DMAX,
     $                    KL, KU, PACK, A, IA, JA, DESCA, ORDER, WORK,
     $                    LWORK, INFO )
*
*  -- ScaLAPACK routine (version 1.7) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     May 1, 1997
*
*     .. Scalar Arguments ..
      CHARACTER          DIST, PACK, SYM
      INTEGER            IA, INFO, JA, KL, KU, LWORK, M, MODE, N, ORDER
      REAL               COND, DMAX
*     ..
*     .. Array Arguments ..
      INTEGER            DESCA( * ), ISEED( 4 )
      REAL               A( * ), D( * ), WORK( * )
*     ..
*
*  Purpose
*  =======
*
*     PSLATMS generates random symmetric matrices with specified
*     eigenvalues for testing SCALAPACK programs.
*
*     PSLATMS operates by applying the following sequence of
*     operations:
*
*       Set the diagonal to D, where D may be input or
*          computed according to MODE, COND, DMAX, and SYM
*          as described below.
*
*           Generate a dense M x N matrix by multiplying D on the left
*               and the right by random unitary matrices, then:
*
*           Reduce the bandwidth according to KL and KU, using
*           Householder transformations.
*           ### bandwidth reduction NOT SUPPORTED ###
*
*  Arguments
*  =========
*
*  M      - (global input) INTEGER
*           The number of rows of A. Not modified.
*
*  N      - (global input) INTEGER
*           The number of columns of A. Not modified.
*           ### M .ne. N unsupported
*
*  DIST   - (global input) CHARACTER*1
*           On entry, DIST specifies the type of distribution to be used
*           to generate the random eigen-/singular values.
*           'U' => UNIFORM( 0, 1 )  ( 'U' for uniform )
*           'S' => UNIFORM( -1, 1 ) ( 'S' for symmetric )
*           'N' => NORMAL( 0, 1 )   ( 'N' for normal )
*           Not modified.
*
*  ISEED  - (global input) INTEGER array, dimension ( 4 )
*           On entry ISEED specifies the seed of the random number
*           generator. They should lie between 0 and 4095 inclusive,
*           and ISEED(4) should be odd. The random number generator
*           uses a linear congruential sequence limited to small
*           integers, and so should produce machine independent
*           random numbers. The values of ISEED are changed on
*           exit, and can be used in the next call to SLATMS
*           to continue the same random number sequence.
*           Changed on exit.
*
*  SYM    - (global input) CHARACTER*1
*           If SYM='S' or 'H', the generated matrix is symmetric, with
*             eigenvalues specified by D, COND, MODE, and DMAX; they
*             may be positive, negative, or zero.
*           If SYM='P', the generated matrix is symmetric, with
*             eigenvalues (= singular values) specified by D, COND,
*             MODE, and DMAX; they will not be negative.
*           If SYM='N', the generated matrix is nonsymmetric, with
*             singular values specified by D, COND, MODE, and DMAX;
*             they will not be negative.
*           ### SYM = 'N' NOT SUPPORTED ###
*           Not modified.
*
*  D      - (local input/output) REAL array,
*           dimension ( MIN( M , N ) )
*           This array is used to specify the singular values or
*           eigenvalues of A (see SYM, above.)  If MODE=0, then D is
*           assumed to contain the singular/eigenvalues, otherwise
*           they will be computed according to MODE, COND, and DMAX,
*           and placed in D.
*           Modified if MODE is nonzero.
*
*  MODE   - (global input) INTEGER
*           On entry this describes how the singular/eigenvalues are to
*           be specified:
*           MODE = 0 means use D as input
*           MODE = 1 sets D(1)=1 and D(2:N)=1.0/COND
*           MODE = 2 sets D(1:N-1)=1 and D(N)=1.0/COND
*           MODE = 3 sets D(I)=COND**(-(I-1)/(N-1))
*           MODE = 4 sets D(i)=1 - (i-1)/(N-1)*(1 - 1/COND)
*           MODE = 5 sets D to random numbers in the range
*                    ( 1/COND , 1 ) such that their logarithms
*                    are uniformly distributed.
*           MODE = 6 set D to random numbers from same distribution
*                    as the rest of the matrix.
*           MODE < 0 has the same meaning as ABS(MODE), except that
*              the order of the elements of D is reversed.
*           Thus if MODE is positive, D has entries ranging from
*              1 to 1/COND, if negative, from 1/COND to 1,
*           If SYM='S' or 'H', and MODE is neither 0, 6, nor -6, then
*              the elements of D will also be multiplied by a random
*              sign (i.e., +1 or -1.)
*           Not modified.
*
*  COND   - (global input) REAL
*           On entry, this is used as described under MODE above.
*           If used, it must be >= 1. Not modified.
*
*  DMAX   - (global input) REAL
*           If MODE is neither -6, 0 nor 6, the contents of D, as
*           computed according to MODE and COND, will be scaled by
*           DMAX / max(abs(D(i))); thus, the maximum absolute eigen- or
*           singular value (which is to say the norm) will be abs(DMAX).
*           Note that DMAX need not be positive: if DMAX is negative
*           (or zero), D will be scaled by a negative number (or zero).
*           Not modified.
*
*  KL     - (global input) INTEGER
*           This specifies the lower bandwidth of the  matrix. For
*           example, KL=0 implies upper triangular, KL=1 implies upper
*           Hessenberg, and KL being at least M-1 means that the matrix
*           has full lower bandwidth.  KL must equal KU if the matrix
*           is symmetric.
*           Not modified.
*           ### 1 <= KL < N-1 is NOT SUPPORTED ###
*
*  KU     - (global input) INTEGER
*           This specifies the upper bandwidth of the  matrix. For
*           example, KU=0 implies lower triangular, KU=1 implies lower
*           Hessenberg, and KU being at least N-1 means that the matrix
*           has full upper bandwidth.  KL must equal KU if the matrix
*           is symmetric.
*           Not modified.
*           ### 1 <= KU < N-1 is NOT SUPPORTED ###
*
*  PACK   - (global input) CHARACTER*1
*           This specifies packing of matrix as follows:
*           'N' => no packing
*           ### PACK must be 'N'  all other options NOT SUPPORTED ###
*
*  A      - (local output) REAL array
*           Global dimension (M, N), local dimension (MP, NQ)
*           On exit A is the desired test matrix.
*
*  IA      (global input) INTEGER
*          A's global row index, which points to the beginning of the
*          submatrix which is to be operated on.
*
*  JA      (global input) INTEGER
*          A's global column index, which points to the beginning of
*          the submatrix which is to be operated on.
*
*  DESCA   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix A.
*
*  ORDER  - (input) INTEGER
*           The number of reflectors used to define the orthogonal
*           matrix Q.  A = Q * D * Q'
*           Higher ORDER requires more computation and communication.
*
*  WORK   - (local input/output) REAL array,
*           dimension (LWORK)
*
*  LWORK  - (local input) INTEGER dimension of WORK
*           LWORK >= SIZETMS as returned by PSLASIZESEP
*
*  INFO   - (global output) INTEGER
*           Error code.  On exit, INFO will be set to one of the
*           following values:
*             0 => normal return
*            -1 => M negative or unequal to N and SYM='S', 'H', or 'P'
*            -2 => N negative
*            -3 => DIST illegal string
*            -5 => SYM illegal string
*            -7 => MODE not in range -6 to 6
*            -8 => COND less than 1.0, and MODE neither -6, 0 nor 6
*           -10 => KL negative
*           -11 => KU negative, or SYM='S' or 'H' and KU not equal to KL
*           -16 => DESCA is inconsistent
*           -17 => ORDER not in the range 0 to N inclusive
*            1  => Error return from SLATM1
*            2  => Cannot scale to DMAX (max. sing. value is 0)
*            3  => Error return from PSLAGSY
*
*-----------------------------------------------------------------------
*
*
*     .. Parameters ..
      INTEGER            BLOCK_CYCLIC_2D, DLEN_, DTYPE_, CTXT_, M_, N_,
     $                   MB_, NB_, RSRC_, CSRC_, LLD_
      parameter( block_cyclic_2d = 1, dlen_ = 9, dtype_ = 1,
     $                   ctxt_ = 2, m_ = 3, n_ = 4, mb_ = 5, nb_ = 6,
     $                   rsrc_ = 7, csrc_ = 8, lld_ = 9 )
      REAL               ZERO, ONE
      PARAMETER          ( ZERO = 0.0e+0, one = 1.0e+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, IDIST, IINFO, IPACK, IRSIGN, ISYM, LLB,
     $                   MNMIN, MYCOL, MYROW, NP, NPCOL, NPROW, NQ
      REAL               ALPHA, TEMP
*     ..
*     .. Local Arrays ..
      INTEGER            IDUM1( 1 ), IDUM2( 1 )
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      INTEGER            NUMROC
      EXTERNAL           lsame, numroc
*     ..
*     .. External Subroutines ..
      EXTERNAL           blacs_gridinfo, chk1mat, pchk1mat, pslagsy,
     $                   pxerbla, slaset, slatm1, sscal
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, max, min, mod
*     ..
*     .. Executable Statements ..
*       This is just to keep ftnchek happy
      IF( block_cyclic_2d*csrc_*ctxt_*dlen_*dtype_*lld_*mb_*m_*nb_*n_*
     $    rsrc_.LT.0 )RETURN
*
*     1)      Decode and Test the input parameters.
*             Initialize flags & seed.
*
*
      info = 0
*
      CALL blacs_gridinfo( desca( ctxt_ ), nprow, npcol, myrow, mycol )
      IF( ( myrow.GE.nprow .OR. myrow.LT.0 ) .OR.
     $    ( mycol.GE.npcol .OR. mycol.LT.0 ) )RETURN
*
      np = numroc( n, desca( mb_ ), myrow, 0, nprow )
      nq = numroc( n, desca( nb_ ), mycol, 0, npcol )
*
*     Quick return if possible
*
      IF( m.EQ.0 .OR. n.EQ.0 )
     $   RETURN
*
*     Decode DIST
*
      IF( lsame( dist, 'U' ) ) THEN
         idist = 1
      ELSE IF( lsame( dist, 'S' ) ) THEN
         idist = 2
      ELSE IF( lsame( dist, 'N' ) ) THEN
         idist = 3
      ELSE
         idist = -1
      END IF
*
*     Decode SYM
*
      IF( lsame( sym, 'N' ) ) THEN
         isym = 1
         irsign = 0
      ELSE IF( lsame( sym, 'P' ) ) THEN
         isym = 2
         irsign = 0
      ELSE IF( lsame( sym, 'S' ) ) THEN
         isym = 2
         irsign = 1
      ELSE IF( lsame( sym, 'H' ) ) THEN
         isym = 2
         irsign = 1
      ELSE
         isym = -1
      END IF
*
*     Decode PACK
*
      IF( lsame( pack, 'N' ) ) THEN
         ipack = 0
      ELSE
         ipack = 1
      END IF
*
*     Set certain internal parameters
*
      mnmin = min( m, n )
      llb = min( kl, m-1 )
*
      IF( order.EQ.0 )
     $   order = n
*
*     Set INFO if an error
*
      IF( nprow.EQ.-1 ) THEN
         info = -( 1600+ctxt_ )
      ELSE
         CALL chk1mat( m, 1, n, 2, ia, ja, desca, 16, info )
         IF( info.EQ.0 ) THEN
            IF( m.NE.n .AND. isym.NE.1 ) THEN
               info = -2
            ELSE IF( idist.EQ.-1 ) THEN
               info = -3
            ELSE IF( isym.EQ.-1 ) THEN
               info = -5
            ELSE IF( abs( mode ).GT.6 ) THEN
               info = -7
            ELSE IF( ( mode.NE.0 .AND. abs( mode ).NE.6 ) .AND. cond.LT.
     $               one ) THEN
               info = -8
            ELSE IF( kl.LT.0 ) THEN
               info = -10
            ELSE IF( ku.LT.0 .OR. ( isym.NE.1 .AND. kl.NE.ku ) ) THEN
               info = -11
            ELSE IF( ( order.LT.0 ) .OR. ( order.GT.n ) ) THEN
               info = -17
            END IF
         END IF
         CALL pchk1mat( m, 1, n, 2, ia, ja, desca, 16, 0, idum1, idum2,
     $                  info )
      END IF
*
*     Check for unsupported features
*
      IF( isym.NE.2 ) THEN
         info = -5
      ELSE IF( ipack.NE.0 ) THEN
         info = -12
      ELSE IF( kl.GT.0 .AND. kl.LT.m-1 ) THEN
         info = -10
      ELSE IF( ku.GT.0 .AND. ku.LT.n-1 ) THEN
         info = -11
      ELSE IF( llb.NE.0 .AND. llb.NE.m-1 ) THEN
         info = -10
      END IF
      IF( info.NE.0 ) THEN
         CALL pxerbla( desca( ctxt_ ), 'PSLATMS', -info )
         RETURN
      END IF
*
*     Initialize random number generator
*
      DO 10 i = 1, 4
         iseed( i ) = mod( abs( iseed( i ) ), 4096 )
   10 CONTINUE
*
      IF( mod( iseed( 4 ), 2 ).NE.1 )
     $   iseed( 4 ) = iseed( 4 ) + 1
*
*     2)      Set up D  if indicated.
*
*             Compute D according to COND and MODE
*
      CALL slatm1( mode, cond, irsign, idist, iseed, d, mnmin, iinfo )
*
      IF( iinfo.NE.0 ) THEN
         info = 1
         RETURN
      END IF
*
*
      IF( mode.NE.0 .AND. abs( mode ).NE.6 ) THEN
*
*        Scale by DMAX
*
         temp = abs( d( 1 ) )
         DO 20 i = 2, mnmin
            temp = max( temp, abs( d( i ) ) )
   20    CONTINUE
*
         IF( temp.GT.zero ) THEN
            alpha = dmax / temp
         ELSE
            info = 2
            RETURN
         END IF
*
         CALL sscal( mnmin, alpha, d, 1 )
*
      END IF
*
      CALL slaset( 'A', np, nq, zero, zero, a, desca( lld_ ) )
*
*     symmetric -- A = U D U'
*
      CALL pslagsy( m, llb, d, a, ia, ja, desca, iseed, order, work,
     $              lwork, iinfo )
*
      RETURN
*
*     End of PSLATMS
*
      SUBROUTINE pslatms( M, N, DIST, ISEED, SYM, D, MODE, COND, DMAX, …
      END