pslasmsub.f

Go to the documentation of this file.

      SUBROUTINE pslasmsub( A, DESCA, I, L, K, SMLNUM, BUF, LWORK )
*
*  -- ScaLAPACK routine (version 1.7) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     May 1, 1997
*
*     .. Scalar Arguments ..
      INTEGER            I, K, L, LWORK
      REAL               SMLNUM
*     ..
*     .. Array Arguments ..
      INTEGER            DESCA( * )
      REAL               A( * ), BUF( * )
*     ..
*
*  Purpose
*  =======
*
*  PSLASMSUB looks for a small subdiagonal element from the bottom
*     of the matrix that it can safely set to zero.
*
*  Notes
*  =====
*
*  Each global data object is described by an associated description
*  vector.  This vector stores the information required to establish
*  the mapping between an object element and its corresponding process
*  and memory location.
*
*  Let A be a generic term for any 2D block cyclicly distributed array.
*  Such a global array has an associated description vector DESCA.
*  In the following comments, the character _ should be read as
*  "of the global array".
*
*  NOTATION        STORED IN      EXPLANATION
*  --------------- -------------- --------------------------------------
*  DTYPE_A(global) DESCA( DTYPE_ )The descriptor type.  In this case,
*                                 DTYPE_A = 1.
*  CTXT_A (global) DESCA( CTXT_ ) The BLACS context handle, indicating
*                                 the BLACS process grid A is distribu-
*                                 ted over. The context itself is glo-
*                                 bal, but the handle (the integer
*                                 value) may vary.
*  M_A    (global) DESCA( M_ )    The number of rows in the global
*                                 array A.
*  N_A    (global) DESCA( N_ )    The number of columns in the global
*                                 array A.
*  MB_A   (global) DESCA( MB_ )   The blocking factor used to distribute
*                                 the rows of the array.
*  NB_A   (global) DESCA( NB_ )   The blocking factor used to distribute
*                                 the columns of the array.
*  RSRC_A (global) DESCA( RSRC_ ) The process row over which the first
*                                 row of the array A is distributed.
*  CSRC_A (global) DESCA( CSRC_ ) The process column over which the
*                                 first column of the array A is
*                                 distributed.
*  LLD_A  (local)  DESCA( LLD_ )  The leading dimension of the local
*                                 array.  LLD_A >= MAX(1,LOCr(M_A)).
*
*  Let K be the number of rows or columns of a distributed matrix,
*  and assume that its process grid has dimension p x q.
*  LOCr( K ) denotes the number of elements of K that a process
*  would receive if K were distributed over the p processes of its
*  process column.
*  Similarly, LOCc( K ) denotes the number of elements of K that a
*  process would receive if K were distributed over the q processes of
*  its process row.
*  The values of LOCr() and LOCc() may be determined via a call to the
*  ScaLAPACK tool function, NUMROC:
*          LOCr( M ) = NUMROC( M, MB_A, MYROW, RSRC_A, NPROW ),
*          LOCc( N ) = NUMROC( N, NB_A, MYCOL, CSRC_A, NPCOL ).
*  An upper bound for these quantities may be computed by:
*          LOCr( M ) <= ceil( ceil(M/MB_A)/NPROW )*MB_A
*          LOCc( N ) <= ceil( ceil(N/NB_A)/NPCOL )*NB_A
*
*  Arguments
*  =========
*
*  A       (global input) REAL             array, dimension
*          (DESCA(LLD_),*)
*          On entry, the Hessenberg matrix whose tridiagonal part is
*          being scanned.
*          Unchanged on exit.
*
*  DESCA   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix A.
*
*  I       (global input) INTEGER
*          The global location of the bottom of the unreduced
*          submatrix of A.
*          Unchanged on exit.
*
*  L       (global input) INTEGER
*          The global location of the top of the unreduced submatrix
*          of A.
*          Unchanged on exit.
*
*  K       (global output) INTEGER
*          On exit, this yields the bottom portion of the unreduced
*          submatrix.  This will satisfy: L <= M  <= I-1.
*
*  SMLNUM  (global input) REAL            
*          On entry, a "small number" for the given matrix.
*          Unchanged on exit.
*
*  BUF     (local output) REAL             array of size LWORK.
*
*  LWORK   (global input) INTEGER
*          On exit, LWORK is the size of the work buffer.
*          This must be at least 2*Ceil( Ceil( (I-L)/HBL ) /
*                                        LCM(NPROW,NPCOL) )
*          Here LCM is least common multiple, and NPROWxNPCOL is the
*          logical grid size.
*
*   Notes:
*
*     This routine does a global maximum and must be called by all
*     processes.
*
*     This code is basically a parallelization of the following snip
*     of LAPACK code from SLAHQR:
*
*        Look for a single small subdiagonal element.
*
*        DO 20 K = I, L + 1, -1
*           TST1 = ABS( H( K-1, K-1 ) ) + ABS( H( K, K ) )
*           IF( TST1.EQ.ZERO )
*    $         TST1 = DLANHS( '1', I-L+1, H( L, L ), LDH, WORK )
*           IF( ABS( H( K, K-1 ) ).LE.MAX( ULP*TST1, SMLNUM ) )
*    $         GO TO 30
*  20    CONTINUE
*  30    CONTINUE
*
*  Implemented by:  G. Henry, November 17, 1996
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            BLOCK_CYCLIC_2D, CSRC_, CTXT_, DLEN_, DTYPE_,
     $                   LLD_, MB_, M_, NB_, N_, RSRC_
      parameter( block_cyclic_2d = 1, dlen_ = 9, dtype_ = 1,
     $                     ctxt_ = 2, m_ = 3, n_ = 4, mb_ = 5, nb_ = 6,
     $                     rsrc_ = 7, csrc_ = 8, lld_ = 9 )
      REAL               ZERO
      parameter( zero = 0.0e+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            CONTXT, DOWN, HBL, IAFIRST, IBUF1, IBUF2,
     $                   ICOL1, ICOL2, II, III, IRCV1, IRCV2, IROW1,
     $                   IROW2, ISRC, ISTR1, ISTR2, ITMP1, ITMP2,
     $                   JAFIRST, JJ, JJJ, JSRC, LDA, LEFT, MODKM1,
     $                   MYCOL, MYROW, NPCOL, NPROW, NUM, RIGHT, UP
      REAL               H10, H11, H22, TST1, ULP
*     ..
*     .. External Functions ..
      INTEGER            ILCM, NUMROC
      REAL               PSLAMCH
      EXTERNAL           ilcm, numroc, pslamch
*     ..
*     .. External Subroutines ..
      EXTERNAL           blacs_gridinfo, sgerv2d, sgesd2d, igamx2d,
     $                   infog1l, infog2l
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, max, mod
*     ..
*     .. Executable Statements ..
*
      hbl = desca( mb_ )
      contxt = desca( ctxt_ )
      lda = desca( lld_ )
      iafirst = desca( rsrc_ )
      jafirst = desca( csrc_ )
      ulp = pslamch( contxt, 'PRECISION' )
      CALL blacs_gridinfo( contxt, nprow, npcol, myrow, mycol )
      left = mod( mycol+npcol-1, npcol )
      right = mod( mycol+1, npcol )
      up = mod( myrow+nprow-1, nprow )
      down = mod( myrow+1, nprow )
      num = nprow*npcol
*
*     BUFFER1 STARTS AT BUF(ISTR1+1) AND WILL CONTAINS IBUF1 ELEMENTS
*     BUFFER2 STARTS AT BUF(ISTR2+1) AND WILL CONTAINS IBUF2 ELEMENTS
*
      istr1 = 0
      istr2 = ( ( i-l ) / hbl )
      IF( istr2*hbl.LT.( i-l ) )
     $   istr2 = istr2 + 1
      ii = istr2 / ilcm( nprow, npcol )
      IF( ii*ilcm( nprow, npcol ).LT.istr2 ) THEN
         istr2 = ii + 1
      ELSE
         istr2 = ii
      END IF
      IF( lwork.LT.2*istr2 ) THEN
*
*        Error!
*
         RETURN
      END IF
      CALL infog2l( i, i, desca, nprow, npcol, myrow, mycol, irow1,
     $              icol1, ii, jj )
      modkm1 = mod( i-1+hbl, hbl )
*
*     COPY OUR RELEVANT PIECES OF TRIADIAGONAL THAT WE OWE INTO
*     2 BUFFERS TO SEND TO WHOMEVER OWNS H(K,K) AS K MOVES DIAGONALLY
*     UP THE TRIDIAGONAL
*
      ibuf1 = 0
      ibuf2 = 0
      ircv1 = 0
      ircv2 = 0
      DO 10 k = i, l + 1, -1
         IF( ( modkm1.EQ.0 ) .AND. ( down.EQ.ii ) .AND.
     $       ( right.EQ.jj ) ) THEN
*
*           WE MUST PACK H(K-1,K-1) AND SEND IT DIAGONAL DOWN
*
            IF( ( down.NE.myrow ) .OR. ( right.NE.mycol ) ) THEN
               CALL infog2l( k-1, k-1, desca, nprow, npcol, myrow,
     $                       mycol, irow1, icol1, isrc, jsrc )
               ibuf1 = ibuf1 + 1
               buf( istr1+ibuf1 ) = a( ( icol1-1 )*lda+irow1 )
            END IF
         END IF
         IF( ( modkm1.EQ.0 ) .AND. ( myrow.EQ.ii ) .AND.
     $       ( right.EQ.jj ) ) THEN
*
*           WE MUST PACK H(K  ,K-1) AND SEND IT RIGHT
*
            IF( npcol.GT.1 ) THEN
               CALL infog2l( k, k-1, desca, nprow, npcol, myrow, mycol,
     $                       irow1, icol1, isrc, jsrc )
               ibuf2 = ibuf2 + 1
               buf( istr2+ibuf2 ) = a( ( icol1-1 )*lda+irow1 )
            END IF
         END IF
*
*        ADD UP THE RECEIVES
*
         IF( ( myrow.EQ.ii ) .AND. ( mycol.EQ.jj ) ) THEN
            IF( ( modkm1.EQ.0 ) .AND. ( ( nprow.GT.1 ) .OR. ( npcol.GT.
     $          1 ) ) ) THEN
*
*              WE MUST RECEIVE H(K-1,K-1) FROM DIAGONAL UP
*
               ircv1 = ircv1 + 1
            END IF
            IF( ( modkm1.EQ.0 ) .AND. ( npcol.GT.1 ) ) THEN
*
*              WE MUST RECEIVE H(K  ,K-1) FROM LEFT
*
               ircv2 = ircv2 + 1
            END IF
         END IF
*
*        POSSIBLY CHANGE OWNERS (OCCURS ONLY WHEN MOD(K-1,HBL) = 0)
*
         IF( modkm1.EQ.0 ) THEN
            ii = ii - 1
            jj = jj - 1
            IF( ii.LT.0 )
     $         ii = nprow - 1
            IF( jj.LT.0 )
     $         jj = npcol - 1
         END IF
         modkm1 = modkm1 - 1
         IF( modkm1.LT.0 )
     $      modkm1 = hbl - 1
   10 CONTINUE
*
*     SEND DATA ON TO THE APPROPRIATE NODE IF THERE IS ANY DATA TO SEND
*
      IF( ibuf1.GT.0 ) THEN
         CALL sgesd2d( contxt, ibuf1, 1, buf( istr1+1 ), ibuf1, down,
     $                 right )
      END IF
      IF( ibuf2.GT.0 ) THEN
         CALL sgesd2d( contxt, ibuf2, 1, buf( istr2+1 ), ibuf2, myrow,
     $                 right )
      END IF
*
*     RECEIVE APPROPRIATE DATA IF THERE IS ANY
*
      IF( ircv1.GT.0 ) THEN
         CALL sgerv2d( contxt, ircv1, 1, buf( istr1+1 ), ircv1, up,
     $                 left )
      END IF
      IF( ircv2.GT.0 ) THEN
         CALL sgerv2d( contxt, ircv2, 1, buf( istr2+1 ), ircv2, myrow,
     $                 left )
      END IF
*
*     START MAIN LOOP
*
      ibuf1 = 0
      ibuf2 = 0
      CALL infog2l( i, i, desca, nprow, npcol, myrow, mycol, irow1,
     $              icol1, ii, jj )
      modkm1 = mod( i-1+hbl, hbl )
*
*        LOOK FOR A SINGLE SMALL SUBDIAGONAL ELEMENT.
*
*        Start loop for subdiagonal search
*
      DO 40 k = i, l + 1, -1
         IF( ( myrow.EQ.ii ) .AND. ( mycol.EQ.jj ) ) THEN
            IF( modkm1.EQ.0 ) THEN
*
*                 Grab information from WORK array
*
               IF( num.GT.1 ) THEN
                  ibuf1 = ibuf1 + 1
                  h11 = buf( istr1+ibuf1 )
               ELSE
                  h11 = a( ( icol1-2 )*lda+irow1-1 )
               END IF
               IF( npcol.GT.1 ) THEN
                  ibuf2 = ibuf2 + 1
                  h10 = buf( istr2+ibuf2 )
               ELSE
                  h10 = a( ( icol1-2 )*lda+irow1 )
               END IF
            ELSE
*
*                 Information is local
*
               h11 = a( ( icol1-2 )*lda+irow1-1 )
               h10 = a( ( icol1-2 )*lda+irow1 )
            END IF
            h22 = a( ( icol1-1 )*lda+irow1 )
            tst1 = abs( h11 ) + abs( h22 )
            IF( tst1.EQ.zero ) THEN
*
*                 FIND SOME NORM OF THE LOCAL H(L:I,L:I)
*
               CALL infog1l( l, hbl, nprow, myrow, iafirst, itmp1, iii )
               irow2 = numroc( i, hbl, myrow, iafirst, nprow )
               CALL infog1l( l, hbl, npcol, mycol, jafirst, itmp2, iii )
               icol2 = numroc( i, hbl, mycol, jafirst, npcol )
               DO 30 iii = itmp1, irow2
                  DO 20 jjj = itmp2, icol2
                     tst1 = tst1 + abs( a( ( jjj-1 )*lda+iii ) )
   20             CONTINUE
   30          CONTINUE
            END IF
            IF( abs( h10 ).LE.max( ulp*tst1, smlnum ) )
     $         GO TO 50
            irow1 = irow1 - 1
            icol1 = icol1 - 1
         END IF
         modkm1 = modkm1 - 1
         IF( modkm1.LT.0 )
     $      modkm1 = hbl - 1
         IF( ( modkm1.EQ.hbl-1 ) .AND. ( k.GT.2 ) ) THEN
            ii = mod( ii+nprow-1, nprow )
            jj = mod( jj+npcol-1, npcol )
            CALL infog2l( k-1, k-1, desca, nprow, npcol, myrow, mycol,
     $                    irow1, icol1, itmp1, itmp2 )
         END IF
   40 CONTINUE
   50 CONTINUE
      CALL igamx2d( contxt, 'ALL', ' ', 1, 1, k, 1, itmp1, itmp2, -1,
     $              -1, -1 )
      RETURN
*
*     End of PSLASMSUB
*
      END