pcunml2.f

Go to the documentation of this file.

      SUBROUTINE pcunml2( SIDE, TRANS, M, N, K, A, IA, JA, DESCA, TAU,
     $                    C, IC, JC, DESCC, WORK, LWORK, INFO )
*
*  -- ScaLAPACK routine (version 1.7) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     May 25, 2001
*
*     .. Scalar Arguments ..
      CHARACTER          SIDE, TRANS
      INTEGER            IA, IC, INFO, JA, JC, K, LWORK, M, N
*     ..
*     .. Array Arguments ..
      INTEGER            DESCA( * ), DESCC( * )
      COMPLEX            A( * ), C( * ), TAU( * ), WORK( * )
*     ..
*
*  Purpose
*  =======
*
*  PCUNML2 overwrites the general complex M-by-N distributed matrix
*  sub( C ) = C(IC:IC+M-1,JC:JC+N-1) with
*
*                       SIDE = 'L'          SIDE = 'R'
*  TRANS = 'N':      Q * sub( C )         sub( C ) * Q
*  TRANS = 'C':      Q**H * sub( C        sub( C ) * Q**H
*
*  where Q is a complex unitary distributed matrix defined as the
*  product of K elementary reflectors
*
*        Q = H(k)' . . . H(2)' H(1)'
*
*  as returned by PCGELQF. Q is of order M if SIDE = 'L' and of order N
*  if SIDE = 'R'.
*
*  Notes
*  =====
*
*  Each global data object is described by an associated description
*  vector.  This vector stores the information required to establish
*  the mapping between an object element and its corresponding process
*  and memory location.
*
*  Let A be a generic term for any 2D block cyclicly distributed array.
*  Such a global array has an associated description vector DESCA.
*  In the following comments, the character _ should be read as
*  "of the global array".
*
*  NOTATION        STORED IN      EXPLANATION
*  --------------- -------------- --------------------------------------
*  DTYPE_A(global) DESCA( DTYPE_ )The descriptor type.  In this case,
*                                 DTYPE_A = 1.
*  CTXT_A (global) DESCA( CTXT_ ) The BLACS context handle, indicating
*                                 the BLACS process grid A is distribu-
*                                 ted over. The context itself is glo-
*                                 bal, but the handle (the integer
*                                 value) may vary.
*  M_A    (global) DESCA( M_ )    The number of rows in the global
*                                 array A.
*  N_A    (global) DESCA( N_ )    The number of columns in the global
*                                 array A.
*  MB_A   (global) DESCA( MB_ )   The blocking factor used to distribute
*                                 the rows of the array.
*  NB_A   (global) DESCA( NB_ )   The blocking factor used to distribute
*                                 the columns of the array.
*  RSRC_A (global) DESCA( RSRC_ ) The process row over which the first
*                                 row of the array A is distributed.
*  CSRC_A (global) DESCA( CSRC_ ) The process column over which the
*                                 first column of the array A is
*                                 distributed.
*  LLD_A  (local)  DESCA( LLD_ )  The leading dimension of the local
*                                 array.  LLD_A >= MAX(1,LOCr(M_A)).
*
*  Let K be the number of rows or columns of a distributed matrix,
*  and assume that its process grid has dimension p x q.
*  LOCr( K ) denotes the number of elements of K that a process
*  would receive if K were distributed over the p processes of its
*  process column.
*  Similarly, LOCc( K ) denotes the number of elements of K that a
*  process would receive if K were distributed over the q processes of
*  its process row.
*  The values of LOCr() and LOCc() may be determined via a call to the
*  ScaLAPACK tool function, NUMROC:
*          LOCr( M ) = NUMROC( M, MB_A, MYROW, RSRC_A, NPROW ),
*          LOCc( N ) = NUMROC( N, NB_A, MYCOL, CSRC_A, NPCOL ).
*  An upper bound for these quantities may be computed by:
*          LOCr( M ) <= ceil( ceil(M/MB_A)/NPROW )*MB_A
*          LOCc( N ) <= ceil( ceil(N/NB_A)/NPCOL )*NB_A
*
*  Arguments
*  =========
*
*  SIDE    (global input) CHARACTER
*          = 'L': apply Q or Q**H from the Left;
*          = 'R': apply Q or Q**H from the Right.
*
*  TRANS   (global input) CHARACTER
*          = 'N':  No transpose, apply Q;
*          = 'C':  Conjugate transpose, apply Q**H.
*
*  M       (global input) INTEGER
*          The number of rows to be operated on i.e the number of rows
*          of the distributed submatrix sub( C ). M >= 0.
*
*  N       (global input) INTEGER
*          The number of columns to be operated on i.e the number of
*          columns of the distributed submatrix sub( C ). N >= 0.
*
*  K       (global input) INTEGER
*          The number of elementary reflectors whose product defines the
*          matrix Q.  If SIDE = 'L', M >= K >= 0, if SIDE = 'R',
*          N >= K >= 0.
*
*  A       (local input) COMPLEX pointer into the local memory
*          to an array of dimension (LLD_A,LOCc(JA+M-1)) if SIDE='L',
*          and (LLD_A,LOCc(JA+N-1)) if SIDE='R', where
*          LLD_A >= max(1,LOCr(IA+K-1)); On entry, the i-th row must
*          contain the vector which defines the elementary reflector
*          H(i), IA <= i <= IA+K-1, as returned by PCGELQF in the
*          K rows of its distributed matrix argument A(IA:IA+K-1,JA:*).
*          A(IA:IA+K-1,JA:*) is modified by the routine but restored on
*          exit.
*
*  IA      (global input) INTEGER
*          The row index in the global array A indicating the first
*          row of sub( A ).
*
*  JA      (global input) INTEGER
*          The column index in the global array A indicating the
*          first column of sub( A ).
*
*  DESCA   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix A.
*
*  TAU     (local input) COMPLEX, array, dimension LOCc(IA+K-1).
*          This array contains the scalar factors TAU(i) of the
*          elementary reflectors H(i) as returned by PCGELQF.
*          TAU is tied to the distributed matrix A.
*
*  C       (local input/local output) COMPLEX pointer into the
*          local memory to an array of dimension (LLD_C,LOCc(JC+N-1)).
*          On entry, the local pieces of the distributed matrix sub(C).
*          On exit, sub( C ) is overwritten by Q*sub( C ) or Q'*sub( C )
*          or sub( C )*Q' or sub( C )*Q.
*
*  IC      (global input) INTEGER
*          The row index in the global array C indicating the first
*          row of sub( C ).
*
*  JC      (global input) INTEGER
*          The column index in the global array C indicating the
*          first column of sub( C ).
*
*  DESCC   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix C.
*
*  WORK    (local workspace/local output) COMPLEX array,
*                                                     dimension (LWORK)
*          On exit, WORK(1) returns the minimal and optimal LWORK.
*
*  LWORK   (local or global input) INTEGER
*          The dimension of the array WORK.
*          LWORK is local input and must be at least
*          If SIDE = 'L', LWORK >= MpC0 + MAX( MAX( 1, NqC0 ), NUMROC(
*                  NUMROC( M+IROFFC,MB_A,0,0,NPROW ),MB_A,0,0,LCMP ) );
*          if SIDE = 'R', LWORK >= NqC0 + MAX( 1, MpC0 );
*
*          where LCMP = LCM / NPROW with LCM = ICLM( NPROW, NPCOL ),
*
*          IROFFC = MOD( IC-1, MB_C ), ICOFFC = MOD( JC-1, NB_C ),
*          ICROW = INDXG2P( IC, MB_C, MYROW, RSRC_C, NPROW ),
*          ICCOL = INDXG2P( JC, NB_C, MYCOL, CSRC_C, NPCOL ),
*          MpC0 = NUMROC( M+IROFFC, MB_C, MYROW, ICROW, NPROW ),
*          NqC0 = NUMROC( N+ICOFFC, NB_C, MYCOL, ICCOL, NPCOL ),
*
*          ILCM, INDXG2P and NUMROC are ScaLAPACK tool functions;
*          MYROW, MYCOL, NPROW and NPCOL can be determined by calling
*          the subroutine BLACS_GRIDINFO.
*
*          If LWORK = -1, then LWORK is global input and a workspace
*          query is assumed; the routine only calculates the minimum
*          and optimal size for all work arrays. Each of these
*          values is returned in the first entry of the corresponding
*          work array, and no error message is issued by PXERBLA.
*
*
*  INFO    (local output) INTEGER
*          = 0:  successful exit
*          < 0:  If the i-th argument is an array and the j-entry had
*                an illegal value, then INFO = -(i*100+j), if the i-th
*                argument is a scalar and had an illegal value, then
*                INFO = -i.
*
*  Alignment requirements
*  ======================
*
*  The distributed submatrices A(IA:*, JA:*) and C(IC:IC+M-1,JC:JC+N-1)
*  must verify some alignment properties, namely the following
*  expressions should be true:
*
*  If SIDE = 'L',
*    ( NB_A.EQ.MB_C .AND. ICOFFA.EQ.IROFFC )
*  If SIDE = 'R',
*    ( NB_A.EQ.NB_C .AND. ICOFFA.EQ.ICOFFC .AND. IACOL.EQ.ICCOL )
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            BLOCK_CYCLIC_2D, CSRC_, CTXT_, DLEN_, DTYPE_,
     $                   lld_, mb_, m_, nb_, n_, rsrc_
      parameter( block_cyclic_2d = 1, dlen_ = 9, dtype_ = 1,
     $                     ctxt_ = 2, m_ = 3, n_ = 4, mb_ = 5, nb_ = 6,
     $                     rsrc_ = 7, csrc_ = 8, lld_ = 9 )
      COMPLEX            ONE
      parameter( one  = ( 1.0e+0, 0.0e+0 ) )
*     ..
*     .. Local Scalars ..
      LOGICAL            LEFT, LQUERY, NOTRAN
      CHARACTER          COLBTOP, ROWBTOP
      INTEGER            I, I1, I2, I3, IACOL, ICC, ICCOL, ICOFFA,
     $                   icoffc, icrow, ictxt, iroffc, jcc, lcm, lcmp,
     $                   lwmin, mi, mpc0, mycol, myrow, ni, npcol,
     $                   nprow, nq, nqc0
      COMPLEX            AII
*     ..
*     .. External Subroutines ..
      EXTERNAL           blacs_abort, blacs_gridinfo, chk1mat, pcelset,
     $                   pcelset2, pclacgv, pclarf, pclarfc,
     $                   pb_topget, pb_topset, pxerbla
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      INTEGER            ILCM, INDXG2P, NUMROC
      EXTERNAL           ilcm, indxg2p, lsame, numroc
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          cmplx, max, mod, real
*     ..
*     .. Executable Statements ..
*
*     Get grid parameters
*
      ictxt = desca( ctxt_ )
      CALL blacs_gridinfo( ictxt, nprow, npcol, myrow, mycol )
*
*     Test the input parameters
*
      info = 0
      IF( nprow.EQ.-1 ) THEN
         info = -(900+ctxt_)
      ELSE
         left = lsame( side, 'L' )
         notran = lsame( trans, 'N' )
*
*        NQ is the order of Q
*
         IF( left ) THEN
            nq = m
            CALL chk1mat( k, 5, m, 3, ia, ja, desca, 9, info )
         ELSE
            nq = n
            CALL chk1mat( k, 5, n, 4, ia, ja, desca, 9, info )
         END IF
         CALL chk1mat( m, 3, n, 4, ic, jc, descc, 14, info )
         IF( info.EQ.0 ) THEN
            icoffa = mod( ja-1, desca( nb_ ) )
            iroffc = mod( ic-1, descc( mb_ ) )
            icoffc = mod( jc-1, descc( nb_ ) )
            iacol = indxg2p( ja, desca( nb_ ), mycol, desca( csrc_ ),
     $                       npcol )
            icrow = indxg2p( ic, descc( mb_ ), myrow, descc( rsrc_ ),
     $                       nprow )
            iccol = indxg2p( jc, descc( nb_ ), mycol, descc( csrc_ ),
     $                       npcol )
            mpc0 = numroc( m+iroffc, descc( mb_ ), myrow, icrow, nprow )
            nqc0 = numroc( n+icoffc, descc( nb_ ), mycol, iccol, npcol )
*
            IF( left ) THEN
               lcm = ilcm( nprow, npcol )
               lcmp = lcm / nprow
               lwmin = mpc0 + max( max( 1, nqc0 ), numroc( numroc(
     $                 m+iroffc, desca( mb_ ), 0, 0, nprow ),
     $                 desca( mb_ ), 0, 0, lcmp ) )
            ELSE
               nqc0 = numroc( n+icoffc, descc( nb_ ), mycol, iccol,
     $                        npcol )
               mpc0 = numroc( m+iroffc, descc( mb_ ), myrow, icrow,
     $                        nprow )
               lwmin = nqc0 + max( 1, mpc0 )
            END IF
*
            work( 1 ) = cmplx( real( lwmin ) )
            lquery = ( lwork.EQ.-1 )
            IF( .NOT.left .AND. .NOT.lsame( side, 'R' ) ) THEN
               info = -1
            ELSE IF( .NOT.notran .AND. .NOT.lsame( trans, 'C' ) ) THEN
               info = -2
            ELSE IF( k.LT.0 .OR. k.GT.nq ) THEN
               info = -5
            ELSE IF( left .AND. desca( nb_ ).NE.descc( mb_ ) ) THEN
               info = -(900+nb_)
            ELSE IF( left .AND. icoffa.NE.iroffc ) THEN
               info = -12
            ELSE IF( .NOT.left .AND. icoffa.NE.icoffc ) THEN
               info = -13
            ELSE IF( .NOT.left .AND. iacol.NE.iccol ) THEN
               info = -13
            ELSE IF( .NOT.left .AND. desca( nb_ ).NE.descc( nb_ ) ) THEN
               info = -(1400+nb_)
            ELSE IF( ictxt.NE.descc( ctxt_ ) ) THEN
               info = -(1400+ctxt_)
            ELSE IF( lwork.LT.lwmin .AND. .NOT.lquery ) THEN
               info = -16
            END IF
         END IF
      END IF
*
      IF( info.NE.0 ) THEN
         CALL pxerbla( ictxt, 'PCUNML2', -info )
         CALL blacs_abort( ictxt, 1 )
         RETURN
      ELSE IF( lquery ) THEN
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( m.EQ.0 .OR. n.EQ.0 .OR. k.EQ.0 )
     $   RETURN
*
      CALL pb_topget( ictxt, 'Broadcast', 'Rowwise', rowbtop )
      CALL pb_topget( ictxt, 'Broadcast', 'Columnwise', colbtop )
*
      IF( ( left .AND. notran .OR. .NOT.left .AND. .NOT.notran ) ) THEN
         i1 = ia
         i2 = ia + k - 1
         i3 = 1
      ELSE
         i1 = ia + k -1
         i2 = ia
         i3 = -1
      END IF
*
      IF( left ) THEN
         ni  = n
         jcc = jc
      ELSE
         mi  = m
         icc = ic
         CALL pb_topset( ictxt, 'Broadcast', 'Rowwise', ' ' )
         IF( notran ) THEN
            CALL pb_topset( ictxt, 'Broadcast', 'Columnwise', 'D-ring' )
         ELSE
            CALL pb_topset( ictxt, 'Broadcast', 'Columnwise', 'I-ring' )
         END IF
      END IF
*
      DO 10 i = i1, i2, i3
         IF( left ) THEN
*
*           H(i) or H(i)' is applied to C(i:ic+m-1,jc:jc+n-1)
*
            mi  = m - i + ia
            icc = ic + i - ia
         ELSE
*
*           H(i) or H(i)' is applied to C(ic:ic+m-1,jc+i-ia:jc+n-1)
*
            ni  = n - i + ia
            jcc = jc + i - ia
         END IF
*
*        Apply H(i) or H(i)'
*
         IF( i-ia+1.LT.nq )
     $      CALL pclacgv( nq-i+ia-1, a, i, ja+i-ia+1, desca,
     $                    desca( m_ ) )
         CALL pcelset2( aii, a, i, ja+i-ia, desca, one )
         IF( notran ) THEN
            CALL pclarfc( side, mi, ni, a, i, ja+i-ia, desca,
     $                    desca( m_ ), tau, c, icc, jcc, descc, work )
         ELSE
            CALL pclarf( side, mi, ni, a, i, ja+i-ia, desca,
     $                   desca( m_ ), tau, c, icc, jcc, descc, work )
         END IF
         CALL pcelset( a, i, ja+i-ia, desca, aii )
         IF( i-ia+1.LT.nq )
     $      CALL pclacgv( nq-i+ia-1, a, i, ja+i-ia+1, desca,
     $                    desca( m_ ) )
*
   10 CONTINUE
*
      CALL pb_topset( ictxt, 'Broadcast', 'Rowwise', rowbtop )
      CALL pb_topset( ictxt, 'Broadcast', 'Columnwise', colbtop )
*
      work( 1 ) = cmplx( real( lwmin ) )
*
      RETURN
*
*     End of PCUNML2
*
      SUBROUTINE pcunml2( SIDE, TRANS, M, N, K, A, IA, JA, DESCA, TAU, …
      END