pdsygst.f

Go to the documentation of this file.

*
*
      SUBROUTINE pdsygst( IBTYPE, UPLO, N, A, IA, JA, DESCA, B, IB, JB,
     $                    DESCB, SCALE, INFO )
*
*  -- ScaLAPACK routine (version 1.7) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     May 1, 1997
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            IA, IB, IBTYPE, INFO, JA, JB, N
      DOUBLE PRECISION   SCALE
*     ..
*     .. Array Arguments ..
      INTEGER            DESCA( * ), DESCB( * )
      DOUBLE PRECISION   A( * ), B( * )
*     ..
*
*  Purpose
*  =======
*
*  PDSYGST reduces a real symmetric-definite generalized eigenproblem
*  to standard form.
*
*  In the following sub( A ) denotes A( IA:IA+N-1, JA:JA+N-1 ) and
*  sub( B ) denotes B( IB:IB+N-1, JB:JB+N-1 ).
*
*  If IBTYPE = 1, the problem is sub( A )*x = lambda*sub( B )*x,
*  and sub( A ) is overwritten by inv(U**T)*sub( A )*inv(U) or
*  inv(L)*sub( A )*inv(L**T)
*
*  If IBTYPE = 2 or 3, the problem is sub( A )*sub( B )*x = lambda*x or
*  sub( B )*sub( A )*x = lambda*x, and sub( A ) is overwritten by
*  U*sub( A )*U**T or L**T*sub( A )*L.
*
*  sub( B ) must have been previously factorized as U**T*U or L*L**T by
*  PDPOTRF.
*
*  Notes
*  =====
*
*  Each global data object is described by an associated description
*  vector.  This vector stores the information required to establish
*  the mapping between an object element and its corresponding process
*  and memory location.
*
*  Let A be a generic term for any 2D block cyclicly distributed array.
*  Such a global array has an associated description vector DESCA.
*  In the following comments, the character _ should be read as
*  "of the global array".
*
*  NOTATION        STORED IN      EXPLANATION
*  --------------- -------------- --------------------------------------
*  DTYPE_A(global) DESCA( DTYPE_ )The descriptor type.  In this case,
*                                 DTYPE_A = 1.
*  CTXT_A (global) DESCA( CTXT_ ) The BLACS context handle, indicating
*                                 the BLACS process grid A is distribu-
*                                 ted over. The context itself is glo-
*                                 bal, but the handle (the integer
*                                 value) may vary.
*  M_A    (global) DESCA( M_ )    The number of rows in the global
*                                 array A.
*  N_A    (global) DESCA( N_ )    The number of columns in the global
*                                 array A.
*  MB_A   (global) DESCA( MB_ )   The blocking factor used to distribute
*                                 the rows of the array.
*  NB_A   (global) DESCA( NB_ )   The blocking factor used to distribute
*                                 the columns of the array.
*  RSRC_A (global) DESCA( RSRC_ ) The process row over which the first
*                                 row of the array A is distributed.
*  CSRC_A (global) DESCA( CSRC_ ) The process column over which the
*                                 first column of the array A is
*                                 distributed.
*  LLD_A  (local)  DESCA( LLD_ )  The leading dimension of the local
*                                 array.  LLD_A >= MAX(1,LOCr(M_A)).
*
*  Let K be the number of rows or columns of a distributed matrix,
*  and assume that its process grid has dimension p x q.
*  LOCr( K ) denotes the number of elements of K that a process
*  would receive if K were distributed over the p processes of its
*  process column.
*  Similarly, LOCc( K ) denotes the number of elements of K that a
*  process would receive if K were distributed over the q processes of
*  its process row.
*  The values of LOCr() and LOCc() may be determined via a call to the
*  ScaLAPACK tool function, NUMROC:
*          LOCr( M ) = NUMROC( M, MB_A, MYROW, RSRC_A, NPROW ),
*          LOCc( N ) = NUMROC( N, NB_A, MYCOL, CSRC_A, NPCOL ).
*  An upper bound for these quantities may be computed by:
*          LOCr( M ) <= ceil( ceil(M/MB_A)/NPROW )*MB_A
*          LOCc( N ) <= ceil( ceil(N/NB_A)/NPCOL )*NB_A
*
*  Arguments
*  =========
*
*  IBTYPE   (global input) INTEGER
*          = 1: compute inv(U**T)*sub( A )*inv(U) or
*               inv(L)*sub( A )*inv(L**T);
*          = 2 or 3: compute U*sub( A )*U**T or L**T*sub( A )*L.
*
*  UPLO    (global input) CHARACTER
*          = 'U':  Upper triangle of sub( A ) is stored and sub( B ) is
*                  factored as U**T*U;
*          = 'L':  Lower triangle of sub( A ) is stored and sub( B ) is
*                  factored as L*L**T.
*
*  N       (global input) INTEGER
*          The order of the matrices sub( A ) and sub( B ).  N >= 0.
*
*  A       (local input/local output) DOUBLE PRECISION pointer into the
*          local memory to an array of dimension (LLD_A, LOCc(JA+N-1)).
*          On entry, this array contains the local pieces of the
*          N-by-N symmetric distributed matrix sub( A ). If UPLO = 'U',
*          the leading N-by-N upper triangular part of sub( A ) contains
*          the upper triangular part of the matrix, and its strictly
*          lower triangular part is not referenced.  If UPLO = 'L', the
*          leading N-by-N lower triangular part of sub( A ) contains
*          the lower triangular part of the matrix, and its strictly
*          upper triangular part is not referenced.
*
*          On exit, if INFO = 0, the transformed matrix, stored in the
*          same format as sub( A ).
*
*  IA      (global input) INTEGER
*          A's global row index, which points to the beginning of the
*          submatrix which is to be operated on.
*
*  JA      (global input) INTEGER
*          A's global column index, which points to the beginning of
*          the submatrix which is to be operated on.
*
*  DESCA   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix A.
*
*  B       (local input) DOUBLE PRECISION pointer into the local memory
*          to an array of dimension (LLD_B, LOCc(JB+N-1)). On entry,
*          this array contains the local pieces of the triangular factor
*          from the Cholesky factorization of sub( B ), as returned by
*          PDPOTRF.
*
*  IB      (global input) INTEGER
*          B's global row index, which points to the beginning of the
*          submatrix which is to be operated on.
*
*  JB      (global input) INTEGER
*          B's global column index, which points to the beginning of
*          the submatrix which is to be operated on.
*
*  DESCB   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix B.
*
*  SCALE   (global output) DOUBLE PRECISION
*          Amount by which the eigenvalues should be scaled to
*          compensate for the scaling performed in this routine.
*          At present, SCALE is always returned as 1.0, it is
*          returned here to allow for future enhancement.
*
*  INFO    (global output) INTEGER
*          = 0:  successful exit
*          < 0:  If the i-th argument is an array and the j-entry had
*                an illegal value, then INFO = -(i*100+j), if the i-th
*                argument is a scalar and had an illegal value, then
*                INFO = -i.
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            BLOCK_CYCLIC_2D, DLEN_, DTYPE_, CTXT_, M_, N_,
     $                   mb_, nb_, rsrc_, csrc_, lld_
      parameter( block_cyclic_2d = 1, dlen_ = 9, dtype_ = 1,
     $                   ctxt_ = 2, m_ = 3, n_ = 4, mb_ = 5, nb_ = 6,
     $                   rsrc_ = 7, csrc_ = 8, lld_ = 9 )
      DOUBLE PRECISION   ONE, HALF
      parameter( one = 1.0d+0, half = 0.5d+0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            UPPER
      INTEGER            IACOL, IAROW, IBCOL, IBROW, ICOFFA, ICOFFB,
     $                   ictxt, iroffa, iroffb, k, kb, mycol, myrow, nb,
     $                   npcol, nprow
*     ..
*     .. Local Arrays ..
      INTEGER            IDUM1( 2 ), IDUM2( 2 )
*     ..
*     .. External Subroutines ..
      EXTERNAL           blacs_gridinfo, chk1mat, pchk2mat, pdsygs2,
     $                   pdsymm, pdsyr2k, pdtrmm, pdtrsm, pxerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          ichar, min, mod
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      INTEGER            ICEIL, INDXG2P
      EXTERNAL           lsame, iceil, indxg2p
*     ..
*     .. Executable Statements ..
*       This is just to keep ftnchek happy
      IF( block_cyclic_2d*csrc_*ctxt_*dlen_*dtype_*lld_*mb_*m_*nb_*n_*
     $    rsrc_.LT.0 )RETURN
*
*     Get grid parameters
*
      scale = one
*
      ictxt = desca( ctxt_ )
      CALL blacs_gridinfo( ictxt, nprow, npcol, myrow, mycol )
*
*     Test the input parameters
*
      info = 0
      IF( nprow.EQ.-1 ) THEN
         info = -( 700+ctxt_ )
      ELSE
         upper = lsame( uplo, 'U' )
         CALL chk1mat( n, 3, n, 3, ia, ja, desca, 7, info )
         CALL chk1mat( n, 3, n, 3, ib, jb, descb, 11, info )
         IF( info.EQ.0 ) THEN
            iarow = indxg2p( ia, desca( mb_ ), myrow, desca( rsrc_ ),
     $              nprow )
            ibrow = indxg2p( ib, descb( mb_ ), myrow, descb( rsrc_ ),
     $              nprow )
            iacol = indxg2p( ja, desca( nb_ ), mycol, desca( csrc_ ),
     $              npcol )
            ibcol = indxg2p( jb, descb( nb_ ), mycol, descb( csrc_ ),
     $              npcol )
            iroffa = mod( ia-1, desca( mb_ ) )
            icoffa = mod( ja-1, desca( nb_ ) )
            iroffb = mod( ib-1, descb( mb_ ) )
            icoffb = mod( jb-1, descb( nb_ ) )
            IF( ibtype.LT.1 .OR. ibtype.GT.3 ) THEN
               info = -1
            ELSE IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
               info = -2
            ELSE IF( n.LT.0 ) THEN
               info = -3
            ELSE IF( iroffa.NE.0 ) THEN
               info = -5
            ELSE IF( icoffa.NE.0 ) THEN
               info = -6
            ELSE IF( desca( mb_ ).NE.desca( nb_ ) ) THEN
               info = -( 700+nb_ )
            ELSE IF( iroffb.NE.0 .OR. ibrow.NE.iarow ) THEN
               info = -9
            ELSE IF( icoffb.NE.0 .OR. ibcol.NE.iacol ) THEN
               info = -10
            ELSE IF( descb( mb_ ).NE.desca( mb_ ) ) THEN
               info = -( 1100+mb_ )
            ELSE IF( descb( nb_ ).NE.desca( nb_ ) ) THEN
               info = -( 1100+nb_ )
            ELSE IF( ictxt.NE.descb( ctxt_ ) ) THEN
               info = -( 1100+ctxt_ )
            END IF
         END IF
         idum1( 1 ) = ibtype
         idum2( 1 ) = 1
         IF( upper ) THEN
            idum1( 2 ) = ichar( 'U' )
         ELSE
            idum1( 2 ) = ichar( 'L' )
         END IF
         idum2( 2 ) = 2
         CALL pchk2mat( n, 3, n, 3, ia, ja, desca, 7, n, 3, n, 3, ib,
     $                  jb, descb, 11, 2, idum1, idum2, info )
      END IF
*
      IF( info.NE.0 ) THEN
         CALL pxerbla( ictxt, 'PDSYGST', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 )
     $   RETURN
*
      IF( ibtype.EQ.1 ) THEN
         IF( upper ) THEN
*
*           Compute inv(U')*sub( A )*inv(U)
*
            k = 1
            nb = desca( nb_ )
            kb = min( iceil( ja, nb )*nb, ja+n-1 ) - ja + 1
*
   10       CONTINUE
*
*           Update the upper triangle of A(ia+k-1:ia+n-1,ja+k-1:ja+n-1)
*
            CALL pdsygs2( ibtype, uplo, kb, a, ia+k-1, ja+k-1, desca, b,
     $                    ib+k-1, ib+k-1, descb, info )
            IF( k+kb.LE.n ) THEN
               CALL pdtrsm( 'Left', uplo, 'Transpose', 'Non-unit', kb,
     $                      n-k-kb+1, one, b, ib+k-1, jb+k-1, descb, a,
     $                      ia+k-1, ja+k+kb-1, desca )
               CALL pdsymm( 'Left', uplo, kb, n-k-kb+1, -half, a,
     $                      ia+k-1, ja+k-1, desca, b, ib+k-1, jb+k+kb-1,
     $                      descb, one, a, ia+k-1, ja+k+kb-1, desca )
               CALL pdsyr2k( uplo, 'Transpose', n-k-kb+1, kb, -one, a,
     $                       ia+k-1, ja+k+kb-1, desca, b, ib+k-1,
     $                       jb+k+kb-1, descb, one, a, ia+k+kb-1,
     $                       ja+k+kb-1, desca )
               CALL pdsymm( 'Left', uplo, kb, n-k-kb+1, -half, a,
     $                      ia+k-1, ja+k-1, desca, b, ib+k-1, jb+k+kb-1,
     $                      descb, one, a, ia+k-1, ja+k+kb-1, desca )
               CALL pdtrsm( 'Right', uplo, 'No transpose', 'Non-unit',
     $                      kb, n-k-kb+1, one, b, ib+k+kb-1, jb+k+kb-1,
     $                      descb, a, ia+k-1, ja+k+kb-1, desca )
            END IF
            k = k + kb
            kb = min( n-k+1, nb )
*
            IF( k.LE.n )
     $         GO TO 10
*
         ELSE
*
*           Compute inv(L)*sub( A )*inv(L')
*
            k = 1
            nb = desca( mb_ )
            kb = min( iceil( ia, nb )*nb, ia+n-1 ) - ia + 1
*
   20       CONTINUE
*
*           Update the lower triangle of A(ia+k-1:ia+n-1,ja+k-1:ja+n-1)
*
            CALL pdsygs2( ibtype, uplo, kb, a, ia+k-1, ja+k-1, desca, b,
     $                    ib+k-1, jb+k-1, descb, info )
            IF( k+kb.LE.n ) THEN
               CALL pdtrsm( 'Right', uplo, 'Transpose', 'Non-unit',
     $                      n-k-kb+1, kb, one, b, ib+k-1, jb+k-1, descb,
     $                      a, ia+k+kb-1, ja+k-1, desca )
               CALL pdsymm( 'Right', uplo, n-k-kb+1, kb, -half, a,
     $                      ia+k-1, ja+k-1, desca, b, ib+k+kb-1, jb+k-1,
     $                      descb, one, a, ia+k+kb-1, ja+k-1, desca )
               CALL pdsyr2k( uplo, 'No transpose', n-k-kb+1, kb, -one,
     $                       a, ia+k+kb-1, ja+k-1, desca, b, ib+k+kb-1,
     $                       jb+k-1, descb, one, a, ia+k+kb-1,
     $                       ja+k+kb-1, desca )
               CALL pdsymm( 'Right', uplo, n-k-kb+1, kb, -half, a,
     $                      ia+k-1, ja+k-1, desca, b, ib+k+kb-1, jb+k-1,
     $                      descb, one, a, ia+k+kb-1, ja+k-1, desca )
               CALL pdtrsm( 'Left', uplo, 'No transpose', 'Non-unit',
     $                      n-k-kb+1, kb, one, b, ib+k+kb-1, jb+k+kb-1,
     $                      descb, a, ia+k+kb-1, ja+k-1, desca )
            END IF
            k = k + kb
            kb = min( n-k+1, nb )
*
            IF( k.LE.n )
     $         GO TO 20
*
         END IF
*
      ELSE
*
         IF( upper ) THEN
*
*           Compute U*sub( A )*U'
*
            k = 1
            nb = desca( nb_ )
            kb = min( iceil( ja, nb )*nb, ja+n-1 ) - ja + 1
*
   30       CONTINUE
*
*           Update the upper triangle of A(ia:ia+k+kb-2,ja:ja+k+kb-2)
*
            CALL pdtrmm( 'Left', uplo, 'No transpose', 'Non-unit', k-1,
     $                   kb, one, b, ib, jb, descb, a, ia, ja+k-1,
     $                   desca )
            CALL pdsymm( 'Right', uplo, k-1, kb, half, a, ia+k-1,
     $                   ja+k-1, desca, b, ib, jb+k-1, descb, one, a,
     $                   ia, ja+k-1, desca )
            CALL pdsyr2k( uplo, 'No transpose', k-1, kb, one, a, ia,
     $                    ja+k-1, desca, b, ib, jb+k-1, descb, one, a,
     $                    ia, ja, desca )
            CALL pdsymm( 'Right', uplo, k-1, kb, half, a, ia+k-1,
     $                   ja+k-1, desca, b, ib, jb+k-1, descb, one, a,
     $                   ia, ja+k-1, desca )
            CALL pdtrmm( 'Right', uplo, 'Transpose', 'Non-unit', k-1,
     $                   kb, one, b, ib+k-1, jb+k-1, descb, a, ia,
     $                   ja+k-1, desca )
            CALL pdsygs2( ibtype, uplo, kb, a, ia+k-1, ja+k-1, desca, b,
     $                    ib+k-1, jb+k-1, descb, info )
*
            k = k + kb
            kb = min( n-k+1, nb )
*
            IF( k.LE.n )
     $         GO TO 30
*
         ELSE
*
*           Compute L'*sub( A )*L
*
            k = 1
            nb = desca( mb_ )
            kb = min( iceil( ia, nb )*nb, ia+n-1 ) - ia + 1
*
   40       CONTINUE
*
*           Update the lower triangle of A(ia:ia+k+kb-2,ja:ja+k+kb-2)
*
            CALL pdtrmm( 'Right', uplo, 'No transpose', 'Non-unit', kb,
     $                   k-1, one, b, ib, jb, descb, a, ia+k-1, ja,
     $                   desca )
            CALL pdsymm( 'Left', uplo, kb, k-1, half, a, ia+k-1, ja+k-1,
     $                   desca, b, ib+k-1, jb, descb, one, a, ia+k-1,
     $                   ja, desca )
            CALL pdsyr2k( uplo, 'Transpose', k-1, kb, one, a, ia+k-1,
     $                    ja, desca, b, ib+k-1, jb, descb, one, a, ia,
     $                    ja, desca )
            CALL pdsymm( 'Left', uplo, kb, k-1, half, a, ia+k-1, ja+k-1,
     $                   desca, b, ib+k-1, jb, descb, one, a, ia+k-1,
     $                   ja, desca )
            CALL pdtrmm( 'Left', uplo, 'Transpose', 'Non-unit', kb, k-1,
     $                   one, b, ib+k-1, jb+k-1, descb, a, ia+k-1, ja,
     $                   desca )
            CALL pdsygs2( ibtype, uplo, kb, a, ia+k-1, ja+k-1, desca, b,
     $                    ib+k-1, jb+k-1, descb, info )
*
            k = k + kb
            kb = min( n-k+1, nb )
*
            IF( k.LE.n )
     $         GO TO 40
*
         END IF
*
      END IF
*
      RETURN
*
*     End of PDSYGST
*
      END