slagge.f

Go to the documentation of this file.

      SUBROUTINE slagge( M, N, KL, KU, D, A, LDA, ISEED, WORK, INFO )
*
*  -- LAPACK auxiliary test routine (version 3.1)
*     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
*     November 2006
*
*     .. Scalar Arguments ..
      INTEGER            INFO, KL, KU, LDA, M, N
*     ..
*     .. Array Arguments ..
      INTEGER            ISEED( 4 )
      REAL               A( LDA, * ), D( * ), WORK( * )
*     ..
*
*  Purpose
*  =======
*
*  SLAGGE generates a real general m by n matrix A, by pre- and post-
*  multiplying a real diagonal matrix D with random orthogonal matrices:
*  A = U*D*V. The lower and upper bandwidths may then be reduced to
*  kl and ku by additional orthogonal transformations.
*
*  Arguments
*  =========
*
*  M       (input) INTEGER
*          The number of rows of the matrix A.  M >= 0.
*
*  N       (input) INTEGER
*          The number of columns of the matrix A.  N >= 0.
*
*  KL      (input) INTEGER
*          The number of nonzero subdiagonals within the band of A.
*          0 <= KL <= M-1.
*
*  KU      (input) INTEGER
*          The number of nonzero superdiagonals within the band of A.
*          0 <= KU <= N-1.
*
*  D       (input) REAL array, dimension (min(M,N))
*          The diagonal elements of the diagonal matrix D.
*
*  A       (output) REAL array, dimension (LDA,N)
*          The generated m by n matrix A.
*
*  LDA     (input) INTEGER
*          The leading dimension of the array A.  LDA >= M.
*
*  ISEED   (input/output) INTEGER array, dimension (4)
*          On entry, the seed of the random number generator; the array
*          elements must be between 0 and 4095, and ISEED(4) must be
*          odd.
*          On exit, the seed is updated.
*
*  WORK    (workspace) REAL array, dimension (M+N)
*
*  INFO    (output) INTEGER
*          = 0: successful exit
*          < 0: if INFO = -i, the i-th argument had an illegal value
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ZERO, ONE
      parameter( zero = 0.0e+0, one = 1.0e+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, J
      REAL               TAU, WA, WB, WN
*     ..
*     .. External Subroutines ..
      EXTERNAL           sgemv, sger, slarnv, sscal, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min, sign
*     ..
*     .. External Functions ..
      REAL               SNRM2
      EXTERNAL           snrm2
*     ..
*     .. Executable Statements ..
*
*     Test the input arguments
*
      info = 0
      IF( m.LT.0 ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( kl.LT.0 .OR. kl.GT.m-1 ) THEN
         info = -3
      ELSE IF( ku.LT.0 .OR. ku.GT.n-1 ) THEN
         info = -4
      ELSE IF( lda.LT.max( 1, m ) ) THEN
         info = -7
      END IF
      IF( info.LT.0 ) THEN
         CALL xerbla( 'SLAGGE', -info )
         RETURN
      END IF
*
*     initialize A to diagonal matrix
*
      DO 20 j = 1, n
         DO 10 i = 1, m
            a( i, j ) = zero
   10    CONTINUE
   20 CONTINUE
      DO 30 i = 1, min( m, n )
         a( i, i ) = d( i )
   30 CONTINUE
*
*     pre- and post-multiply A by random orthogonal matrices
*
      DO 40 i = min( m, n ), 1, -1
         IF( i.LT.m ) THEN
*
*           generate random reflection
*
            CALL slarnv( 3, iseed, m-i+1, work )
            wn = snrm2( m-i+1, work, 1 )
            wa = sign( wn, work( 1 ) )
            IF( wn.EQ.zero ) THEN
               tau = zero
            ELSE
               wb = work( 1 ) + wa
               CALL sscal( m-i, one / wb, work( 2 ), 1 )
               work( 1 ) = one
               tau = wb / wa
            END IF
*
*           multiply A(i:m,i:n) by random reflection from the left
*
            CALL sgemv( 'Transpose', m-i+1, n-i+1, one, a( i, i ), lda,
     $                  work, 1, zero, work( m+1 ), 1 )
            CALL sger( m-i+1, n-i+1, -tau, work, 1, work( m+1 ), 1,
     $                 a( i, i ), lda )
         END IF
         IF( i.LT.n ) THEN
*
*           generate random reflection
*
            CALL slarnv( 3, iseed, n-i+1, work )
            wn = snrm2( n-i+1, work, 1 )
            wa = sign( wn, work( 1 ) )
            IF( wn.EQ.zero ) THEN
               tau = zero
            ELSE
               wb = work( 1 ) + wa
               CALL sscal( n-i, one / wb, work( 2 ), 1 )
               work( 1 ) = one
               tau = wb / wa
            END IF
*
*           multiply A(i:m,i:n) by random reflection from the right
*
            CALL sgemv( 'No transpose', m-i+1, n-i+1, one, a( i, i ),
     $                  lda, work, 1, zero, work( n+1 ), 1 )
            CALL sger( m-i+1, n-i+1, -tau, work( n+1 ), 1, work, 1,
     $                 a( i, i ), lda )
         END IF
   40 CONTINUE
*
*     Reduce number of subdiagonals to KL and number of superdiagonals
*     to KU
*
      DO 70 i = 1, max( m-1-kl, n-1-ku )
         IF( kl.LE.ku ) THEN
*
*           annihilate subdiagonal elements first (necessary if KL = 0)
*
            IF( i.LE.min( m-1-kl, n ) ) THEN
*
*              generate reflection to annihilate A(kl+i+1:m,i)
*
               wn = snrm2( m-kl-i+1, a( kl+i, i ), 1 )
               wa = sign( wn, a( kl+i, i ) )
               IF( wn.EQ.zero ) THEN
                  tau = zero
               ELSE
                  wb = a( kl+i, i ) + wa
                  CALL sscal( m-kl-i, one / wb, a( kl+i+1, i ), 1 )
                  a( kl+i, i ) = one
                  tau = wb / wa
               END IF
*
*              apply reflection to A(kl+i:m,i+1:n) from the left
*
               CALL sgemv( 'Transpose', m-kl-i+1, n-i, one,
     $                     a( kl+i, i+1 ), lda, a( kl+i, i ), 1, zero,
     $                     work, 1 )
               CALL sger( m-kl-i+1, n-i, -tau, a( kl+i, i ), 1, work, 1,
     $                    a( kl+i, i+1 ), lda )
               a( kl+i, i ) = -wa
            END IF
*
            IF( i.LE.min( n-1-ku, m ) ) THEN
*
*              generate reflection to annihilate A(i,ku+i+1:n)
*
               wn = snrm2( n-ku-i+1, a( i, ku+i ), lda )
               wa = sign( wn, a( i, ku+i ) )
               IF( wn.EQ.zero ) THEN
                  tau = zero
               ELSE
                  wb = a( i, ku+i ) + wa
                  CALL sscal( n-ku-i, one / wb, a( i, ku+i+1 ), lda )
                  a( i, ku+i ) = one
                  tau = wb / wa
               END IF
*
*              apply reflection to A(i+1:m,ku+i:n) from the right
*
               CALL sgemv( 'No transpose', m-i, n-ku-i+1, one,
     $                     a( i+1, ku+i ), lda, a( i, ku+i ), lda, zero,
     $                     work, 1 )
               CALL sger( m-i, n-ku-i+1, -tau, work, 1, a( i, ku+i ),
     $                    lda, a( i+1, ku+i ), lda )
               a( i, ku+i ) = -wa
            END IF
         ELSE
*
*           annihilate superdiagonal elements first (necessary if
*           KU = 0)
*
            IF( i.LE.min( n-1-ku, m ) ) THEN
*
*              generate reflection to annihilate A(i,ku+i+1:n)
*
               wn = snrm2( n-ku-i+1, a( i, ku+i ), lda )
               wa = sign( wn, a( i, ku+i ) )
               IF( wn.EQ.zero ) THEN
                  tau = zero
               ELSE
                  wb = a( i, ku+i ) + wa
                  CALL sscal( n-ku-i, one / wb, a( i, ku+i+1 ), lda )
                  a( i, ku+i ) = one
                  tau = wb / wa
               END IF
*
*              apply reflection to A(i+1:m,ku+i:n) from the right
*
               CALL sgemv( 'No transpose', m-i, n-ku-i+1, one,
     $                     a( i+1, ku+i ), lda, a( i, ku+i ), lda, zero,
     $                     work, 1 )
               CALL sger( m-i, n-ku-i+1, -tau, work, 1, a( i, ku+i ),
     $                    lda, a( i+1, ku+i ), lda )
               a( i, ku+i ) = -wa
            END IF
*
            IF( i.LE.min( m-1-kl, n ) ) THEN
*
*              generate reflection to annihilate A(kl+i+1:m,i)
*
               wn = snrm2( m-kl-i+1, a( kl+i, i ), 1 )
               wa = sign( wn, a( kl+i, i ) )
               IF( wn.EQ.zero ) THEN
                  tau = zero
               ELSE
                  wb = a( kl+i, i ) + wa
                  CALL sscal( m-kl-i, one / wb, a( kl+i+1, i ), 1 )
                  a( kl+i, i ) = one
                  tau = wb / wa
               END IF
*
*              apply reflection to A(kl+i:m,i+1:n) from the left
*
               CALL sgemv( 'Transpose', m-kl-i+1, n-i, one,
     $                     a( kl+i, i+1 ), lda, a( kl+i, i ), 1, zero,
     $                     work, 1 )
               CALL sger( m-kl-i+1, n-i, -tau, a( kl+i, i ), 1, work, 1,
     $                    a( kl+i, i+1 ), lda )
               a( kl+i, i ) = -wa
            END IF
         END IF
*
         DO 50 j = kl + i + 1, m
            a( j, i ) = zero
   50    CONTINUE
*
         DO 60 j = ku + i + 1, n
            a( i, j ) = zero
   60    CONTINUE
   70 CONTINUE
      RETURN
*
*     End of SLAGGE
*
      END