psgehdrv.f

Go to the documentation of this file.

      SUBROUTINE psgehdrv( N, ILO, IHI, A, IA, JA, DESCA, TAU, WORK )
*
*  -- ScaLAPACK routine (version 1.7) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     May 28, 2001
*
*     .. Scalar Arguments ..
      INTEGER              IA, IHI, ILO, JA, N
*     ..
*     .. Array Arguments ..
      INTEGER              DESCA( * )
      REAL                 A( * ), TAU( * ), WORK( * )
*     ..
*
*  Purpose
*  =======
*
*  PSGEHDRV computes sub( A ) = A(IA:IA+N-1,JA:JA+N-1) from the
*  orthogonal matrix Q, the Hessenberg matrix, and the array TAU
*  returned by PSGEHRD:
*                       sub( A ) := Q * H * Q'
*
*  Arguments
*  =========
*
*  N       (global input) INTEGER
*          The number of rows and columns to be operated on, i.e. the
*          order of the distributed submatrix sub( A ). N >= 0.
*
*  ILO     (global input) INTEGER
*  IHI     (global input) INTEGER
*          It is assumed that sub( A ) is already upper triangular in
*          rows and columns 1:ILO-1 and IHI+1:N. If N > 0,
*          1 <= ILO <= IHI <= N; otherwise set ILO = 1, IHI = N.
*
*  A       (local input/local output) REAL pointer into the
*          local memory to an array of dimension (LLD_A,LOCc(JA+N-1)).
*          On entry, this array contains the local pieces of the N-by-N
*          general distributed matrix sub( A ) reduced to Hessenberg
*          form by PSGEHRD. The upper triangle and the first sub-
*          diagonal of sub( A ) contain the upper Hessenberg matrix H,
*          and the elements below the first subdiagonal, with the array
*          TAU, represent the orthogonal matrix Q as a product of
*          elementary reflectors. On exit, the original distributed
*          N-by-N matrix sub( A ) is recovered.
*
*  IA      (global input) INTEGER
*          The row index in the global array A indicating the first
*          row of sub( A ).
*
*  JA      (global input) INTEGER
*          The column index in the global array A indicating the
*          first column of sub( A ).
*
*  DESCA   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix A.
*
*  TAU     (local input) REAL array, dimension LOCc(JA+N-2)
*          The scalar factors of the elementary reflectors returned by
*          PSGEHRD. TAU is tied to the distributed matrix A.
*
*  WORK    (local workspace) REAL array, dimension (LWORK).
*          LWORK >= NB*NB + NB*IHLP + MAX[ NB*( IHLP+INLQ ),
*                   NB*( IHLQ + MAX[ IHIP,
*                   IHLP+NUMROC( NUMROC( IHI-ILO+LOFF+1, NB, 0, 0,
*                   NPCOL ), NB, 0, 0, LCMQ ) ] ) ]
*
*          where NB = MB_A = NB_A,
*          LCM is the least common multiple of NPROW and NPCOL,
*          LCM = ILCM( NPROW, NPCOL ), LCMQ = LCM / NPCOL,
*
*          IROFFA = MOD( IA-1, NB ),
*          IAROW = INDXG2P( IA, NB, MYROW, RSRC_A, NPROW ),
*          IHIP = NUMROC( IHI+IROFFA, NB, MYROW, IAROW, NPROW ),
*
*          ILROW = INDXG2P( IA+ILO-1, NB, MYROW, RSRC_A, NPROW ),
*          ILCOL = INDXG2P( JA+ILO-1, NB, MYCOL, CSRC_A, NPCOL ),
*          IHLP = NUMROC( IHI-ILO+IROFFA+1, NB, MYROW, ILROW, NPROW ),
*          IHLQ = NUMROC( IHI-ILO+IROFFA+1, NB, MYCOL, ILCOL, NPCOL ),
*          INLQ = NUMROC( N-ILO+IROFFA+1, NB, MYCOL, ILCOL, NPCOL ).
*
*          ILCM, INDXG2P and NUMROC are ScaLAPACK tool functions;
*          MYROW, MYCOL, NPROW and NPCOL can be determined by calling
*          the subroutine BLACS_GRIDINFO.
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            BLOCK_CYCLIC_2D, CSRC_, CTXT_, DLEN_, DTYPE_,
     $                   LLD_, MB_, M_, NB_, N_, RSRC_
      parameter( block_cyclic_2d = 1, dlen_ = 9, dtype_ = 1,
     $                     ctxt_ = 2, m_ = 3, n_ = 4, mb_ = 5, nb_ = 6,
     $                     rsrc_ = 7, csrc_ = 8, lld_ = 9 )
      REAL                 ZERO
      parameter( zero = 0.0e+0 )
*     ..
*     .. Local Scalars ..
      INTEGER              I, IACOL, IAROW, ICTXT, IHLP, II, IOFF, IPT,
     $                     IPV, IPW, IV, J, JB, JJ, JL, K, MYCOL, MYROW,
     $                     NB, NPCOL, NPROW
*     ..
*     .. Local Arrays ..
      INTEGER              DESCV( DLEN_ )
*     ..
*     .. External Functions ..
      INTEGER              INDXG2P, NUMROC
      EXTERNAL             indxg2p, numroc
*     ..
*     .. External Subroutines ..
      EXTERNAL             blacs_gridinfo, descset, infog2l, pslarfb,
     $                     pslarft, pslacpy, pslaset
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC            max, min, mod
*     ..
*     .. Executable statements ..
*
*     Get grid parameters
*
      ictxt = desca( ctxt_ )
      CALL blacs_gridinfo( ictxt, nprow, npcol, myrow, mycol )
*
*     Quick return if possible
*
      IF( ihi-ilo.LE.0 )
     $   RETURN
*
      nb = desca( mb_ )
      ioff = mod( ia+ilo-2, nb )
      CALL infog2l( ia+ilo-1, ja+ilo-1, desca, nprow, npcol, myrow,
     $              mycol, ii, jj, iarow, iacol )
      ihlp = numroc( ihi-ilo+ioff+1, nb, myrow, iarow, nprow )
*
      ipt = 1
      ipv = ipt + nb * nb
      ipw = ipv + ihlp * nb
      jl = max( ( ( ja+ihi-2 ) / nb ) * nb + 1, ja + ilo - 1 )
      CALL descset( descv, ihi-ilo+ioff+1, nb, nb, nb, iarow,
     $              indxg2p( jl, desca( nb_ ), mycol, desca( csrc_ ),
     $              npcol ), ictxt, max( 1, ihlp ) )
*
      DO 10 j = jl, ilo+ja+nb-ioff-1, -nb
         jb = min( ja+ihi-j-1, nb )
         i  = ia + j - ja
         k  = i - ia + 1
         iv = k - ilo + ioff + 1
*
*        Compute upper triangular matrix T from TAU.
*
         CALL pslarft( 'Forward', 'Columnwise', ihi-k, jb, a, i+1, j,
     $                 desca, tau, work( ipt ), work( ipw ) )
*
*        Copy Householder vectors into workspace.
*
         CALL pslacpy( 'All', ihi-k, jb, a, i+1, j, desca, work( ipv ),
     $                 iv+1, 1, descv )
*
*        Zero out the strict lower triangular part of A.
*
         CALL pslaset( 'Lower', ihi-k-1, jb, zero, zero, a, i+2, j,
     $                 desca )
*
*        Apply block Householder transformation from Left.
*
         CALL pslarfb( 'Left', 'No transpose', 'Forward', 'Columnwise',
     $                 ihi-k, n-k+1, jb, work( ipv ), iv+1, 1, descv,
     $                 work( ipt ), a, i+1, j, desca, work( ipw ) )
*
*        Apply block Householder transformation from Right.
*
         CALL pslarfb( 'Right', 'Transpose', 'Forward', 'Columnwise',
     $                 ihi, ihi-k, jb, work( ipv ), iv+1, 1, descv,
     $                 work( ipt ), a, ia, j+1, desca, work( ipw ) )
*
         descv( csrc_ ) = mod( descv( csrc_ ) + npcol - 1, npcol )
*
   10 CONTINUE
*
*     Handle the first block separately
*
      iv = ioff + 1
      i = ia + ilo - 1
      j = ja + ilo - 1
      jb = min( nb-ioff, ja+ihi-j-1 )
*
*     Compute upper triangular matrix T from TAU.
*
      CALL pslarft( 'Forward', 'Columnwise', ihi-ilo, jb, a, i+1, j,
     $              desca, tau, work( ipt ), work( ipw ) )
*
*     Copy Householder vectors into workspace.
*
      CALL pslacpy( 'All', ihi-ilo, jb, a, i+1, j, desca, work( ipv ),
     $              iv+1, 1, descv )
*
*     Zero out the strict lower triangular part of A.
*
      IF( ihi-ilo.GT.0 )
     $   CALL pslaset( 'Lower', ihi-ilo-1, jb, zero, zero, a, i+2, j,
     $                 desca )
*
*     Apply block Householder transformation from Left.
*
      CALL pslarfb( 'Left', 'No transpose', 'Forward', 'Columnwise',
     $              ihi-ilo, n-ilo+1, jb, work( ipv ), iv+1, 1, descv,
     $              work( ipt ), a, i+1, j, desca, work( ipw ) )
*
*     Apply block Householder transformation from Right.
*
      CALL pslarfb( 'Right', 'Transpose', 'Forward', 'Columnwise', ihi,
     $              ihi-ilo, jb, work( ipv ), iv+1, 1, descv,
     $              work( ipt ), a, ia, j+1, desca, work( ipw ) )
*
      RETURN
*
*     End of PSGEHDRV
*
      END