pcerraxpby()

subroutine pcerraxpby	(	real	errbnd,
		complex	alpha,
		complex	x,
		complex	beta,
		complex	y,
		real	prec
	)

Definition at line 6942 of file pcblastst.f.

*
*  -- PBLAS test routine (version 2.0) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     April 1, 1998
*
*     .. Scalar Arguments ..
      REAL               ERRBND, PREC
      COMPLEX            ALPHA, BETA, X, Y
*     ..
*
*  Purpose
*  =======
*
*  PCERRAXPBY  serially  computes  y := beta*y + alpha * x and returns a
*  scaled relative acceptable error bound on the result.
*
*  Arguments
*  =========
*
*  ERRBND  (global output) REAL
*          On exit, ERRBND  specifies the scaled relative acceptable er-
*          ror bound.
*
*  ALPHA   (global input) COMPLEX
*          On entry, ALPHA specifies the scalar alpha.
*
*  X       (global input) COMPLEX
*          On entry, X  specifies the scalar x to be scaled.
*
*  BETA    (global input) COMPLEX
*          On entry, BETA specifies the scalar beta.
*
*  Y       (global input/global output) COMPLEX
*          On entry,  Y  specifies  the scalar y to be added. On exit, Y
*          contains the resulting scalar y.
*
*  PREC    (global input) REAL
*          On entry, PREC specifies the machine precision.
*
*  -- Written on April 1, 1998 by
*     Antoine Petitet, University  of  Tennessee, Knoxville 37996, USA.
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ONE, TWO, ZERO
      parameter( one = 1.0e+0, two = 2.0e+0,
     $                   zero = 0.0e+0 )
*     ..
*     .. Local Scalars ..
      REAL               ADDBND, FACT, SUMINEG, SUMIPOS, SUMRNEG,
     $                   SUMRPOS
      COMPLEX            TMP
*     ..
*     .. Intrinsic Functions ..
*     ..
*     .. Executable Statements ..
*
      sumipos = zero
      sumineg = zero
      sumrpos = zero
      sumrneg = zero
      fact = one + two * prec
      addbnd = two * two * two * prec
*
      tmp = alpha * x
      IF( real( tmp ).GE.zero ) THEN
         sumrpos = sumrpos + real( tmp ) * fact
      ELSE
         sumrneg = sumrneg - real( tmp ) * fact
      END IF
      IF( aimag( tmp ).GE.zero ) THEN
         sumipos = sumipos + aimag( tmp ) * fact
      ELSE
         sumineg = sumineg - aimag( tmp ) * fact
      END IF
*
      tmp = beta * y
      IF( real( tmp ).GE.zero ) THEN
         sumrpos = sumrpos + real( tmp ) * fact
      ELSE
         sumrneg = sumrneg - real( tmp ) * fact
      END IF
      IF( aimag( tmp ).GE.zero ) THEN
         sumipos = sumipos + aimag( tmp ) * fact
      ELSE
         sumineg = sumineg - aimag( tmp ) * fact
      END IF
*
      y = ( beta * y ) + ( alpha * x )
*
      errbnd = addbnd * max( max( sumrpos, sumrneg ),
     $                       max( sumipos, sumineg ) )
*
      RETURN
*
*     End of PCERRAXPBY
*

Here is the caller graph for this function: