csyr2.f

Go to the documentation of this file.

      SUBROUTINE csyr2( UPLO, N, ALPHA, X, INCX, Y, INCY, A, LDA )
*
*  -- PBLAS auxiliary routine (version 2.0) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     April 1, 1998
*
*     .. Scalar Arguments ..
      CHARACTER*1        UPLO
      INTEGER            INCX, INCY, LDA, N
      COMPLEX            ALPHA
*     ..
*     .. Array Arguments ..
      COMPLEX            A( LDA, * ), X( * ), Y( * )
*     ..
*
*  Purpose
*  =======
*
*  CSYR2  performs the symmetric rank 2 operation
*
*     A := alpha*x*y' + alpha*y*x' + A,
*
*  where alpha is a complex scalar, x and y are n element vectors and  A
*  is an n by n SY matrix.
*
*  Arguments
*  =========
*
*  UPLO    (input) CHARACTER*1
*          On entry, UPLO  specifies which part of the matrix A is to be
*          referenced as follows:
*
*             UPLO = 'L' or 'l' the lower trapezoid of A is referenced,
*
*             UPLO = 'U' or 'u' the upper trapezoid of A is referenced,
*
*             otherwise         all of the matrix A is referenced.
*
*  N       (input) INTEGER
*          On entry, N specifies the order of the matrix A. N must be at
*          least zero.
*
*  ALPHA   (input) COMPLEX
*          On entry, ALPHA specifies the scalar alpha.
*
*  X       (input) COMPLEX array of dimension at least
*          ( 1 + ( n - 1 )*abs( INCX ) ).  Before entry, the incremented
*          array X must contain the vector x.
*
*  INCX    (input) INTEGER
*          On entry, INCX specifies the increment for the elements of X.
*          INCX must not be zero.
*
*  Y       (input) COMPLEX array of dimension at least
*          ( 1 + ( n - 1 )*abs( INCY ) ).  Before entry, the incremented
*          array Y must contain the vector y.
*
*  INCY    (input) INTEGER
*          On entry, INCY specifies the increment for the elements of Y.
*          INCY must not be zero.
*
*  A       (input/output) COMPLEX array
*          On entry,  A  is an array of dimension (LDA,N).  Before entry
*          with UPLO = 'U' or 'u', the leading n by n part of the  array
*          A must contain the upper triangular part of the symmetric ma-
*          trix and the strictly lower triangular part of A is not refe-
*          renced. On exit, the upper triangular part of the array A  is
*          overwritten  by  the upper triangular part of the updated ma-
*          trix. When UPLO = 'L' or 'l', the leading n by n part of  the
*          the array  A  must  contain  the lower triangular part of the
*          symmetric matrix and the strictly upper trapezoidal part of A
*          is not referenced.  On exit, the lower triangular part of the
*          array  A  is  overwritten by the lower triangular part of the
*          updated matrix.
*
*  LDA     (input) INTEGER
*          On entry, LDA specifies the leading dimension of the array A.
*          LDA must be at least max( 1, N ).
*
*  -- Written on April 1, 1998 by
*     Antoine Petitet, University  of  Tennessee, Knoxville 37996, USA.
*
*  =====================================================================
*
*     .. Parameters ..
      COMPLEX            ZERO
      parameter( zero = ( 0.0e+0, 0.0e+0 ) )
*     ..
*     .. Local Scalars ..
      INTEGER            I, INFO, IX, IY, J, JX, JY, KX, KY
      COMPLEX            TEMP1, TEMP2
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      EXTERNAL           lsame
*     ..
*     .. External Subroutines ..
      EXTERNAL           xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
      IF     ( .NOT.lsame( uplo, 'U' ).AND.
     $         .NOT.lsame( uplo, 'L' )      )THEN
         info = 1
      ELSE IF( n.LT.0 )THEN
         info = 2
      ELSE IF( incx.EQ.0 )THEN
         info = 5
      ELSE IF( incy.EQ.0 )THEN
         info = 7
      ELSE IF( lda.LT.max( 1, n ) )THEN
         info = 9
      END IF
      IF( info.NE.0 )THEN
         CALL xerbla( 'CSYR2', info )
         RETURN
      END IF
*
*     Quick return if possible.
*
      IF( ( n.EQ.0 ).OR.( alpha.EQ.zero ) )
     $   RETURN
*
*     Set up the start points in X and Y if the increments are not both
*     unity.
*
    kx = 1
    ky = 1
    jx = 1
    jy = 1
      IF( ( incx.NE.1 ).OR.( incy.NE.1 ) )THEN
         IF( incx.GT.0 )THEN
            kx = 1
         ELSE
            kx = 1 - ( n - 1 )*incx
         END IF
         IF( incy.GT.0 )THEN
            ky = 1
         ELSE
            ky = 1 - ( n - 1 )*incy
         END IF
         jx = kx
         jy = ky
      END IF
*
*     Start the operations. In this version the elements of A are
*     accessed sequentially with one pass through the triangular part
*     of A.
*
      IF( lsame( uplo, 'U' ) )THEN
*
*        Form  A  when A is stored in the upper triangle.
*
         IF( ( incx.EQ.1 ).AND.( incy.EQ.1 ) )THEN
            DO 20, j = 1, n
               IF( ( x( j ).NE.zero ).OR.( y( j ).NE.zero ) )THEN
                  temp1 = alpha*y( j )
                  temp2 = alpha*x( j )
                  DO 10, i = 1, j
                     a( i, j ) = a( i, j ) + x( i )*temp1 + y( i )*temp2
   10             CONTINUE
               END IF
   20       CONTINUE
         ELSE
            DO 40, j = 1, n
               IF( ( x( jx ).NE.zero ).OR.( y( jy ).NE.zero ) )THEN
                  temp1 = alpha*y( jy )
                  temp2 = alpha*x( jx )
                  ix    = kx
                  iy    = ky
                  DO 30, i = 1, j
                     a( i, j ) = a( i, j ) + x( ix )*temp1
     $                                     + y( iy )*temp2
                     ix        = ix        + incx
                     iy        = iy        + incy
   30             CONTINUE
               END IF
               jx = jx + incx
               jy = jy + incy
   40       CONTINUE
         END IF
      ELSE
*
*        Form  A  when A is stored in the lower triangle.
*
         IF( ( incx.EQ.1 ).AND.( incy.EQ.1 ) )THEN
            DO 60, j = 1, n
               IF( ( x( j ).NE.zero ).OR.( y( j ).NE.zero ) )THEN
                  temp1 = alpha*y( j )
                  temp2 = alpha*x( j )
                  DO 50, i = j, n
                     a( i, j ) = a( i, j ) + x( i )*temp1 + y( i )*temp2
   50             CONTINUE
               END IF
   60       CONTINUE
         ELSE
            DO 80, j = 1, n
               IF( ( x( jx ).NE.zero ).OR.( y( jy ).NE.zero ) )THEN
                  temp1 = alpha*y( jy )
                  temp2 = alpha*x( jx )
                  ix    = jx
                  iy    = jy
                  DO 70, i = j, n
                     a( i, j ) = a( i, j ) + x( ix )*temp1
     $                                     + y( iy )*temp2
                     ix        = ix        + incx
                     iy        = iy        + incy
   70             CONTINUE
               END IF
               jx = jx + incx
               jy = jy + incy
   80       CONTINUE
         END IF
      END IF
*
      RETURN
*
*     End of CSYR2
*
      END