pdlaprnt.f

Go to the documentation of this file.

      SUBROUTINE pdlaprnt( M, N, A, IA, JA, DESCA, IRPRNT, ICPRNT,
     $                     CMATNM, NOUT, WORK )
*
*  -- ScaLAPACK tools routine (version 1.7) --
*     University of Tennessee, Knoxville, Oak Ridge National Laboratory,
*     and University of California, Berkeley.
*     May 1, 1997
*
*     .. Scalar Arguments ..
      INTEGER            IA, ICPRNT, IRPRNT, JA, M, N, NOUT
*     ..
*     .. Array Arguments ..
      CHARACTER*(*)      CMATNM
      INTEGER            DESCA( * )
      DOUBLE PRECISION   A( * ), WORK( * )
*     ..
*
*  Purpose
*  =======
*
*  PDLAPRNT prints to the standard output a distributed matrix sub( A )
*  denoting A(IA:IA+M-1,JA:JA+N-1). The local pieces are sent and
*  printed by the process of coordinates (IRPRNT, ICPRNT).
*
*  Notes
*  =====
*
*  Each global data object is described by an associated description
*  vector.  This vector stores the information required to establish
*  the mapping between an object element and its corresponding process
*  and memory location.
*
*  Let A be a generic term for any 2D block cyclicly distributed array.
*  Such a global array has an associated description vector DESCA.
*  In the following comments, the character _ should be read as
*  "of the global array".
*
*  NOTATION        STORED IN      EXPLANATION
*  --------------- -------------- --------------------------------------
*  DTYPE_A(global) DESCA( DTYPE_ )The descriptor type.  In this case,
*                                 DTYPE_A = 1.
*  CTXT_A (global) DESCA( CTXT_ ) The BLACS context handle, indicating
*                                 the BLACS process grid A is distribu-
*                                 ted over. The context itself is glo-
*                                 bal, but the handle (the integer
*                                 value) may vary.
*  M_A    (global) DESCA( M_ )    The number of rows in the global
*                                 array A.
*  N_A    (global) DESCA( N_ )    The number of columns in the global
*                                 array A.
*  MB_A   (global) DESCA( MB_ )   The blocking factor used to distribute
*                                 the rows of the array.
*  NB_A   (global) DESCA( NB_ )   The blocking factor used to distribute
*                                 the columns of the array.
*  RSRC_A (global) DESCA( RSRC_ ) The process row over which the first
*                                 row of the array A is distributed.
*  CSRC_A (global) DESCA( CSRC_ ) The process column over which the
*                                 first column of the array A is
*                                 distributed.
*  LLD_A  (local)  DESCA( LLD_ )  The leading dimension of the local
*                                 array.  LLD_A >= MAX(1,LOCr(M_A)).
*
*  Let K be the number of rows or columns of a distributed matrix,
*  and assume that its process grid has dimension p x q.
*  LOCr( K ) denotes the number of elements of K that a process
*  would receive if K were distributed over the p processes of its
*  process column.
*  Similarly, LOCc( K ) denotes the number of elements of K that a
*  process would receive if K were distributed over the q processes of
*  its process row.
*  The values of LOCr() and LOCc() may be determined via a call to the
*  ScaLAPACK tool function, NUMROC:
*          LOCr( M ) = NUMROC( M, MB_A, MYROW, RSRC_A, NPROW ),
*          LOCc( N ) = NUMROC( N, NB_A, MYCOL, CSRC_A, NPCOL ).
*  An upper bound for these quantities may be computed by:
*          LOCr( M ) <= ceil( ceil(M/MB_A)/NPROW )*MB_A
*          LOCc( N ) <= ceil( ceil(N/NB_A)/NPCOL )*NB_A
*
*  Arguments
*  =========
*
*  M       (global input) INTEGER
*          The number of rows to be operated on i.e the number of rows
*          of the distributed submatrix sub( A ). M >= 0.
*
*  N       (global input) INTEGER
*          The number of columns to be operated on i.e the number of
*          columns of the distributed submatrix sub( A ). N >= 0.
*
*  A       (local input) DOUBLE PRECISION pointer into the local memory to a
*          local array of dimension (LLD_A, LOCc(JA+N-1) ) containing
*          the local pieces of the distributed matrix sub( A ).
*
*  IA      (global input) INTEGER
*          The row index in the global array A indicating the first
*          row of sub( A ).
*
*  JA      (global input) INTEGER
*          The column index in the global array A indicating the
*          first column of sub( A ).
*
*  DESCA   (global and local input) INTEGER array of dimension DLEN_.
*          The array descriptor for the distributed matrix A.
*
*  IRPRNT  (global input) INTEGER
*          The row index of the printing process.
*
*  ICPRNT  (global input) INTEGER
*          The column index of the printing process.
*
*  CMATNM  (global input) CHARACTER*(*)
*          Identifier of the distributed matrix to be printed.
*
*  NOUT    (global input) INTEGER
*          The unit number for output file. NOUT = 6, ouput to screen,
*          NOUT = 0, output to stderr.
*
*  WORK    (local workspace) DOUBLE PRECISION
*          Working array of minimum size equal to MB_A.
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            BLOCK_CYCLIC_2D, CSRC_, CTXT_, DLEN_, DTYPE_,
     $                   lld_, mb_, m_, nb_, n_, rsrc_
      parameter( block_cyclic_2d = 1, dlen_ = 9, dtype_ = 1,
     $                     ctxt_ = 2, m_ = 3, n_ = 4, mb_ = 5, nb_ = 6,
     $                     rsrc_ = 7, csrc_ = 8, lld_ = 9 )
*     ..
*     .. Local Scalars ..
      INTEGER            H, I, IACOL, IAROW, IB, ICTXT, ICURCOL,
     $                   icurrow, ii, iia, in, j, jb, jj, jja, jn, k,
     $                   lda, mycol, myrow, npcol, nprow
*     ..
*     .. External Subroutines ..
      EXTERNAL           blacs_barrier, blacs_gridinfo, infog2l,
     $                   dgerv2d, dgesd2d
*     ..
*     .. External Functions ..
      INTEGER            ICEIL
      EXTERNAL           iceil
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          min
*     ..
*     .. Executable Statements ..
*
*     Get grid parameters
*
      ictxt = desca( ctxt_ )
      CALL blacs_gridinfo( ictxt, nprow, npcol, myrow, mycol )
*
      CALL infog2l( ia, ja, desca, nprow, npcol, myrow, mycol,
     $              iia, jja, iarow, iacol )
      icurrow = iarow
      icurcol = iacol
      ii = iia
      jj = jja
      lda = desca( lld_ )
*
*     Handle the first block of column separately
*
      jn = min( iceil( ja, desca( nb_ ) ) * desca( nb_ ), ja+n-1 )
      jb = jn-ja+1
      DO 60 h = 0, jb-1
         in = min( iceil( ia, desca( mb_ ) ) * desca( mb_ ), ia+m-1 )
         ib = in-ia+1
         IF( icurrow.EQ.irprnt .AND. icurcol.EQ.icprnt ) THEN
            IF( myrow.EQ.irprnt .AND. mycol.EQ.icprnt ) THEN
               DO 10 k = 0, ib-1
                  WRITE( nout, fmt = 9999 )
     $                   cmatnm, ia+k, ja+h, a( ii+k+(jj+h-1)*lda )
   10          CONTINUE
            END IF
         ELSE
            IF( myrow.EQ.icurrow .AND. mycol.EQ.icurcol ) THEN
               CALL dgesd2d( ictxt, ib, 1, a( ii+(jj+h-1)*lda ), lda,
     $                       irprnt, icprnt )
            ELSE IF( myrow.EQ.irprnt .AND. mycol.EQ.icprnt ) THEN
               CALL dgerv2d( ictxt, ib, 1, work, desca( mb_ ),
     $                       icurrow, icurcol )
               DO 20 k = 1, ib
                  WRITE( nout, fmt = 9999 )
     $                   cmatnm, ia+k-1, ja+h, work( k )
   20          CONTINUE
            END IF
         END IF
         IF( myrow.EQ.icurrow )
     $      ii = ii + ib
         icurrow = mod( icurrow+1, nprow )
         CALL blacs_barrier( ictxt, 'All' )
*
*        Loop over remaining block of rows
*
         DO 50 i = in+1, ia+m-1, desca( mb_ )
            ib = min( desca( mb_ ), ia+m-i )
            IF( icurrow.EQ.irprnt .AND. icurcol.EQ.icprnt ) THEN
               IF( myrow.EQ.irprnt .AND. mycol.EQ.icprnt ) THEN
                  DO 30 k = 0, ib-1
                     WRITE( nout, fmt = 9999 )
     $                      cmatnm, i+k, ja+h, a( ii+k+(jj+h-1)*lda )
   30             CONTINUE
               END IF
            ELSE
               IF( myrow.EQ.icurrow .AND. mycol.EQ.icurcol ) THEN
                  CALL dgesd2d( ictxt, ib, 1, a( ii+(jj+h-1)*lda ),
     $                          lda, irprnt, icprnt )
               ELSE IF( myrow.EQ.irprnt .AND. mycol.EQ.icprnt ) THEN
                  CALL dgerv2d( ictxt, ib, 1, work, desca( mb_ ),
     $                          icurrow, icurcol )
                  DO 40 k = 1, ib
                     WRITE( nout, fmt = 9999 )
     $                      cmatnm, i+k-1, ja+h, work( k )
   40             CONTINUE
               END IF
            END IF
            IF( myrow.EQ.icurrow )
     $         ii = ii + ib
            icurrow = mod( icurrow+1, nprow )
            CALL blacs_barrier( ictxt, 'All' )
   50    CONTINUE
*
        ii = iia
        icurrow = iarow
   60 CONTINUE
*
      IF( mycol.EQ.icurcol )
     $   jj = jj + jb
      icurcol = mod( icurcol+1, npcol )
      CALL blacs_barrier( ictxt, 'All' )
*
*     Loop over remaining column blocks
*
      DO 130 j = jn+1, ja+n-1, desca( nb_ )
         jb = min(  desca( nb_ ), ja+n-j )
         DO 120 h = 0, jb-1
            in = min( iceil( ia, desca( mb_ ) ) * desca( mb_ ), ia+m-1 )
            ib = in-ia+1
            IF( icurrow.EQ.irprnt .AND. icurcol.EQ.icprnt ) THEN
               IF( myrow.EQ.irprnt .AND. mycol.EQ.icprnt ) THEN
                  DO 70 k = 0, ib-1
                     WRITE( nout, fmt = 9999 )
     $                      cmatnm, ia+k, j+h, a( ii+k+(jj+h-1)*lda )
   70             CONTINUE
               END IF
            ELSE
               IF( myrow.EQ.icurrow .AND. mycol.EQ.icurcol ) THEN
                  CALL dgesd2d( ictxt, ib, 1, a( ii+(jj+h-1)*lda ),
     $                          lda, irprnt, icprnt )
               ELSE IF( myrow.EQ.irprnt .AND. mycol.EQ.icprnt ) THEN
                  CALL dgerv2d( ictxt, ib, 1, work, desca( mb_ ),
     $                          icurrow, icurcol )
                  DO 80 k = 1, ib
                     WRITE( nout, fmt = 9999 )
     $                      cmatnm, ia+k-1, j+h, work( k )
   80             CONTINUE
               END IF
            END IF
            IF( myrow.EQ.icurrow )
     $         ii = ii + ib
            icurrow = mod( icurrow+1, nprow )
            CALL blacs_barrier( ictxt, 'All' )
*
*           Loop over remaining block of rows
*
            DO 110 i = in+1, ia+m-1, desca( mb_ )
               ib = min( desca( mb_ ), ia+m-i )
               IF( icurrow.EQ.irprnt .AND. icurcol.EQ.icprnt ) THEN
                  IF( myrow.EQ.irprnt .AND. mycol.EQ.icprnt ) THEN
                     DO 90 k = 0, ib-1
                        WRITE( nout, fmt = 9999 )
     $                         cmatnm, i+k, j+h, a( ii+k+(jj+h-1)*lda )
   90                CONTINUE
                  END IF
               ELSE
                  IF( myrow.EQ.icurrow .AND. mycol.EQ.icurcol ) THEN
                     CALL dgesd2d( ictxt, ib, 1, a( ii+(jj+h-1)*lda ),
     $                             lda, irprnt, icprnt )
                   ELSE IF( myrow.EQ.irprnt .AND. mycol.EQ.icprnt ) THEN
                     CALL dgerv2d( ictxt, ib, 1, work, desca( mb_ ),
     $                             icurrow, icurcol )
                     DO 100 k = 1, ib
                        WRITE( nout, fmt = 9999 )
     $                         cmatnm, i+k-1, j+h, work( k )
  100                CONTINUE
                  END IF
               END IF
               IF( myrow.EQ.icurrow )
     $            ii = ii + ib
               icurrow = mod( icurrow+1, nprow )
               CALL blacs_barrier( ictxt, 'All' )
  110       CONTINUE
*
            ii = iia
            icurrow = iarow
  120    CONTINUE
*
         IF( mycol.EQ.icurcol )
     $      jj = jj + jb
         icurcol = mod( icurcol+1, npcol )
         CALL blacs_barrier( ictxt, 'All' )
*
  130 CONTINUE
*
 9999 FORMAT(a,'(',i6,',',i6,')=',d30.18)
*
      RETURN
*
*     End of PDLAPRNT
*
      END