dqrt15.f

Go to the documentation of this file.

*> \brief \b DQRT15
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*  Definition:
*  ===========
*
*       SUBROUTINE DQRT15( SCALE, RKSEL, M, N, NRHS, A, LDA, B, LDB, S,
*                          RANK, NORMA, NORMB, ISEED, WORK, LWORK )
*
*       .. Scalar Arguments ..
*       INTEGER            LDA, LDB, LWORK, M, N, NRHS, RANK, RKSEL, SCALE
*       DOUBLE PRECISION   NORMA, NORMB
*       ..
*       .. Array Arguments ..
*       INTEGER            ISEED( 4 )
*       DOUBLE PRECISION   A( LDA, * ), B( LDB, * ), S( * ), WORK( LWORK )
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> DQRT15 generates a matrix with full or deficient rank and of various
*> norms.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] SCALE
*> \verbatim
*>          SCALE is INTEGER
*>          SCALE = 1: normally scaled matrix
*>          SCALE = 2: matrix scaled up
*>          SCALE = 3: matrix scaled down
*> \endverbatim
*>
*> \param[in] RKSEL
*> \verbatim
*>          RKSEL is INTEGER
*>          RKSEL = 1: full rank matrix
*>          RKSEL = 2: rank-deficient matrix
*> \endverbatim
*>
*> \param[in] M
*> \verbatim
*>          M is INTEGER
*>          The number of rows of the matrix A.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The number of columns of A.
*> \endverbatim
*>
*> \param[in] NRHS
*> \verbatim
*>          NRHS is INTEGER
*>          The number of columns of B.
*> \endverbatim
*>
*> \param[out] A
*> \verbatim
*>          A is DOUBLE PRECISION array, dimension (LDA,N)
*>          The M-by-N matrix A.
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>          The leading dimension of the array A.
*> \endverbatim
*>
*> \param[out] B
*> \verbatim
*>          B is DOUBLE PRECISION array, dimension (LDB, NRHS)
*>          A matrix that is in the range space of matrix A.
*> \endverbatim
*>
*> \param[in] LDB
*> \verbatim
*>          LDB is INTEGER
*>          The leading dimension of the array B.
*> \endverbatim
*>
*> \param[out] S
*> \verbatim
*>          S is DOUBLE PRECISION array, dimension MIN(M,N)
*>          Singular values of A.
*> \endverbatim
*>
*> \param[out] RANK
*> \verbatim
*>          RANK is INTEGER
*>          number of nonzero singular values of A.
*> \endverbatim
*>
*> \param[out] NORMA
*> \verbatim
*>          NORMA is DOUBLE PRECISION
*>          one-norm of A.
*> \endverbatim
*>
*> \param[out] NORMB
*> \verbatim
*>          NORMB is DOUBLE PRECISION
*>          one-norm of B.
*> \endverbatim
*>
*> \param[in,out] ISEED
*> \verbatim
*>          ISEED is integer array, dimension (4)
*>          seed for random number generator.
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is DOUBLE PRECISION array, dimension (LWORK)
*> \endverbatim
*>
*> \param[in] LWORK
*> \verbatim
*>          LWORK is INTEGER
*>          length of work space required.
*>          LWORK >= MAX(M+MIN(M,N),NRHS*MIN(M,N),2*N+M)
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \ingroup double_lin
*
*  =====================================================================
      SUBROUTINE dqrt15( SCALE, RKSEL, M, N, NRHS, A, LDA, B, LDB, S,
     $                   RANK, NORMA, NORMB, ISEED, WORK, LWORK )
*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            LDA, LDB, LWORK, M, N, NRHS, RANK, RKSEL, SCALE
      DOUBLE PRECISION   NORMA, NORMB
*     ..
*     .. Array Arguments ..
      INTEGER            ISEED( 4 )
      DOUBLE PRECISION   A( LDA, * ), B( LDB, * ), S( * ), WORK( LWORK )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO, ONE, TWO, SVMIN
      parameter( zero = 0.0d0, one = 1.0d0, two = 2.0d0,
     $                   svmin = 0.1d0 )
*     ..
*     .. Local Scalars ..
      INTEGER            INFO, J, MN
      DOUBLE PRECISION   BIGNUM, EPS, SMLNUM, TEMP
*     ..
*     .. Local Arrays ..
      DOUBLE PRECISION   DUMMY( 1 )
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   DASUM, DLAMCH, DLANGE, DLARND, DNRM2
      EXTERNAL           dasum, dlamch, dlange, dlarnd, dnrm2
*     ..
*     .. External Subroutines ..
      EXTERNAL           dgemm, dlaord, dlarf, dlarnv, dlaror, dlascl,
     $                   dlaset, dscal, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, max, min
*     ..
*     .. Executable Statements ..
*
      mn = min( m, n )
      IF( lwork.LT.max( m+mn, mn*nrhs, 2*n+m ) ) THEN
         CALL xerbla( 'DQRT15', 16 )
         RETURN
      END IF
*
      smlnum = dlamch( 'Safe minimum' )
      bignum = one / smlnum
      eps = dlamch( 'Epsilon' )
      smlnum = ( smlnum / eps ) / eps
      bignum = one / smlnum
*
*     Determine rank and (unscaled) singular values
*
      IF( rksel.EQ.1 ) THEN
         rank = mn
      ELSE IF( rksel.EQ.2 ) THEN
         rank = ( 3*mn ) / 4
         DO 10 j = rank + 1, mn
            s( j ) = zero
   10    CONTINUE
      ELSE
         CALL xerbla( 'DQRT15', 2 )
      END IF
*
      IF( rank.GT.0 ) THEN
*
*        Nontrivial case
*
         s( 1 ) = one
         DO 30 j = 2, rank
   20       CONTINUE
            temp = dlarnd( 1, iseed )
            IF( temp.GT.svmin ) THEN
               s( j ) = abs( temp )
            ELSE
               GO TO 20
            END IF
   30    CONTINUE
         CALL dlaord( 'Decreasing', rank, s, 1 )
*
*        Generate 'rank' columns of a random orthogonal matrix in A
*
         CALL dlarnv( 2, iseed, m, work )
         CALL dscal( m, one / dnrm2( m, work, 1 ), work, 1 )
         CALL dlaset( 'Full', m, rank, zero, one, a, lda )
         CALL dlarf( 'Left', m, rank, work, 1, two, a, lda,
     $               work( m+1 ) )
*
*        workspace used: m+mn
*
*        Generate consistent rhs in the range space of A
*
         CALL dlarnv( 2, iseed, rank*nrhs, work )
         CALL dgemm( 'No transpose', 'No transpose', m, nrhs, rank, one,
     $               a, lda, work, rank, zero, b, ldb )
*
*        work space used: <= mn *nrhs
*
*        generate (unscaled) matrix A
*
         DO 40 j = 1, rank
            CALL dscal( m, s( j ), a( 1, j ), 1 )
   40    CONTINUE
         IF( rank.LT.n )
     $      CALL dlaset( 'Full', m, n-rank, zero, zero, a( 1, rank+1 ),
     $                   lda )
         CALL dlaror( 'Right', 'No initialization', m, n, a, lda, iseed,
     $                work, info )
*
      ELSE
*
*        work space used 2*n+m
*
*        Generate null matrix and rhs
*
         DO 50 j = 1, mn
            s( j ) = zero
   50    CONTINUE
         CALL dlaset( 'Full', m, n, zero, zero, a, lda )
         CALL dlaset( 'Full', m, nrhs, zero, zero, b, ldb )
*
      END IF
*
*     Scale the matrix
*
      IF( scale.NE.1 ) THEN
         norma = dlange( 'Max', m, n, a, lda, dummy )
         IF( norma.NE.zero ) THEN
            IF( scale.EQ.2 ) THEN
*
*              matrix scaled up
*
               CALL dlascl( 'General', 0, 0, norma, bignum, m, n, a,
     $                      lda, info )
               CALL dlascl( 'General', 0, 0, norma, bignum, mn, 1, s,
     $                      mn, info )
               CALL dlascl( 'General', 0, 0, norma, bignum, m, nrhs, b,
     $                      ldb, info )
            ELSE IF( scale.EQ.3 ) THEN
*
*              matrix scaled down
*
               CALL dlascl( 'General', 0, 0, norma, smlnum, m, n, a,
     $                      lda, info )
               CALL dlascl( 'General', 0, 0, norma, smlnum, mn, 1, s,
     $                      mn, info )
               CALL dlascl( 'General', 0, 0, norma, smlnum, m, nrhs, b,
     $                      ldb, info )
            ELSE
               CALL xerbla( 'DQRT15', 1 )
               RETURN
            END IF
         END IF
      END IF
*
      norma = dasum( mn, s, 1 )
      normb = dlange( 'One-norm', m, nrhs, b, ldb, dummy )
*
      RETURN
*
*     End of DQRT15
*
      END