dlaed1()

subroutine dlaed1	(	integer	n,
		double precision, dimension( * )	d,
		double precision, dimension( ldq, * )	q,
		integer	ldq,
		integer, dimension( * )	indxq,
		double precision	rho,
		integer	cutpnt,
		double precision, dimension( * )	work,
		integer, dimension( * )	iwork,
		integer	info )

DLAED1 used by DSTEDC. Computes the updated eigensystem of a diagonal matrix after modification by a rank-one symmetric matrix. Used when the original matrix is tridiagonal.

Download DLAED1 + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> DLAED1 computes the updated eigensystem of a diagonal
!> matrix after modification by a rank-one symmetric matrix.  This
!> routine is used only for the eigenproblem which requires all
!> eigenvalues and eigenvectors of a tridiagonal matrix.  DLAED7 handles
!> the case in which eigenvalues only or eigenvalues and eigenvectors
!> of a full symmetric matrix (which was reduced to tridiagonal form)
!> are desired.
!>
!>   T = Q(in) ( D(in) + RHO * Z*Z**T ) Q**T(in) = Q(out) * D(out) * Q**T(out)
!>
!>    where Z = Q**T*u, u is a vector of length N with ones in the
!>    CUTPNT and CUTPNT + 1 th elements and zeros elsewhere.
!>
!>    The eigenvectors of the original matrix are stored in Q, and the
!>    eigenvalues are in D.  The algorithm consists of three stages:
!>
!>       The first stage consists of deflating the size of the problem
!>       when there are multiple eigenvalues or if there is a zero in
!>       the Z vector.  For each such occurrence the dimension of the
!>       secular equation problem is reduced by one.  This stage is
!>       performed by the routine DLAED2.
!>
!>       The second stage consists of calculating the updated
!>       eigenvalues. This is done by finding the roots of the secular
!>       equation via the routine DLAED4 (as called by DLAED3).
!>       This routine also calculates the eigenvectors of the current
!>       problem.
!>
!>       The final stage consists of computing the updated eigenvectors
!>       directly using the updated eigenvalues.  The eigenvectors for
!>       the current problem are multiplied with the eigenvectors from
!>       the overall problem.
!> 

Parameters

[in]	N	!> N is INTEGER !> The dimension of the symmetric tridiagonal matrix. N >= 0. !>
[in,out]	D	!> D is DOUBLE PRECISION array, dimension (N) !> On entry, the eigenvalues of the rank-1-perturbed matrix. !> On exit, the eigenvalues of the repaired matrix. !>
[in,out]	Q	!> Q is DOUBLE PRECISION array, dimension (LDQ,N) !> On entry, the eigenvectors of the rank-1-perturbed matrix. !> On exit, the eigenvectors of the repaired tridiagonal matrix. !>
[in]	LDQ	!> LDQ is INTEGER !> The leading dimension of the array Q. LDQ >= max(1,N). !>
[in,out]	INDXQ	!> INDXQ is INTEGER array, dimension (N) !> On entry, the permutation which separately sorts the two !> subproblems in D into ascending order. !> On exit, the permutation which will reintegrate the !> subproblems back into sorted order, !> i.e. D( INDXQ( I = 1, N ) ) will be in ascending order. !>
[in]	RHO	!> RHO is DOUBLE PRECISION !> The subdiagonal entry used to create the rank-1 modification. !>
[in]	CUTPNT	!> CUTPNT is INTEGER !> The location of the last eigenvalue in the leading sub-matrix. !> min(1,N) <= CUTPNT <= N/2. !>
[out]	WORK	!> WORK is DOUBLE PRECISION array, dimension (4*N + N**2) !>
[out]	IWORK	!> IWORK is INTEGER array, dimension (4*N) !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit. !> < 0: if INFO = -i, the i-th argument had an illegal value. !> > 0: if INFO = 1, an eigenvalue did not converge !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Contributors:

Jeff Rutter, Computer Science Division, University of California at Berkeley, USA
Modified by Francoise Tisseur, University of Tennessee

Definition at line 159 of file dlaed1.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            CUTPNT, INFO, LDQ, N
      DOUBLE PRECISION   RHO
*     ..
*     .. Array Arguments ..
      INTEGER            INDXQ( * ), IWORK( * )
      DOUBLE PRECISION   D( * ), Q( LDQ, * ), WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Local Scalars ..
      INTEGER            COLTYP, I, IDLMDA, INDX, INDXC, INDXP, IQ2, IS,
     $                   IW, IZ, K, N1, N2, ZPP1
*     ..
*     .. External Subroutines ..
      EXTERNAL           dcopy, dlaed2, dlaed3, dlamrg,
     $                   xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
*
      IF( n.LT.0 ) THEN
         info = -1
      ELSE IF( ldq.LT.max( 1, n ) ) THEN
         info = -4
      ELSE IF( min( 1, n / 2 ).GT.cutpnt .OR. ( n / 2 ).LT.cutpnt ) THEN
         info = -7
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'DLAED1', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 )
     $   RETURN
*
*     The following values are integer pointers which indicate
*     the portion of the workspace
*     used by a particular array in DLAED2 and DLAED3.
*
      iz = 1
      idlmda = iz + n
      iw = idlmda + n
      iq2 = iw + n
*
      indx = 1
      indxc = indx + n
      coltyp = indxc + n
      indxp = coltyp + n
*
*
*     Form the z-vector which consists of the last row of Q_1 and the
*     first row of Q_2.
*
      CALL dcopy( cutpnt, q( cutpnt, 1 ), ldq, work( iz ), 1 )
      zpp1 = cutpnt + 1
      CALL dcopy( n-cutpnt, q( zpp1, zpp1 ), ldq, work( iz+cutpnt ),
     $            1 )
*
*     Deflate eigenvalues.
*
      CALL dlaed2( k, n, cutpnt, d, q, ldq, indxq, rho, work( iz ),
     $             work( idlmda ), work( iw ), work( iq2 ),
     $             iwork( indx ), iwork( indxc ), iwork( indxp ),
     $             iwork( coltyp ), info )
*
      IF( info.NE.0 )
     $   GO TO 20
*
*     Solve Secular Equation.
*
      IF( k.NE.0 ) THEN
         is = ( iwork( coltyp )+iwork( coltyp+1 ) )*cutpnt +
     $        ( iwork( coltyp+1 )+iwork( coltyp+2 ) )*( n-cutpnt ) + iq2
         CALL dlaed3( k, n, cutpnt, d, q, ldq, rho, work( idlmda ),
     $                work( iq2 ), iwork( indxc ), iwork( coltyp ),
     $                work( iw ), work( is ), info )
         IF( info.NE.0 )
     $      GO TO 20
*
*     Prepare the INDXQ sorting permutation.
*
         n1 = k
         n2 = n - k
         CALL dlamrg( n1, n2, d, 1, -1, indxq )
      ELSE
         DO 10 i = 1, n
            indxq( i ) = i
   10    CONTINUE
      END IF
*
   20 CONTINUE
      RETURN
*
*     End of DLAED1
*

Here is the call graph for this function:

Here is the caller graph for this function: