dlaed2.f

Go to the documentation of this file.

*> \brief \b DLAED2 used by DSTEDC. Merges eigenvalues and deflates secular equation. Used when the original matrix is tridiagonal.
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*> \htmlonly
*> Download DLAED2 + dependencies
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/dlaed2.f">
*> [TGZ]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/dlaed2.f">
*> [ZIP]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/dlaed2.f">
*> [TXT]</a>
*> \endhtmlonly
*
*  Definition:
*  ===========
*
*       SUBROUTINE DLAED2( K, N, N1, D, Q, LDQ, INDXQ, RHO, Z, DLAMBDA, W,
*                          Q2, INDX, INDXC, INDXP, COLTYP, INFO )
*
*       .. Scalar Arguments ..
*       INTEGER            INFO, K, LDQ, N, N1
*       DOUBLE PRECISION   RHO
*       ..
*       .. Array Arguments ..
*       INTEGER            COLTYP( * ), INDX( * ), INDXC( * ), INDXP( * ),
*      $                   INDXQ( * )
*       DOUBLE PRECISION   D( * ), DLAMBDA( * ), Q( LDQ, * ), Q2( * ),
*      $                   W( * ), Z( * )
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> DLAED2 merges the two sets of eigenvalues together into a single
*> sorted set.  Then it tries to deflate the size of the problem.
*> There are two ways in which deflation can occur:  when two or more
*> eigenvalues are close together or if there is a tiny entry in the
*> Z vector.  For each such occurrence the order of the related secular
*> equation problem is reduced by one.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[out] K
*> \verbatim
*>          K is INTEGER
*>         The number of non-deflated eigenvalues, and the order of the
*>         related secular equation. 0 <= K <=N.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>         The dimension of the symmetric tridiagonal matrix.  N >= 0.
*> \endverbatim
*>
*> \param[in] N1
*> \verbatim
*>          N1 is INTEGER
*>         The location of the last eigenvalue in the leading sub-matrix.
*>         min(1,N) <= N1 <= N/2.
*> \endverbatim
*>
*> \param[in,out] D
*> \verbatim
*>          D is DOUBLE PRECISION array, dimension (N)
*>         On entry, D contains the eigenvalues of the two submatrices to
*>         be combined.
*>         On exit, D contains the trailing (N-K) updated eigenvalues
*>         (those which were deflated) sorted into increasing order.
*> \endverbatim
*>
*> \param[in,out] Q
*> \verbatim
*>          Q is DOUBLE PRECISION array, dimension (LDQ, N)
*>         On entry, Q contains the eigenvectors of two submatrices in
*>         the two square blocks with corners at (1,1), (N1,N1)
*>         and (N1+1, N1+1), (N,N).
*>         On exit, Q contains the trailing (N-K) updated eigenvectors
*>         (those which were deflated) in its last N-K columns.
*> \endverbatim
*>
*> \param[in] LDQ
*> \verbatim
*>          LDQ is INTEGER
*>         The leading dimension of the array Q.  LDQ >= max(1,N).
*> \endverbatim
*>
*> \param[in,out] INDXQ
*> \verbatim
*>          INDXQ is INTEGER array, dimension (N)
*>         The permutation which separately sorts the two sub-problems
*>         in D into ascending order.  Note that elements in the second
*>         half of this permutation must first have N1 added to their
*>         values. Destroyed on exit.
*> \endverbatim
*>
*> \param[in,out] RHO
*> \verbatim
*>          RHO is DOUBLE PRECISION
*>         On entry, the off-diagonal element associated with the rank-1
*>         cut which originally split the two submatrices which are now
*>         being recombined.
*>         On exit, RHO has been modified to the value required by
*>         DLAED3.
*> \endverbatim
*>
*> \param[in] Z
*> \verbatim
*>          Z is DOUBLE PRECISION array, dimension (N)
*>         On entry, Z contains the updating vector (the last
*>         row of the first sub-eigenvector matrix and the first row of
*>         the second sub-eigenvector matrix).
*>         On exit, the contents of Z have been destroyed by the updating
*>         process.
*> \endverbatim
*>
*> \param[out] DLAMBDA
*> \verbatim
*>          DLAMBDA is DOUBLE PRECISION array, dimension (N)
*>         A copy of the first K eigenvalues which will be used by
*>         DLAED3 to form the secular equation.
*> \endverbatim
*>
*> \param[out] W
*> \verbatim
*>          W is DOUBLE PRECISION array, dimension (N)
*>         The first k values of the final deflation-altered z-vector
*>         which will be passed to DLAED3.
*> \endverbatim
*>
*> \param[out] Q2
*> \verbatim
*>          Q2 is DOUBLE PRECISION array, dimension (N1**2+(N-N1)**2)
*>         A copy of the first K eigenvectors which will be used by
*>         DLAED3 in a matrix multiply (DGEMM) to solve for the new
*>         eigenvectors.
*> \endverbatim
*>
*> \param[out] INDX
*> \verbatim
*>          INDX is INTEGER array, dimension (N)
*>         The permutation used to sort the contents of DLAMBDA into
*>         ascending order.
*> \endverbatim
*>
*> \param[out] INDXC
*> \verbatim
*>          INDXC is INTEGER array, dimension (N)
*>         The permutation used to arrange the columns of the deflated
*>         Q matrix into three groups:  the first group contains non-zero
*>         elements only at and above N1, the second contains
*>         non-zero elements only below N1, and the third is dense.
*> \endverbatim
*>
*> \param[out] INDXP
*> \verbatim
*>          INDXP is INTEGER array, dimension (N)
*>         The permutation used to place deflated values of D at the end
*>         of the array.  INDXP(1:K) points to the nondeflated D-values
*>         and INDXP(K+1:N) points to the deflated eigenvalues.
*> \endverbatim
*>
*> \param[out] COLTYP
*> \verbatim
*>          COLTYP is INTEGER array, dimension (N)
*>         During execution, a label which will indicate which of the
*>         following types a column in the Q2 matrix is:
*>         1 : non-zero in the upper half only;
*>         2 : dense;
*>         3 : non-zero in the lower half only;
*>         4 : deflated.
*>         On exit, COLTYP(i) is the number of columns of type i,
*>         for i=1 to 4 only.
*> \endverbatim
*>
*> \param[out] INFO
*> \verbatim
*>          INFO is INTEGER
*>          = 0:  successful exit.
*>          < 0:  if INFO = -i, the i-th argument had an illegal value.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \ingroup laed2
*
*> \par Contributors:
*  ==================
*>
*> Jeff Rutter, Computer Science Division, University of California
*> at Berkeley, USA \n
*>  Modified by Francoise Tisseur, University of Tennessee
*>
*  =====================================================================
      SUBROUTINE dlaed2( K, N, N1, D, Q, LDQ, INDXQ, RHO, Z, DLAMBDA, W,
     $                   Q2, INDX, INDXC, INDXP, COLTYP, INFO )
*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            INFO, K, LDQ, N, N1
      DOUBLE PRECISION   RHO
*     ..
*     .. Array Arguments ..
      INTEGER            COLTYP( * ), INDX( * ), INDXC( * ), INDXP( * ),
     $                   indxq( * )
      DOUBLE PRECISION   D( * ), DLAMBDA( * ), Q( LDQ, * ), Q2( * ),
     $                   w( * ), z( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   MONE, ZERO, ONE, TWO, EIGHT
      parameter( mone = -1.0d0, zero = 0.0d0, one = 1.0d0,
     $                   two = 2.0d0, eight = 8.0d0 )
*     ..
*     .. Local Arrays ..
      INTEGER            CTOT( 4 ), PSM( 4 )
*     ..
*     .. Local Scalars ..
      INTEGER            CT, I, IMAX, IQ1, IQ2, J, JMAX, JS, K2, N1P1,
     $                   n2, nj, pj
      DOUBLE PRECISION   C, EPS, S, T, TAU, TOL
*     ..
*     .. External Functions ..
      INTEGER            IDAMAX
      DOUBLE PRECISION   DLAMCH, DLAPY2
      EXTERNAL           idamax, dlamch, dlapy2
*     ..
*     .. External Subroutines ..
      EXTERNAL           dcopy, dlacpy, dlamrg, drot, dscal, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, max, min, sqrt
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
*
      IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( ldq.LT.max( 1, n ) ) THEN
         info = -6
      ELSE IF( min( 1, ( n / 2 ) ).GT.n1 .OR. ( n / 2 ).LT.n1 ) THEN
         info = -3
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'DLAED2', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 )
     $   RETURN
*
      n2 = n - n1
      n1p1 = n1 + 1
*
      IF( rho.LT.zero ) THEN
         CALL dscal( n2, mone, z( n1p1 ), 1 )
      END IF
*
*     Normalize z so that norm(z) = 1.  Since z is the concatenation of
*     two normalized vectors, norm2(z) = sqrt(2).
*
      t = one / sqrt( two )
      CALL dscal( n, t, z, 1 )
*
*     RHO = ABS( norm(z)**2 * RHO )
*
      rho = abs( two*rho )
*
*     Sort the eigenvalues into increasing order
*
      DO 10 i = n1p1, n
         indxq( i ) = indxq( i ) + n1
   10 CONTINUE
*
*     re-integrate the deflated parts from the last pass
*
      DO 20 i = 1, n
         dlambda( i ) = d( indxq( i ) )
   20 CONTINUE
      CALL dlamrg( n1, n2, dlambda, 1, 1, indxc )
      DO 30 i = 1, n
         indx( i ) = indxq( indxc( i ) )
   30 CONTINUE
*
*     Calculate the allowable deflation tolerance
*
      imax = idamax( n, z, 1 )
      jmax = idamax( n, d, 1 )
      eps = dlamch( 'Epsilon' )
      tol = eight*eps*max( abs( d( jmax ) ), abs( z( imax ) ) )
*
*     If the rank-1 modifier is small enough, no more needs to be done
*     except to reorganize Q so that its columns correspond with the
*     elements in D.
*
      IF( rho*abs( z( imax ) ).LE.tol ) THEN
         k = 0
         iq2 = 1
         DO 40 j = 1, n
            i = indx( j )
            CALL dcopy( n, q( 1, i ), 1, q2( iq2 ), 1 )
            dlambda( j ) = d( i )
            iq2 = iq2 + n
   40    CONTINUE
         CALL dlacpy( 'A', n, n, q2, n, q, ldq )
         CALL dcopy( n, dlambda, 1, d, 1 )
         GO TO 190
      END IF
*
*     If there are multiple eigenvalues then the problem deflates.  Here
*     the number of equal eigenvalues are found.  As each equal
*     eigenvalue is found, an elementary reflector is computed to rotate
*     the corresponding eigensubspace so that the corresponding
*     components of Z are zero in this new basis.
*
      DO 50 i = 1, n1
         coltyp( i ) = 1
   50 CONTINUE
      DO 60 i = n1p1, n
         coltyp( i ) = 3
   60 CONTINUE
*
*
      k = 0
      k2 = n + 1
      DO 70 j = 1, n
         nj = indx( j )
         IF( rho*abs( z( nj ) ).LE.tol ) THEN
*
*           Deflate due to small z component.
*
            k2 = k2 - 1
            coltyp( nj ) = 4
            indxp( k2 ) = nj
            IF( j.EQ.n )
     $         GO TO 100
         ELSE
            pj = nj
            GO TO 80
         END IF
   70 CONTINUE
   80 CONTINUE
      j = j + 1
      nj = indx( j )
      IF( j.GT.n )
     $   GO TO 100
      IF( rho*abs( z( nj ) ).LE.tol ) THEN
*
*        Deflate due to small z component.
*
         k2 = k2 - 1
         coltyp( nj ) = 4
         indxp( k2 ) = nj
      ELSE
*
*        Check if eigenvalues are close enough to allow deflation.
*
         s = z( pj )
         c = z( nj )
*
*        Find sqrt(a**2+b**2) without overflow or
*        destructive underflow.
*
         tau = dlapy2( c, s )
         t = d( nj ) - d( pj )
         c = c / tau
         s = -s / tau
         IF( abs( t*c*s ).LE.tol ) THEN
*
*           Deflation is possible.
*
            z( nj ) = tau
            z( pj ) = zero
            IF( coltyp( nj ).NE.coltyp( pj ) )
     $         coltyp( nj ) = 2
            coltyp( pj ) = 4
            CALL drot( n, q( 1, pj ), 1, q( 1, nj ), 1, c, s )
            t = d( pj )*c**2 + d( nj )*s**2
            d( nj ) = d( pj )*s**2 + d( nj )*c**2
            d( pj ) = t
            k2 = k2 - 1
            i = 1
   90       CONTINUE
            IF( k2+i.LE.n ) THEN
               IF( d( pj ).LT.d( indxp( k2+i ) ) ) THEN
                  indxp( k2+i-1 ) = indxp( k2+i )
                  indxp( k2+i ) = pj
                  i = i + 1
                  GO TO 90
               ELSE
                  indxp( k2+i-1 ) = pj
               END IF
            ELSE
               indxp( k2+i-1 ) = pj
            END IF
            pj = nj
         ELSE
            k = k + 1
            dlambda( k ) = d( pj )
            w( k ) = z( pj )
            indxp( k ) = pj
            pj = nj
         END IF
      END IF
      GO TO 80
  100 CONTINUE
*
*     Record the last eigenvalue.
*
      k = k + 1
      dlambda( k ) = d( pj )
      w( k ) = z( pj )
      indxp( k ) = pj
*
*     Count up the total number of the various types of columns, then
*     form a permutation which positions the four column types into
*     four uniform groups (although one or more of these groups may be
*     empty).
*
      DO 110 j = 1, 4
         ctot( j ) = 0
  110 CONTINUE
      DO 120 j = 1, n
         ct = coltyp( j )
         ctot( ct ) = ctot( ct ) + 1
  120 CONTINUE
*
*     PSM(*) = Position in SubMatrix (of types 1 through 4)
*
      psm( 1 ) = 1
      psm( 2 ) = 1 + ctot( 1 )
      psm( 3 ) = psm( 2 ) + ctot( 2 )
      psm( 4 ) = psm( 3 ) + ctot( 3 )
      k = n - ctot( 4 )
*
*     Fill out the INDXC array so that the permutation which it induces
*     will place all type-1 columns first, all type-2 columns next,
*     then all type-3's, and finally all type-4's.
*
      DO 130 j = 1, n
         js = indxp( j )
         ct = coltyp( js )
         indx( psm( ct ) ) = js
         indxc( psm( ct ) ) = j
         psm( ct ) = psm( ct ) + 1
  130 CONTINUE
*
*     Sort the eigenvalues and corresponding eigenvectors into DLAMBDA
*     and Q2 respectively.  The eigenvalues/vectors which were not
*     deflated go into the first K slots of DLAMBDA and Q2 respectively,
*     while those which were deflated go into the last N - K slots.
*
      i = 1
      iq1 = 1
      iq2 = 1 + ( ctot( 1 )+ctot( 2 ) )*n1
      DO 140 j = 1, ctot( 1 )
         js = indx( i )
         CALL dcopy( n1, q( 1, js ), 1, q2( iq1 ), 1 )
         z( i ) = d( js )
         i = i + 1
         iq1 = iq1 + n1
  140 CONTINUE
*
      DO 150 j = 1, ctot( 2 )
         js = indx( i )
         CALL dcopy( n1, q( 1, js ), 1, q2( iq1 ), 1 )
         CALL dcopy( n2, q( n1+1, js ), 1, q2( iq2 ), 1 )
         z( i ) = d( js )
         i = i + 1
         iq1 = iq1 + n1
         iq2 = iq2 + n2
  150 CONTINUE
*
      DO 160 j = 1, ctot( 3 )
         js = indx( i )
         CALL dcopy( n2, q( n1+1, js ), 1, q2( iq2 ), 1 )
         z( i ) = d( js )
         i = i + 1
         iq2 = iq2 + n2
  160 CONTINUE
*
      iq1 = iq2
      DO 170 j = 1, ctot( 4 )
         js = indx( i )
         CALL dcopy( n, q( 1, js ), 1, q2( iq2 ), 1 )
         iq2 = iq2 + n
         z( i ) = d( js )
         i = i + 1
  170 CONTINUE
*
*     The deflated eigenvalues and their corresponding vectors go back
*     into the last N - K slots of D and Q respectively.
*
      IF( k.LT.n ) THEN
         CALL dlacpy( 'A', n, ctot( 4 ), q2( iq1 ), n,
     $                q( 1, k+1 ), ldq )
         CALL dcopy( n-k, z( k+1 ), 1, d( k+1 ), 1 )
      END IF
*
*     Copy CTOT into COLTYP for referencing in DLAED3.
*
      DO 180 j = 1, 4
         coltyp( j ) = ctot( j )
  180 CONTINUE
*
  190 CONTINUE
      RETURN
*
*     End of DLAED2
*
      END