ctrsyl()

subroutine ctrsyl	(	character	trana,
		character	tranb,
		integer	isgn,
		integer	m,
		integer	n,
		complex, dimension( lda, * )	a,
		integer	lda,
		complex, dimension( ldb, * )	b,
		integer	ldb,
		complex, dimension( ldc, * )	c,
		integer	ldc,
		real	scale,
		integer	info )

CTRSYL

Download CTRSYL + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> CTRSYL solves the complex Sylvester matrix equation:
!>
!>    op(A)*X + X*op(B) = scale*C or
!>    op(A)*X - X*op(B) = scale*C,
!>
!> where op(A) = A or A**H, and A and B are both upper triangular. A is
!> M-by-M and B is N-by-N; the right hand side C and the solution X are
!> M-by-N; and scale is an output scale factor, set <= 1 to avoid
!> overflow in X.
!> 

Parameters

[in]	TRANA	!> TRANA is CHARACTER*1 !> Specifies the option op(A): !> = 'N': op(A) = A (No transpose) !> = 'C': op(A) = A**H (Conjugate transpose) !>
[in]	TRANB	!> TRANB is CHARACTER*1 !> Specifies the option op(B): !> = 'N': op(B) = B (No transpose) !> = 'C': op(B) = B**H (Conjugate transpose) !>
[in]	ISGN	!> ISGN is INTEGER !> Specifies the sign in the equation: !> = +1: solve op(A)*X + X*op(B) = scale*C !> = -1: solve op(A)*X - X*op(B) = scale*C !>
[in]	M	!> M is INTEGER !> The order of the matrix A, and the number of rows in the !> matrices X and C. M >= 0. !>
[in]	N	!> N is INTEGER !> The order of the matrix B, and the number of columns in the !> matrices X and C. N >= 0. !>
[in]	A	!> A is COMPLEX array, dimension (LDA,M) !> The upper triangular matrix A. !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the array A. LDA >= max(1,M). !>
[in]	B	!> B is COMPLEX array, dimension (LDB,N) !> The upper triangular matrix B. !>
[in]	LDB	!> LDB is INTEGER !> The leading dimension of the array B. LDB >= max(1,N). !>
[in,out]	C	!> C is COMPLEX array, dimension (LDC,N) !> On entry, the M-by-N right hand side matrix C. !> On exit, C is overwritten by the solution matrix X. !>
[in]	LDC	!> LDC is INTEGER !> The leading dimension of the array C. LDC >= max(1,M) !>
[out]	SCALE	!> SCALE is REAL !> The scale factor, scale, set <= 1 to avoid overflow in X. !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit !> < 0: if INFO = -i, the i-th argument had an illegal value !> = 1: A and B have common or very close eigenvalues; perturbed !> values were used to solve the equation (but the matrices !> A and B are unchanged). !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 153 of file ctrsyl.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          TRANA, TRANB
      INTEGER            INFO, ISGN, LDA, LDB, LDC, M, N
      REAL               SCALE
*     ..
*     .. Array Arguments ..
      COMPLEX            A( LDA, * ), B( LDB, * ), C( LDC, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ONE
      parameter( one = 1.0e+0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            NOTRNA, NOTRNB
      INTEGER            J, K, L
      REAL               BIGNUM, DA11, DB, EPS, SCALOC, SGN, SMIN,
     $                   SMLNUM
      COMPLEX            A11, SUML, SUMR, VEC, X11
*     ..
*     .. Local Arrays ..
      REAL               DUM( 1 )
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      REAL               CLANGE, SLAMCH
      COMPLEX            CDOTC, CDOTU, CLADIV
      EXTERNAL           lsame, clange, slamch, cdotc, cdotu,
     $                   cladiv
*     ..
*     .. External Subroutines ..
      EXTERNAL           csscal, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, aimag, cmplx, conjg, max, min, real
*     ..
*     .. Executable Statements ..
*
*     Decode and Test input parameters
*
      notrna = lsame( trana, 'N' )
      notrnb = lsame( tranb, 'N' )
*
      info = 0
      IF( .NOT.notrna .AND. .NOT.lsame( trana, 'C' ) ) THEN
         info = -1
      ELSE IF( .NOT.notrnb .AND. .NOT.lsame( tranb, 'C' ) ) THEN
         info = -2
      ELSE IF( isgn.NE.1 .AND. isgn.NE.-1 ) THEN
         info = -3
      ELSE IF( m.LT.0 ) THEN
         info = -4
      ELSE IF( n.LT.0 ) THEN
         info = -5
      ELSE IF( lda.LT.max( 1, m ) ) THEN
         info = -7
      ELSE IF( ldb.LT.max( 1, n ) ) THEN
         info = -9
      ELSE IF( ldc.LT.max( 1, m ) ) THEN
         info = -11
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'CTRSYL', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      scale = one
      IF( m.EQ.0 .OR. n.EQ.0 )
     $   RETURN
*
*     Set constants to control overflow
*
      eps = slamch( 'P' )
      smlnum = slamch( 'S' )
      bignum = one / smlnum
      smlnum = smlnum*real( m*n ) / eps
      bignum = one / smlnum
      smin = max( smlnum, eps*clange( 'M', m, m, a, lda, dum ),
     $       eps*clange( 'M', n, n, b, ldb, dum ) )
      sgn = real( isgn )
*
      IF( notrna .AND. notrnb ) THEN
*
*        Solve    A*X + ISGN*X*B = scale*C.
*
*        The (K,L)th block of X is determined starting from
*        bottom-left corner column by column by
*
*            A(K,K)*X(K,L) + ISGN*X(K,L)*B(L,L) = C(K,L) - R(K,L)
*
*        Where
*                    M                        L-1
*          R(K,L) = SUM [A(K,I)*X(I,L)] +ISGN*SUM [X(K,J)*B(J,L)].
*                  I=K+1                      J=1
*
         DO 30 l = 1, n
            DO 20 k = m, 1, -1
*
               suml = cdotu( m-k, a( k, min( k+1, m ) ), lda,
     $                c( min( k+1, m ), l ), 1 )
               sumr = cdotu( l-1, c( k, 1 ), ldc, b( 1, l ), 1 )
               vec = c( k, l ) - ( suml+sgn*sumr )
*
               scaloc = one
               a11 = a( k, k ) + sgn*b( l, l )
               da11 = abs( real( a11 ) ) + abs( aimag( a11 ) )
               IF( da11.LE.smin ) THEN
                  a11 = smin
                  da11 = smin
                  info = 1
               END IF
               db = abs( real( vec ) ) + abs( aimag( vec ) )
               IF( da11.LT.one .AND. db.GT.one ) THEN
                  IF( db.GT.bignum*da11 )
     $               scaloc = one / db
               END IF
               x11 = cladiv( vec*cmplx( scaloc ), a11 )
*
               IF( scaloc.NE.one ) THEN
                  DO 10 j = 1, n
                     CALL csscal( m, scaloc, c( 1, j ), 1 )
   10             CONTINUE
                  scale = scale*scaloc
               END IF
               c( k, l ) = x11
*
   20       CONTINUE
   30    CONTINUE
*
      ELSE IF( .NOT.notrna .AND. notrnb ) THEN
*
*        Solve    A**H *X + ISGN*X*B = scale*C.
*
*        The (K,L)th block of X is determined starting from
*        upper-left corner column by column by
*
*            A**H(K,K)*X(K,L) + ISGN*X(K,L)*B(L,L) = C(K,L) - R(K,L)
*
*        Where
*                   K-1                           L-1
*          R(K,L) = SUM [A**H(I,K)*X(I,L)] + ISGN*SUM [X(K,J)*B(J,L)]
*                   I=1                           J=1
*
         DO 60 l = 1, n
            DO 50 k = 1, m
*
               suml = cdotc( k-1, a( 1, k ), 1, c( 1, l ), 1 )
               sumr = cdotu( l-1, c( k, 1 ), ldc, b( 1, l ), 1 )
               vec = c( k, l ) - ( suml+sgn*sumr )
*
               scaloc = one
               a11 = conjg( a( k, k ) ) + sgn*b( l, l )
               da11 = abs( real( a11 ) ) + abs( aimag( a11 ) )
               IF( da11.LE.smin ) THEN
                  a11 = smin
                  da11 = smin
                  info = 1
               END IF
               db = abs( real( vec ) ) + abs( aimag( vec ) )
               IF( da11.LT.one .AND. db.GT.one ) THEN
                  IF( db.GT.bignum*da11 )
     $               scaloc = one / db
               END IF
*
               x11 = cladiv( vec*cmplx( scaloc ), a11 )
*
               IF( scaloc.NE.one ) THEN
                  DO 40 j = 1, n
                     CALL csscal( m, scaloc, c( 1, j ), 1 )
   40             CONTINUE
                  scale = scale*scaloc
               END IF
               c( k, l ) = x11
*
   50       CONTINUE
   60    CONTINUE
*
      ELSE IF( .NOT.notrna .AND. .NOT.notrnb ) THEN
*
*        Solve    A**H*X + ISGN*X*B**H = C.
*
*        The (K,L)th block of X is determined starting from
*        upper-right corner column by column by
*
*            A**H(K,K)*X(K,L) + ISGN*X(K,L)*B**H(L,L) = C(K,L) - R(K,L)
*
*        Where
*                    K-1
*           R(K,L) = SUM [A**H(I,K)*X(I,L)] +
*                    I=1
*                           N
*                     ISGN*SUM [X(K,J)*B**H(L,J)].
*                          J=L+1
*
         DO 90 l = n, 1, -1
            DO 80 k = 1, m
*
               suml = cdotc( k-1, a( 1, k ), 1, c( 1, l ), 1 )
               sumr = cdotc( n-l, c( k, min( l+1, n ) ), ldc,
     $                b( l, min( l+1, n ) ), ldb )
               vec = c( k, l ) - ( suml+sgn*conjg( sumr ) )
*
               scaloc = one
               a11 = conjg( a( k, k )+sgn*b( l, l ) )
               da11 = abs( real( a11 ) ) + abs( aimag( a11 ) )
               IF( da11.LE.smin ) THEN
                  a11 = smin
                  da11 = smin
                  info = 1
               END IF
               db = abs( real( vec ) ) + abs( aimag( vec ) )
               IF( da11.LT.one .AND. db.GT.one ) THEN
                  IF( db.GT.bignum*da11 )
     $               scaloc = one / db
               END IF
*
               x11 = cladiv( vec*cmplx( scaloc ), a11 )
*
               IF( scaloc.NE.one ) THEN
                  DO 70 j = 1, n
                     CALL csscal( m, scaloc, c( 1, j ), 1 )
   70             CONTINUE
                  scale = scale*scaloc
               END IF
               c( k, l ) = x11
*
   80       CONTINUE
   90    CONTINUE
*
      ELSE IF( notrna .AND. .NOT.notrnb ) THEN
*
*        Solve    A*X + ISGN*X*B**H = C.
*
*        The (K,L)th block of X is determined starting from
*        bottom-left corner column by column by
*
*           A(K,K)*X(K,L) + ISGN*X(K,L)*B**H(L,L) = C(K,L) - R(K,L)
*
*        Where
*                    M                          N
*          R(K,L) = SUM [A(K,I)*X(I,L)] + ISGN*SUM [X(K,J)*B**H(L,J)]
*                  I=K+1                      J=L+1
*
         DO 120 l = n, 1, -1
            DO 110 k = m, 1, -1
*
               suml = cdotu( m-k, a( k, min( k+1, m ) ), lda,
     $                c( min( k+1, m ), l ), 1 )
               sumr = cdotc( n-l, c( k, min( l+1, n ) ), ldc,
     $                b( l, min( l+1, n ) ), ldb )
               vec = c( k, l ) - ( suml+sgn*conjg( sumr ) )
*
               scaloc = one
               a11 = a( k, k ) + sgn*conjg( b( l, l ) )
               da11 = abs( real( a11 ) ) + abs( aimag( a11 ) )
               IF( da11.LE.smin ) THEN
                  a11 = smin
                  da11 = smin
                  info = 1
               END IF
               db = abs( real( vec ) ) + abs( aimag( vec ) )
               IF( da11.LT.one .AND. db.GT.one ) THEN
                  IF( db.GT.bignum*da11 )
     $               scaloc = one / db
               END IF
*
               x11 = cladiv( vec*cmplx( scaloc ), a11 )
*
               IF( scaloc.NE.one ) THEN
                  DO 100 j = 1, n
                     CALL csscal( m, scaloc, c( 1, j ), 1 )
  100             CONTINUE
                  scale = scale*scaloc
               END IF
               c( k, l ) = x11
*
  110       CONTINUE
  120    CONTINUE
*
      END IF
*
      RETURN
*
*     End of CTRSYL
*

Here is the call graph for this function:

Here is the caller graph for this function: