schkrq.f

Go to the documentation of this file.

*> \brief \b SCHKRQ
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*  Definition:
*  ===========
*
*       SUBROUTINE SCHKRQ( DOTYPE, NM, MVAL, NN, NVAL, NNB, NBVAL, NXVAL,
*                          NRHS, THRESH, TSTERR, NMAX, A, AF, AQ, AR, AC,
*                          B, X, XACT, TAU, WORK, RWORK, IWORK, NOUT )
*
*       .. Scalar Arguments ..
*       LOGICAL            TSTERR
*       INTEGER            NM, NMAX, NN, NNB, NOUT, NRHS
*       REAL               THRESH
*       ..
*       .. Array Arguments ..
*       LOGICAL            DOTYPE( * )
*       INTEGER            IWORK( * ), MVAL( * ), NBVAL( * ), NVAL( * ),
*      $                   NXVAL( * )
*       REAL               A( * ), AC( * ), AF( * ), AQ( * ), AR( * ),
*      $                   B( * ), RWORK( * ), TAU( * ), WORK( * ),
*      $                   X( * ), XACT( * )
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> SCHKRQ tests SGERQF, SORGRQ and SORMRQ.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] DOTYPE
*> \verbatim
*>          DOTYPE is LOGICAL array, dimension (NTYPES)
*>          The matrix types to be used for testing.  Matrices of type j
*>          (for 1 <= j <= NTYPES) are used for testing if DOTYPE(j) =
*>          .TRUE.; if DOTYPE(j) = .FALSE., then type j is not used.
*> \endverbatim
*>
*> \param[in] NM
*> \verbatim
*>          NM is INTEGER
*>          The number of values of M contained in the vector MVAL.
*> \endverbatim
*>
*> \param[in] MVAL
*> \verbatim
*>          MVAL is INTEGER array, dimension (NM)
*>          The values of the matrix row dimension M.
*> \endverbatim
*>
*> \param[in] NN
*> \verbatim
*>          NN is INTEGER
*>          The number of values of N contained in the vector NVAL.
*> \endverbatim
*>
*> \param[in] NVAL
*> \verbatim
*>          NVAL is INTEGER array, dimension (NN)
*>          The values of the matrix column dimension N.
*> \endverbatim
*>
*> \param[in] NNB
*> \verbatim
*>          NNB is INTEGER
*>          The number of values of NB and NX contained in the
*>          vectors NBVAL and NXVAL.  The blocking parameters are used
*>          in pairs (NB,NX).
*> \endverbatim
*>
*> \param[in] NBVAL
*> \verbatim
*>          NBVAL is INTEGER array, dimension (NNB)
*>          The values of the blocksize NB.
*> \endverbatim
*>
*> \param[in] NXVAL
*> \verbatim
*>          NXVAL is INTEGER array, dimension (NNB)
*>          The values of the crossover point NX.
*> \endverbatim
*>
*> \param[in] NRHS
*> \verbatim
*>          NRHS is INTEGER
*>          The number of right hand side vectors to be generated for
*>          each linear system.
*> \endverbatim
*>
*> \param[in] THRESH
*> \verbatim
*>          THRESH is REAL
*>          The threshold value for the test ratios.  A result is
*>          included in the output file if RESULT >= THRESH.  To have
*>          every test ratio printed, use THRESH = 0.
*> \endverbatim
*>
*> \param[in] TSTERR
*> \verbatim
*>          TSTERR is LOGICAL
*>          Flag that indicates whether error exits are to be tested.
*> \endverbatim
*>
*> \param[in] NMAX
*> \verbatim
*>          NMAX is INTEGER
*>          The maximum value permitted for M or N, used in dimensioning
*>          the work arrays.
*> \endverbatim
*>
*> \param[out] A
*> \verbatim
*>          A is REAL array, dimension (NMAX*NMAX)
*> \endverbatim
*>
*> \param[out] AF
*> \verbatim
*>          AF is REAL array, dimension (NMAX*NMAX)
*> \endverbatim
*>
*> \param[out] AQ
*> \verbatim
*>          AQ is REAL array, dimension (NMAX*NMAX)
*> \endverbatim
*>
*> \param[out] AR
*> \verbatim
*>          AR is REAL array, dimension (NMAX*NMAX)
*> \endverbatim
*>
*> \param[out] AC
*> \verbatim
*>          AC is REAL array, dimension (NMAX*NMAX)
*> \endverbatim
*>
*> \param[out] B
*> \verbatim
*>          B is REAL array, dimension (NMAX*NRHS)
*> \endverbatim
*>
*> \param[out] X
*> \verbatim
*>          X is REAL array, dimension (NMAX*NRHS)
*> \endverbatim
*>
*> \param[out] XACT
*> \verbatim
*>          XACT is REAL array, dimension (NMAX*NRHS)
*> \endverbatim
*>
*> \param[out] TAU
*> \verbatim
*>          TAU is REAL array, dimension (NMAX)
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is REAL array, dimension (NMAX*NMAX)
*> \endverbatim
*>
*> \param[out] RWORK
*> \verbatim
*>          RWORK is REAL array, dimension (NMAX)
*> \endverbatim
*>
*> \param[out] IWORK
*> \verbatim
*>          IWORK is INTEGER array, dimension (NMAX)
*> \endverbatim
*>
*> \param[in] NOUT
*> \verbatim
*>          NOUT is INTEGER
*>          The unit number for output.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \ingroup single_lin
*
*  =====================================================================
      SUBROUTINE schkrq( DOTYPE, NM, MVAL, NN, NVAL, NNB, NBVAL, NXVAL,
     $                   NRHS, THRESH, TSTERR, NMAX, A, AF, AQ, AR, AC,
     $                   B, X, XACT, TAU, WORK, RWORK, IWORK, NOUT )
*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      LOGICAL            TSTERR
      INTEGER            NM, NMAX, NN, NNB, NOUT, NRHS
      REAL               THRESH
*     ..
*     .. Array Arguments ..
      LOGICAL            DOTYPE( * )
      INTEGER            IWORK( * ), MVAL( * ), NBVAL( * ), NVAL( * ),
     $                   nxval( * )
      REAL               A( * ), AC( * ), AF( * ), AQ( * ), AR( * ),
     $                   B( * ), RWORK( * ), TAU( * ), WORK( * ),
     $                   x( * ), xact( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            NTESTS
      PARAMETER          ( NTESTS = 7 )
      INTEGER            NTYPES
      parameter( ntypes = 8 )
      REAL               ZERO
      parameter( zero = 0.0e0 )
*     ..
*     .. Local Scalars ..
      CHARACTER          DIST, TYPE
      CHARACTER*3        PATH
      INTEGER            I, IK, IM, IMAT, IN, INB, INFO, K, KL, KU, LDA,
     $                   lwork, m, minmn, mode, n, nb, nerrs, nfail, nk,
     $                   nrun, nt, nx
      REAL               ANORM, CNDNUM
*     ..
*     .. Local Arrays ..
      INTEGER            ISEED( 4 ), ISEEDY( 4 ), KVAL( 4 )
      REAL               RESULT( NTESTS )
*     ..
*     .. External Subroutines ..
      EXTERNAL           alaerh, alahd, alasum, serrrq, sgerqs, sget02,
     $                   slacpy, slarhs, slatb4, slatms, srqt01, srqt02,
     $                   srqt03, xlaenv
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min
*     ..
*     .. Scalars in Common ..
      LOGICAL            LERR, OK
      CHARACTER*32       SRNAMT
      INTEGER            INFOT, NUNIT
*     ..
*     .. Common blocks ..
      COMMON             / infoc / infot, nunit, ok, lerr
      COMMON             / srnamc / srnamt
*     ..
*     .. Data statements ..
      DATA               iseedy / 1988, 1989, 1990, 1991 /
*     ..
*     .. Executable Statements ..
*
*     Initialize constants and the random number seed.
*
      path( 1: 1 ) = 'Single precision'
      path( 2: 3 ) = 'RQ'
      nrun = 0
      nfail = 0
      nerrs = 0
      DO 10 i = 1, 4
         iseed( i ) = iseedy( i )
   10 CONTINUE
*
*     Test the error exits
*
      IF( tsterr )
     $   CALL serrrq( path, nout )
      infot = 0
      CALL xlaenv( 2, 2 )
*
      lda = nmax
      lwork = nmax*max( nmax, nrhs )
*
*     Do for each value of M in MVAL.
*
      DO 70 im = 1, nm
         m = mval( im )
*
*        Do for each value of N in NVAL.
*
         DO 60 in = 1, nn
            n = nval( in )
            minmn = min( m, n )
            DO 50 imat = 1, ntypes
*
*              Do the tests only if DOTYPE( IMAT ) is true.
*
               IF( .NOT.dotype( imat ) )
     $            GO TO 50
*
*              Set up parameters with SLATB4 and generate a test matrix
*              with SLATMS.
*
               CALL slatb4( path, imat, m, n, TYPE, kl, ku, anorm, mode,
     $                      cndnum, dist )
*
               srnamt = 'SLATMS'
               CALL slatms( m, n, dist, iseed, TYPE, rwork, mode,
     $                      cndnum, anorm, kl, ku, 'No packing', a, lda,
     $                      work, info )
*
*              Check error code from SLATMS.
*
               IF( info.NE.0 ) THEN
                  CALL alaerh( path, 'SLATMS', info, 0, ' ', m, n, -1,
     $                         -1, -1, imat, nfail, nerrs, nout )
                  GO TO 50
               END IF
*
*              Set some values for K: the first value must be MINMN,
*              corresponding to the call of SRQT01; other values are
*              used in the calls of SRQT02, and must not exceed MINMN.
*
               kval( 1 ) = minmn
               kval( 2 ) = 0
               kval( 3 ) = 1
               kval( 4 ) = minmn / 2
               IF( minmn.EQ.0 ) THEN
                  nk = 1
               ELSE IF( minmn.EQ.1 ) THEN
                  nk = 2
               ELSE IF( minmn.LE.3 ) THEN
                  nk = 3
               ELSE
                  nk = 4
               END IF
*
*              Do for each value of K in KVAL
*
               DO 40 ik = 1, nk
                  k = kval( ik )
*
*                 Do for each pair of values (NB,NX) in NBVAL and NXVAL.
*
                  DO 30 inb = 1, nnb
                     nb = nbval( inb )
                     CALL xlaenv( 1, nb )
                     nx = nxval( inb )
                     CALL xlaenv( 3, nx )
                     DO i = 1, ntests
                        result( i ) = zero
                     END DO
                     nt = 2
                     IF( ik.EQ.1 ) THEN
*
*                       Test SGERQF
*
                        CALL srqt01( m, n, a, af, aq, ar, lda, tau,
     $                               work, lwork, rwork, result( 1 ) )
                     ELSE IF( m.LE.n ) THEN
*
*                       Test SORGRQ, using factorization
*                       returned by SRQT01
*
                        CALL srqt02( m, n, k, a, af, aq, ar, lda, tau,
     $                               work, lwork, rwork, result( 1 ) )
                     END IF
                     IF( m.GE.k ) THEN
*
*                       Test SORMRQ, using factorization returned
*                       by SRQT01
*
                        CALL srqt03( m, n, k, af, ac, ar, aq, lda, tau,
     $                               work, lwork, rwork, result( 3 ) )
                        nt = nt + 4
*
*                       If M>=N and K=N, call SGERQS to solve a system
*                       with NRHS right hand sides and compute the
*                       residual.
*
                        IF( k.EQ.m .AND. inb.EQ.1 ) THEN
*
*                          Generate a solution and set the right
*                          hand side.
*
                           srnamt = 'SLARHS'
                           CALL slarhs( path, 'New', 'Full',
     $                                  'No transpose', m, n, 0, 0,
     $                                  nrhs, a, lda, xact, lda, b, lda,
     $                                  iseed, info )
*
                           CALL slacpy( 'Full', m, nrhs, b, lda,
     $                                  x( n-m+1 ), lda )
                           srnamt = 'SGERQS'
                           CALL sgerqs( m, n, nrhs, af, lda, tau, x,
     $                                  lda, work, lwork, info )
*
*                          Check error code from SGERQS.
*
                           IF( info.NE.0 )
     $                        CALL alaerh( path, 'SGERQS', info, 0, ' ',
     $                                     m, n, nrhs, -1, nb, imat,
     $                                     nfail, nerrs, nout )
*
                           CALL sget02( 'No transpose', m, n, nrhs, a,
     $                                  lda, x, lda, b, lda, rwork,
     $                                  result( 7 ) )
                           nt = nt + 1
                        END IF
                     END IF
*
*                    Print information about the tests that did not
*                    pass the threshold.
*
                     DO 20 i = 1, nt
                        IF( result( i ).GE.thresh ) THEN
                           IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                        CALL alahd( nout, path )
                           WRITE( nout, fmt = 9999 )m, n, k, nb, nx,
     $                        imat, i, result( i )
                           nfail = nfail + 1
                        END IF
   20                CONTINUE
                     nrun = nrun + nt
   30             CONTINUE
   40          CONTINUE
   50       CONTINUE
   60    CONTINUE
   70 CONTINUE
*
*     Print a summary of the results.
*
      CALL alasum( path, nout, nfail, nrun, nerrs )
*
 9999 FORMAT( ' M=', i5, ', N=', i5, ', K=', i5, ', NB=', i4, ', NX=',
     $      i5, ', type ', i2, ', test(', i2, ')=', g12.5 )
      RETURN
*
*     End of SCHKRQ
*
      END