zrscl()

subroutine zrscl	(	integer	n,
		complex*16	a,
		complex*16, dimension( * )	x,
		integer	incx
	)

ZDRSCL multiplies a vector by the reciprocal of a real scalar.

Download ZDRSCL + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 ZRSCL multiplies an n-element complex vector x by the complex scalar
 1/a.  This is done without overflow or underflow as long as
 the final result x/a does not overflow or underflow.

Parameters

[in]	N	N is INTEGER The number of components of the vector x.
[in]	A	A is COMPLEX*16 The scalar a which is used to divide each component of x. A must not be 0, or the subroutine will divide by zero.
[in,out]	X	X is COMPLEX*16 array, dimension (1+(N-1)*abs(INCX)) The n-element vector x.
[in]	INCX	INCX is INTEGER The increment between successive values of the vector SX. > 0: SX(1) = X(1) and SX(1+(i-1)*INCX) = x(i), 1< i<= n

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 83 of file zrscl.f.

*
*  -- LAPACK auxiliary routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            INCX, N
      COMPLEX*16         A
*     ..
*     .. Array Arguments ..
      COMPLEX*16         X( * )
*     ..
*
* =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO, ONE
      parameter( zero = 0.0d+0, one = 1.0d+0 )
*     ..
*     .. Local Scalars ..
      DOUBLE PRECISION   SAFMAX, SAFMIN, OV, AR, AI, ABSR, ABSI, UR, UI
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   DLAMCH
      COMPLEX*16         ZLADIV
      EXTERNAL           dlamch, zladiv
*     ..
*     .. External Subroutines ..
      EXTERNAL           dscal, zdscal, zdrscl
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs
*     ..
*     .. Executable Statements ..
*
*     Quick return if possible
*
      IF( n.LE.0 )
     $   RETURN
*
*     Get machine parameters
*
      safmin = dlamch( 'S' )
      safmax = one / safmin
      ov   = dlamch( 'O' )
*
*     Initialize constants related to A.
*
      ar = dble( a )
      ai = dimag( a )
      absr = abs( ar )
      absi = abs( ai )
*
      IF( ai.EQ.zero ) THEN
*        If alpha is real, then we can use csrscl
         CALL zdrscl( n, ar, x, incx )
*
      ELSE IF( ar.EQ.zero ) THEN
*        If alpha has a zero real part, then we follow the same rules as if
*        alpha were real.
         IF( absi.GT.safmax ) THEN
            CALL zdscal( n, safmin, x, incx )
            CALL zscal( n, dcmplx( zero, -safmax / ai ), x, incx )
         ELSE IF( absi.LT.safmin ) THEN
            CALL zscal( n, dcmplx( zero, -safmin / ai ), x, incx )
            CALL zdscal( n, safmax, x, incx )
         ELSE
            CALL zscal( n, dcmplx( zero, -one / ai ), x, incx )
         END IF
*
      ELSE
*        The following numbers can be computed.
*        They are the inverse of the real and imaginary parts of 1/alpha.
*        Note that a and b are always different from zero.
*        NaNs are only possible if either:
*        1. alphaR or alphaI is NaN.
*        2. alphaR and alphaI are both infinite, in which case it makes sense
*        to propagate a NaN.
         ur = ar + ai * ( ai / ar )
         ui = ai + ar * ( ar / ai )
*
         IF( (abs( ur ).LT.safmin).OR.(abs( ui ).LT.safmin) ) THEN
*           This means that both alphaR and alphaI are very small.
            CALL zscal( n, dcmplx( safmin / ur, -safmin / ui ), x,
     $                  incx )
            CALL zdscal( n, safmax, x, incx )
         ELSE IF( (abs( ur ).GT.safmax).OR.(abs( ui ).GT.safmax) ) THEN
            IF( (absr.GT.ov).OR.(absi.GT.ov) ) THEN
*              This means that a and b are both Inf. No need for scaling.
               CALL zscal( n, dcmplx( one / ur, -one / ui ), x, incx )
            ELSE
               CALL zdscal( n, safmin, x, incx )
               IF( (abs( ur ).GT.ov).OR.(abs( ui ).GT.ov) ) THEN
*                 Infs were generated. We do proper scaling to avoid them.
                  IF( absr.GE.absi ) THEN
*                    ABS( UR ) <= ABS( UI )
                     ur = (safmin * ar) + safmin * (ai * ( ai / ar ))
                     ui = (safmin * ai) + ar * ( (safmin * ar) / ai )
                  ELSE
*                    ABS( UR ) > ABS( UI )
                     ur = (safmin * ar) + ai * ( (safmin * ai) / ar )
                     ui = (safmin * ai) + safmin * (ar * ( ar / ai ))
                  END IF
                  CALL zscal( n, dcmplx( one / ur, -one / ui ), x,
     $                        incx )
               ELSE
                  CALL zscal( n, dcmplx( safmax / ur, -safmax / ui ),
     $                        x, incx )
               END IF
            END IF
         ELSE
            CALL zscal( n, dcmplx( one / ur, -one / ui ), x, incx )
         END IF
      END IF
*
      RETURN
*
*     End of ZRSCL
*

Here is the call graph for this function:

Here is the caller graph for this function: