zdrscl()

subroutine zdrscl	(	integer	n,
		double precision	sa,
		complex*16, dimension( * )	sx,
		integer	incx )

ZDRSCL multiplies a vector by the reciprocal of a real scalar.

Download ZDRSCL + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> ZDRSCL multiplies an n-element complex vector x by the real scalar
!> 1/a.  This is done without overflow or underflow as long as
!> the final result x/a does not overflow or underflow.
!> 

Parameters

[in]	N	!> N is INTEGER !> The number of components of the vector x. !>
[in]	SA	!> SA is DOUBLE PRECISION !> The scalar a which is used to divide each component of x. !> SA must be >= 0, or the subroutine will divide by zero. !>
[in,out]	SX	!> SX is COMPLEX*16 array, dimension !> (1+(N-1)*abs(INCX)) !> The n-element vector x. !>
[in]	INCX	!> INCX is INTEGER !> The increment between successive values of the vector SX. !> > 0: SX(1) = X(1) and SX(1+(i-1)*INCX) = x(i), 1< i<= n !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 81 of file zdrscl.f.

*
*  -- LAPACK auxiliary routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            INCX, N
      DOUBLE PRECISION   SA
*     ..
*     .. Array Arguments ..
      COMPLEX*16         SX( * )
*     ..
*
* =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO, ONE
      parameter( zero = 0.0d+0, one = 1.0d+0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            DONE
      DOUBLE PRECISION   BIGNUM, CDEN, CDEN1, CNUM, CNUM1, MUL, SMLNUM
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   DLAMCH
      EXTERNAL           dlamch
*     ..
*     .. External Subroutines ..
      EXTERNAL           zdscal
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs
*     ..
*     .. Executable Statements ..
*
*     Quick return if possible
*
      IF( n.LE.0 )
     $   RETURN
*
*     Get machine parameters
*
      smlnum = dlamch( 'S' )
      bignum = one / smlnum
*
*     Initialize the denominator to SA and the numerator to 1.
*
      cden = sa
      cnum = one
*
   10 CONTINUE
      cden1 = cden*smlnum
      cnum1 = cnum / bignum
      IF( abs( cden1 ).GT.abs( cnum ) .AND. cnum.NE.zero ) THEN
*
*        Pre-multiply X by SMLNUM if CDEN is large compared to CNUM.
*
         mul = smlnum
         done = .false.
         cden = cden1
      ELSE IF( abs( cnum1 ).GT.abs( cden ) ) THEN
*
*        Pre-multiply X by BIGNUM if CDEN is small compared to CNUM.
*
         mul = bignum
         done = .false.
         cnum = cnum1
      ELSE
*
*        Multiply X by CNUM / CDEN and return.
*
         mul = cnum / cden
         done = .true.
      END IF
*
*     Scale the vector X by MUL
*
      CALL zdscal( n, mul, sx, incx )
*
      IF( .NOT.done )
     $   GO TO 10
*
      RETURN
*
*     End of ZDRSCL
*

Here is the call graph for this function:

Here is the caller graph for this function: