cupmtr()

subroutine cupmtr	(	character	side,
		character	uplo,
		character	trans,
		integer	m,
		integer	n,
		complex, dimension( * )	ap,
		complex, dimension( * )	tau,
		complex, dimension( ldc, * )	c,
		integer	ldc,
		complex, dimension( * )	work,
		integer	info )

CUPMTR

Download CUPMTR + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> CUPMTR overwrites the general complex M-by-N matrix C with
!>
!>                 SIDE = 'L'     SIDE = 'R'
!> TRANS = 'N':      Q * C          C * Q
!> TRANS = 'C':      Q**H * C       C * Q**H
!>
!> where Q is a complex unitary matrix of order nq, with nq = m if
!> SIDE = 'L' and nq = n if SIDE = 'R'. Q is defined as the product of
!> nq-1 elementary reflectors, as returned by CHPTRD using packed
!> storage:
!>
!> if UPLO = 'U', Q = H(nq-1) . . . H(2) H(1);
!>
!> if UPLO = 'L', Q = H(1) H(2) . . . H(nq-1).
!> 

Parameters

[in]	SIDE	!> SIDE is CHARACTER*1 !> = 'L': apply Q or Q**H from the Left; !> = 'R': apply Q or Q**H from the Right. !>
[in]	UPLO	!> UPLO is CHARACTER*1 !> = 'U': Upper triangular packed storage used in previous !> call to CHPTRD; !> = 'L': Lower triangular packed storage used in previous !> call to CHPTRD. !>
[in]	TRANS	!> TRANS is CHARACTER*1 !> = 'N': No transpose, apply Q; !> = 'C': Conjugate transpose, apply Q**H. !>
[in]	M	!> M is INTEGER !> The number of rows of the matrix C. M >= 0. !>
[in]	N	!> N is INTEGER !> The number of columns of the matrix C. N >= 0. !>
[in]	AP	!> AP is COMPLEX array, dimension !> (M*(M+1)/2) if SIDE = 'L' !> (N*(N+1)/2) if SIDE = 'R' !> The vectors which define the elementary reflectors, as !> returned by CHPTRD. AP is modified by the routine but !> restored on exit. !>
[in]	TAU	!> TAU is COMPLEX array, dimension (M-1) if SIDE = 'L' !> or (N-1) if SIDE = 'R' !> TAU(i) must contain the scalar factor of the elementary !> reflector H(i), as returned by CHPTRD. !>
[in,out]	C	!> C is COMPLEX array, dimension (LDC,N) !> On entry, the M-by-N matrix C. !> On exit, C is overwritten by Q*C or Q**H*C or C*Q**H or C*Q. !>
[in]	LDC	!> LDC is INTEGER !> The leading dimension of the array C. LDC >= max(1,M). !>
[out]	WORK	!> WORK is COMPLEX array, dimension !> (N) if SIDE = 'L' !> (M) if SIDE = 'R' !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit !> < 0: if INFO = -i, the i-th argument had an illegal value !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 146 of file cupmtr.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          SIDE, TRANS, UPLO
      INTEGER            INFO, LDC, M, N
*     ..
*     .. Array Arguments ..
      COMPLEX            AP( * ), C( LDC, * ), TAU( * ), WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Local Scalars ..
      LOGICAL            FORWRD, LEFT, NOTRAN, UPPER
      INTEGER            I, I1, I2, I3, IC, II, JC, MI, NI, NQ
      COMPLEX            TAUI
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      EXTERNAL           lsame
*     ..
*     .. External Subroutines ..
      EXTERNAL           clarf1f, clarf1l, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          conjg, max
*     ..
*     .. Executable Statements ..
*
*     Test the input arguments
*
      info = 0
      left = lsame( side, 'L' )
      notran = lsame( trans, 'N' )
      upper = lsame( uplo, 'U' )
*
*     NQ is the order of Q
*
      IF( left ) THEN
         nq = m
      ELSE
         nq = n
      END IF
      IF( .NOT.left .AND. .NOT.lsame( side, 'R' ) ) THEN
         info = -1
      ELSE IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
         info = -2
      ELSE IF( .NOT.notran .AND. .NOT.lsame( trans, 'C' ) ) THEN
         info = -3
      ELSE IF( m.LT.0 ) THEN
         info = -4
      ELSE IF( n.LT.0 ) THEN
         info = -5
      ELSE IF( ldc.LT.max( 1, m ) ) THEN
         info = -9
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'CUPMTR', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( m.EQ.0 .OR. n.EQ.0 )
     $   RETURN
*
      IF( upper ) THEN
*
*        Q was determined by a call to CHPTRD with UPLO = 'U'
*
         forwrd = ( left .AND. notran ) .OR.
     $            ( .NOT.left .AND. .NOT.notran )
*
         IF( forwrd ) THEN
            i1 = 1
            i2 = nq - 1
            i3 = 1
            ii = 2
         ELSE
            i1 = nq - 1
            i2 = 1
            i3 = -1
            ii = nq*( nq+1 ) / 2 - 1
         END IF
*
         IF( left ) THEN
            ni = n
         ELSE
            mi = m
         END IF
*
         DO 10 i = i1, i2, i3
            IF( left ) THEN
*
*              H(i) or H(i)**H is applied to C(1:i,1:n)
*
               mi = i
            ELSE
*
*              H(i) or H(i)**H is applied to C(1:m,1:i)
*
               ni = i
            END IF
*
*           Apply H(i) or H(i)**H
*
            IF( notran ) THEN
               taui = tau( i )
            ELSE
               taui = conjg( tau( i ) )
            END IF
            CALL clarf1l( side, mi, ni, ap( ii-i+1 ), 1, taui, c,
     $                    ldc, work )
*
            IF( forwrd ) THEN
               ii = ii + i + 2
            ELSE
               ii = ii - i - 1
            END IF
   10    CONTINUE
      ELSE
*
*        Q was determined by a call to CHPTRD with UPLO = 'L'.
*
         forwrd = ( left .AND. .NOT.notran ) .OR.
     $            ( .NOT.left .AND. notran )
*
         IF( forwrd ) THEN
            i1 = 1
            i2 = nq - 1
            i3 = 1
            ii = 2
         ELSE
            i1 = nq - 1
            i2 = 1
            i3 = -1
            ii = nq*( nq+1 ) / 2 - 1
         END IF
*
         IF( left ) THEN
            ni = n
            jc = 1
         ELSE
            mi = m
            ic = 1
         END IF
*
         DO 20 i = i1, i2, i3
            IF( left ) THEN
*
*              H(i) or H(i)**H is applied to C(i+1:m,1:n)
*
               mi = m - i
               ic = i + 1
            ELSE
*
*              H(i) or H(i)**H is applied to C(1:m,i+1:n)
*
               ni = n - i
               jc = i + 1
            END IF
*
*           Apply H(i) or H(i)**H
*
            IF( notran ) THEN
               taui = tau( i )
            ELSE
               taui = conjg( tau( i ) )
            END IF
            CALL clarf1f( side, mi, ni, ap( ii ), 1, taui, c( ic,
     $                    jc ), ldc, work )
*
            IF( forwrd ) THEN
               ii = ii + nq - i + 1
            ELSE
               ii = ii - nq + i - 2
            END IF
   20    CONTINUE
      END IF
      RETURN
*
*     End of CUPMTR
*

Here is the call graph for this function:

Here is the caller graph for this function: