cpotf2()

subroutine cpotf2	(	character	uplo,
		integer	n,
		complex, dimension( lda, * )	a,
		integer	lda,
		integer	info )

CPOTF2 computes the Cholesky factorization of a symmetric/Hermitian positive definite matrix (unblocked algorithm).

Download CPOTF2 + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> CPOTF2 computes the Cholesky factorization of a complex Hermitian
!> positive definite matrix A.
!>
!> The factorization has the form
!>    A = U**H * U ,  if UPLO = 'U', or
!>    A = L  * L**H,  if UPLO = 'L',
!> where U is an upper triangular matrix and L is lower triangular.
!>
!> This is the unblocked version of the algorithm, calling Level 2 BLAS.
!> 

Parameters

[in]	UPLO	!> UPLO is CHARACTER*1 !> Specifies whether the upper or lower triangular part of the !> Hermitian matrix A is stored. !> = 'U': Upper triangular !> = 'L': Lower triangular !>
[in]	N	!> N is INTEGER !> The order of the matrix A. N >= 0. !>
[in,out]	A	!> A is COMPLEX array, dimension (LDA,N) !> On entry, the Hermitian matrix A. If UPLO = 'U', the leading !> n by n upper triangular part of A contains the upper !> triangular part of the matrix A, and the strictly lower !> triangular part of A is not referenced. If UPLO = 'L', the !> leading n by n lower triangular part of A contains the lower !> triangular part of the matrix A, and the strictly upper !> triangular part of A is not referenced. !> !> On exit, if INFO = 0, the factor U or L from the Cholesky !> factorization A = U**H *U or A = L*L**H. !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the array A. LDA >= max(1,N). !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit !> < 0: if INFO = -k, the k-th argument had an illegal value !> > 0: if INFO = k, the leading principal minor of order k !> is not positive, and the factorization could not be !> completed. !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 106 of file cpotf2.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            INFO, LDA, N
*     ..
*     .. Array Arguments ..
      COMPLEX            A( LDA, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ONE, ZERO
      parameter( one = 1.0e+0, zero = 0.0e+0 )
      COMPLEX            CONE
      parameter( cone = ( 1.0e+0, 0.0e+0 ) )
*     ..
*     .. Local Scalars ..
      LOGICAL            UPPER
      INTEGER            J
      REAL               AJJ
*     ..
*     .. External Functions ..
      LOGICAL            LSAME, SISNAN
      COMPLEX            CDOTC
      EXTERNAL           lsame, cdotc, sisnan
*     ..
*     .. External Subroutines ..
      EXTERNAL           cgemv, clacgv, csscal, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, real, sqrt
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
      upper = lsame( uplo, 'U' )
      IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( lda.LT.max( 1, n ) ) THEN
         info = -4
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'CPOTF2', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 )
     $   RETURN
*
      IF( upper ) THEN
*
*        Compute the Cholesky factorization A = U**H *U.
*
         DO 10 j = 1, n
*
*           Compute U(J,J) and test for non-positive-definiteness.
*
            ajj = real( real( a( j, j ) ) - cdotc( j-1, a( 1, j ), 1,
     $            a( 1, j ), 1 ) )
            IF( ajj.LE.zero.OR.sisnan( ajj ) ) THEN
               a( j, j ) = ajj
               GO TO 30
            END IF
            ajj = sqrt( ajj )
            a( j, j ) = ajj
*
*           Compute elements J+1:N of row J.
*
            IF( j.LT.n ) THEN
               CALL clacgv( j-1, a( 1, j ), 1 )
               CALL cgemv( 'Transpose', j-1, n-j, -cone, a( 1, j+1 ),
     $                     lda, a( 1, j ), 1, cone, a( j, j+1 ), lda )
               CALL clacgv( j-1, a( 1, j ), 1 )
               CALL csscal( n-j, one / ajj, a( j, j+1 ), lda )
            END IF
   10    CONTINUE
      ELSE
*
*        Compute the Cholesky factorization A = L*L**H.
*
         DO 20 j = 1, n
*
*           Compute L(J,J) and test for non-positive-definiteness.
*
            ajj = real( real( a( j, j ) ) - cdotc( j-1, a( j, 1 ),
     $                  lda,
     $            a( j, 1 ), lda ) )
            IF( ajj.LE.zero.OR.sisnan( ajj ) ) THEN
               a( j, j ) = ajj
               GO TO 30
            END IF
            ajj = sqrt( ajj )
            a( j, j ) = ajj
*
*           Compute elements J+1:N of column J.
*
            IF( j.LT.n ) THEN
               CALL clacgv( j-1, a( j, 1 ), lda )
               CALL cgemv( 'No transpose', n-j, j-1, -cone, a( j+1,
     $                     1 ),
     $                     lda, a( j, 1 ), lda, cone, a( j+1, j ), 1 )
               CALL clacgv( j-1, a( j, 1 ), lda )
               CALL csscal( n-j, one / ajj, a( j+1, j ), 1 )
            END IF
   20    CONTINUE
      END IF
      GO TO 40
*
   30 CONTINUE
      info = j
*
   40 CONTINUE
      RETURN
*
*     End of CPOTF2
*

Here is the call graph for this function:

Here is the caller graph for this function: