zget54()

subroutine zget54	(	integer	n,
		complex*16, dimension( lda, * )	a,
		integer	lda,
		complex*16, dimension( ldb, * )	b,
		integer	ldb,
		complex*16, dimension( lds, * )	s,
		integer	lds,
		complex*16, dimension( ldt, * )	t,
		integer	ldt,
		complex*16, dimension( ldu, * )	u,
		integer	ldu,
		complex*16, dimension( ldv, * )	v,
		integer	ldv,
		complex*16, dimension( * )	work,
		double precision	result )

ZGET54

Purpose:

!>
!> ZGET54 checks a generalized decomposition of the form
!>
!>          A = U*S*V'  and B = U*T* V'
!>
!> where ' means conjugate transpose and U and V are unitary.
!>
!> Specifically,
!>
!>   RESULT = ||( A - U*S*V', B - U*T*V' )|| / (||( A, B )||*n*ulp )
!> 

Parameters

[in]	N	!> N is INTEGER !> The size of the matrix. If it is zero, DGET54 does nothing. !> It must be at least zero. !>
[in]	A	!> A is COMPLEX*16 array, dimension (LDA, N) !> The original (unfactored) matrix A. !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of A. It must be at least 1 !> and at least N. !>
[in]	B	!> B is COMPLEX*16 array, dimension (LDB, N) !> The original (unfactored) matrix B. !>
[in]	LDB	!> LDB is INTEGER !> The leading dimension of B. It must be at least 1 !> and at least N. !>
[in]	S	!> S is COMPLEX*16 array, dimension (LDS, N) !> The factored matrix S. !>
[in]	LDS	!> LDS is INTEGER !> The leading dimension of S. It must be at least 1 !> and at least N. !>
[in]	T	!> T is COMPLEX*16 array, dimension (LDT, N) !> The factored matrix T. !>
[in]	LDT	!> LDT is INTEGER !> The leading dimension of T. It must be at least 1 !> and at least N. !>
[in]	U	!> U is COMPLEX*16 array, dimension (LDU, N) !> The orthogonal matrix on the left-hand side in the !> decomposition. !>
[in]	LDU	!> LDU is INTEGER !> The leading dimension of U. LDU must be at least N and !> at least 1. !>
[in]	V	!> V is COMPLEX*16 array, dimension (LDV, N) !> The orthogonal matrix on the left-hand side in the !> decomposition. !>
[in]	LDV	!> LDV is INTEGER !> The leading dimension of V. LDV must be at least N and !> at least 1. !>
[out]	WORK	!> WORK is COMPLEX*16 array, dimension (3*N**2) !>
[out]	RESULT	!> RESULT is DOUBLE PRECISION !> The value RESULT, It is currently limited to 1/ulp, to !> avoid overflow. Errors are flagged by RESULT=10/ulp. !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 154 of file zget54.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            LDA, LDB, LDS, LDT, LDU, LDV, N
      DOUBLE PRECISION   RESULT
*     ..
*     .. Array Arguments ..
      COMPLEX*16         A( LDA, * ), B( LDB, * ), S( LDS, * ),
     $                   T( LDT, * ), U( LDU, * ), V( LDV, * ),
     $                   WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO, ONE
      parameter( zero = 0.0d+0, one = 1.0d+0 )
      COMPLEX*16         CZERO, CONE
      parameter( czero = ( 0.0d+0, 0.0d+0 ),
     $                   cone = ( 1.0d+0, 0.0d+0 ) )
*     ..
*     .. Local Scalars ..
      DOUBLE PRECISION   ABNORM, ULP, UNFL, WNORM
*     ..
*     .. Local Arrays ..
      DOUBLE PRECISION   DUM( 1 )
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   DLAMCH, ZLANGE
      EXTERNAL           dlamch, zlange
*     ..
*     .. External Subroutines ..
      EXTERNAL           zgemm, zlacpy
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble, max, min
*     ..
*     .. Executable Statements ..
*
      result = zero
      IF( n.LE.0 )
     $   RETURN
*
*     Constants
*
      unfl = dlamch( 'Safe minimum' )
      ulp = dlamch( 'Epsilon' )*dlamch( 'Base' )
*
*     compute the norm of (A,B)
*
      CALL zlacpy( 'Full', n, n, a, lda, work, n )
      CALL zlacpy( 'Full', n, n, b, ldb, work( n*n+1 ), n )
      abnorm = max( zlange( '1', n, 2*n, work, n, dum ), unfl )
*
*     Compute W1 = A - U*S*V', and put in the array WORK(1:N*N)
*
      CALL zlacpy( ' ', n, n, a, lda, work, n )
      CALL zgemm( 'N', 'N', n, n, n, cone, u, ldu, s, lds, czero,
     $            work( n*n+1 ), n )
*
      CALL zgemm( 'N', 'C', n, n, n, -cone, work( n*n+1 ), n, v, ldv,
     $            cone, work, n )
*
*     Compute W2 = B - U*T*V', and put in the workarray W(N*N+1:2*N*N)
*
      CALL zlacpy( ' ', n, n, b, ldb, work( n*n+1 ), n )
      CALL zgemm( 'N', 'N', n, n, n, cone, u, ldu, t, ldt, czero,
     $            work( 2*n*n+1 ), n )
*
      CALL zgemm( 'N', 'C', n, n, n, -cone, work( 2*n*n+1 ), n, v, ldv,
     $            cone, work( n*n+1 ), n )
*
*     Compute norm(W)/ ( ulp*norm((A,B)) )
*
      wnorm = zlange( '1', n, 2*n, work, n, dum )
*
      IF( abnorm.GT.wnorm ) THEN
         result = ( wnorm / abnorm ) / ( 2*n*ulp )
      ELSE
         IF( abnorm.LT.one ) THEN
            result = ( min( wnorm, 2*n*abnorm ) / abnorm ) / ( 2*n*ulp )
         ELSE
            result = min( wnorm / abnorm, dble( 2*n ) ) / ( 2*n*ulp )
         END IF
      END IF
*
      RETURN
*
*     End of ZGET54
*

Here is the call graph for this function:

Here is the caller graph for this function: