zlatrs()

subroutine zlatrs	(	character	uplo,
		character	trans,
		character	diag,
		character	normin,
		integer	n,
		complex*16, dimension( lda, * )	a,
		integer	lda,
		complex*16, dimension( * )	x,
		double precision	scale,
		double precision, dimension( * )	cnorm,
		integer	info )

ZLATRS solves a triangular system of equations with the scale factor set to prevent overflow.

Download ZLATRS + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> ZLATRS solves one of the triangular systems
!>
!>    A * x = s*b,  A**T * x = s*b,  or  A**H * x = s*b,
!>
!> with scaling to prevent overflow.  Here A is an upper or lower
!> triangular matrix, A**T denotes the transpose of A, A**H denotes the
!> conjugate transpose of A, x and b are n-element vectors, and s is a
!> scaling factor, usually less than or equal to 1, chosen so that the
!> components of x will be less than the overflow threshold.  If the
!> unscaled problem will not cause overflow, the Level 2 BLAS routine
!> ZTRSV is called. If the matrix A is singular (A(j,j) = 0 for some j),
!> then s is set to 0 and a non-trivial solution to A*x = 0 is returned.
!> 

Parameters

[in]	UPLO	!> UPLO is CHARACTER*1 !> Specifies whether the matrix A is upper or lower triangular. !> = 'U': Upper triangular !> = 'L': Lower triangular !>
[in]	TRANS	!> TRANS is CHARACTER*1 !> Specifies the operation applied to A. !> = 'N': Solve A * x = s*b (No transpose) !> = 'T': Solve A**T * x = s*b (Transpose) !> = 'C': Solve A**H * x = s*b (Conjugate transpose) !>
[in]	DIAG	!> DIAG is CHARACTER*1 !> Specifies whether or not the matrix A is unit triangular. !> = 'N': Non-unit triangular !> = 'U': Unit triangular !>
[in]	NORMIN	!> NORMIN is CHARACTER*1 !> Specifies whether CNORM has been set or not. !> = 'Y': CNORM contains the column norms on entry !> = 'N': CNORM is not set on entry. On exit, the norms will !> be computed and stored in CNORM. !>
[in]	N	!> N is INTEGER !> The order of the matrix A. N >= 0. !>
[in]	A	!> A is COMPLEX*16 array, dimension (LDA,N) !> The triangular matrix A. If UPLO = 'U', the leading n by n !> upper triangular part of the array A contains the upper !> triangular matrix, and the strictly lower triangular part of !> A is not referenced. If UPLO = 'L', the leading n by n lower !> triangular part of the array A contains the lower triangular !> matrix, and the strictly upper triangular part of A is not !> referenced. If DIAG = 'U', the diagonal elements of A are !> also not referenced and are assumed to be 1. !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the array A. LDA >= max (1,N). !>
[in,out]	X	!> X is COMPLEX*16 array, dimension (N) !> On entry, the right hand side b of the triangular system. !> On exit, X is overwritten by the solution vector x. !>
[out]	SCALE	!> SCALE is DOUBLE PRECISION !> The scaling factor s for the triangular system !> A * x = s*b, A**T * x = s*b, or A**H * x = s*b. !> If SCALE = 0, the matrix A is singular or badly scaled, and !> the vector x is an exact or approximate solution to A*x = 0. !>
[in,out]	CNORM	!> CNORM is DOUBLE PRECISION array, dimension (N) !> !> If NORMIN = 'Y', CNORM is an input argument and CNORM(j) !> contains the norm of the off-diagonal part of the j-th column !> of A. If TRANS = 'N', CNORM(j) must be greater than or equal !> to the infinity-norm, and if TRANS = 'T' or 'C', CNORM(j) !> must be greater than or equal to the 1-norm. !> !> If NORMIN = 'N', CNORM is an output argument and CNORM(j) !> returns the 1-norm of the offdiagonal part of the j-th column !> of A. !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit !> < 0: if INFO = -k, the k-th argument had an illegal value !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Further Details:

!>
!>  A rough bound on x is computed; if that is less than overflow, ZTRSV
!>  is called, otherwise, specific code is used which checks for possible
!>  overflow or divide-by-zero at every operation.
!>
!>  A columnwise scheme is used for solving A*x = b.  The basic algorithm
!>  if A is lower triangular is
!>
!>       x[1:n] := b[1:n]
!>       for j = 1, ..., n
!>            x(j) := x(j) / A(j,j)
!>            x[j+1:n] := x[j+1:n] - x(j) * A[j+1:n,j]
!>       end
!>
!>  Define bounds on the components of x after j iterations of the loop:
!>     M(j) = bound on x[1:j]
!>     G(j) = bound on x[j+1:n]
!>  Initially, let M(0) = 0 and G(0) = max{x(i), i=1,...,n}.
!>
!>  Then for iteration j+1 we have
!>     M(j+1) <= G(j) / | A(j+1,j+1) |
!>     G(j+1) <= G(j) + M(j+1) * | A[j+2:n,j+1] |
!>            <= G(j) ( 1 + CNORM(j+1) / | A(j+1,j+1) | )
!>
!>  where CNORM(j+1) is greater than or equal to the infinity-norm of
!>  column j+1 of A, not counting the diagonal.  Hence
!>
!>     G(j) <= G(0) product ( 1 + CNORM(i) / | A(i,i) | )
!>                  1<=i<=j
!>  and
!>
!>     |x(j)| <= ( G(0) / |A(j,j)| ) product ( 1 + CNORM(i) / |A(i,i)| )
!>                                   1<=i< j
!>
!>  Since |x(j)| <= M(j), we use the Level 2 BLAS routine ZTRSV if the
!>  reciprocal of the largest M(j), j=1,..,n, is larger than
!>  max(underflow, 1/overflow).
!>
!>  The bound on x(j) is also used to determine when a step in the
!>  columnwise method can be performed without fear of overflow.  If
!>  the computed bound is greater than a large constant, x is scaled to
!>  prevent overflow, but if the bound overflows, x is set to 0, x(j) to
!>  1, and scale to 0, and a non-trivial solution to A*x = 0 is found.
!>
!>  Similarly, a row-wise scheme is used to solve A**T *x = b  or
!>  A**H *x = b.  The basic algorithm for A upper triangular is
!>
!>       for j = 1, ..., n
!>            x(j) := ( b(j) - A[1:j-1,j]' * x[1:j-1] ) / A(j,j)
!>       end
!>
!>  We simultaneously compute two bounds
!>       G(j) = bound on ( b(i) - A[1:i-1,i]' * x[1:i-1] ), 1<=i<=j
!>       M(j) = bound on x(i), 1<=i<=j
!>
!>  The initial values are G(0) = 0, M(0) = max{b(i), i=1,..,n}, and we
!>  add the constraint G(j) >= G(j-1) and M(j) >= M(j-1) for j >= 1.
!>  Then the bound on x(j) is
!>
!>       M(j) <= M(j-1) * ( 1 + CNORM(j) ) / | A(j,j) |
!>
!>            <= M(0) * product ( ( 1 + CNORM(i) ) / |A(i,i)| )
!>                      1<=i<=j
!>
!>  and we can safely call ZTRSV if 1/M(n) and 1/G(n) are both greater
!>  than max(underflow, 1/overflow).
!> 

Definition at line 235 of file zlatrs.f.

*
*  -- LAPACK auxiliary routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          DIAG, NORMIN, TRANS, UPLO
      INTEGER            INFO, LDA, N
      DOUBLE PRECISION   SCALE
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   CNORM( * )
      COMPLEX*16         A( LDA, * ), X( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO, HALF, ONE, TWO
      parameter( zero = 0.0d+0, half = 0.5d+0, one = 1.0d+0,
     $                   two = 2.0d+0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            NOTRAN, NOUNIT, UPPER
      INTEGER            I, IMAX, J, JFIRST, JINC, JLAST
      DOUBLE PRECISION   BIGNUM, GROW, REC, SMLNUM, TJJ, TMAX, TSCAL,
     $                   XBND, XJ, XMAX
      COMPLEX*16         CSUMJ, TJJS, USCAL, ZDUM
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      INTEGER            IDAMAX, IZAMAX
      DOUBLE PRECISION   DLAMCH, DZASUM
      COMPLEX*16         ZDOTC, ZDOTU, ZLADIV
      EXTERNAL           lsame, idamax, izamax, dlamch, dzasum,
     $                   zdotc,
     $                   zdotu, zladiv
*     ..
*     .. External Subroutines ..
      EXTERNAL           dscal, xerbla, zaxpy, zdscal, ztrsv
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, dble, dcmplx, dconjg, dimag, max, min
*     ..
*     .. Statement Functions ..
      DOUBLE PRECISION   CABS1, CABS2
*     ..
*     .. Statement Function definitions ..
      cabs1( zdum ) = abs( dble( zdum ) ) + abs( dimag( zdum ) )
      cabs2( zdum ) = abs( dble( zdum ) / 2.d0 ) +
     $                abs( dimag( zdum ) / 2.d0 )
*     ..
*     .. Executable Statements ..
*
      info = 0
      upper = lsame( uplo, 'U' )
      notran = lsame( trans, 'N' )
      nounit = lsame( diag, 'N' )
*
*     Test the input parameters.
*
      IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
         info = -1
      ELSE IF( .NOT.notran .AND. .NOT.lsame( trans, 'T' ) .AND. .NOT.
     $         lsame( trans, 'C' ) ) THEN
         info = -2
      ELSE IF( .NOT.nounit .AND. .NOT.lsame( diag, 'U' ) ) THEN
         info = -3
      ELSE IF( .NOT.lsame( normin, 'Y' ) .AND. .NOT.
     $         lsame( normin, 'N' ) ) THEN
         info = -4
      ELSE IF( n.LT.0 ) THEN
         info = -5
      ELSE IF( lda.LT.max( 1, n ) ) THEN
         info = -7
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'ZLATRS', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      scale = one
      IF( n.EQ.0 )
     $   RETURN
*
*     Determine machine dependent parameters to control overflow.
*
      smlnum = dlamch( 'Safe minimum' ) / dlamch( 'Precision' )
      bignum = one / smlnum
*
      IF( lsame( normin, 'N' ) ) THEN
*
*        Compute the 1-norm of each column, not including the diagonal.
*
         IF( upper ) THEN
*
*           A is upper triangular.
*
            DO 10 j = 1, n
               cnorm( j ) = dzasum( j-1, a( 1, j ), 1 )
   10       CONTINUE
         ELSE
*
*           A is lower triangular.
*
            DO 20 j = 1, n - 1
               cnorm( j ) = dzasum( n-j, a( j+1, j ), 1 )
   20       CONTINUE
            cnorm( n ) = zero
         END IF
      END IF
*
*     Scale the column norms by TSCAL if the maximum element in CNORM is
*     greater than BIGNUM/2.
*
      imax = idamax( n, cnorm, 1 )
      tmax = cnorm( imax )
      IF( tmax.LE.bignum*half ) THEN
         tscal = one
      ELSE
*
*        Avoid NaN generation if entries in CNORM exceed the
*        overflow threshold
*
         IF ( tmax.LE.dlamch('Overflow') ) THEN
*           Case 1: All entries in CNORM are valid floating-point numbers
            tscal = half / ( smlnum*tmax )
            CALL dscal( n, tscal, cnorm, 1 )
         ELSE
*           Case 2: At least one column norm of A cannot be
*           represented as a floating-point number. Find the
*           maximum offdiagonal absolute value
*           max( |Re(A(I,J))|, |Im(A(I,J)| ). If this entry is
*           not +/- Infinity, use this value as TSCAL.
            tmax = zero
            IF( upper ) THEN
*
*              A is upper triangular.
*
               DO j = 2, n
                  DO i = 1, j - 1
                     tmax = max( tmax, abs( dble( a( i, j ) ) ),
     $                           abs( dimag(a( i, j ) ) ) )
                  END DO
               END DO
            ELSE
*
*              A is lower triangular.
*
               DO j = 1, n - 1
                  DO i = j + 1, n
                     tmax = max( tmax, abs( dble( a( i, j ) ) ),
     $                           abs( dimag(a( i, j ) ) ) )
                  END DO
               END DO
            END IF
*
            IF( tmax.LE.dlamch('Overflow') ) THEN
               tscal = one / ( smlnum*tmax )
               DO j = 1, n
                  IF( cnorm( j ).LE.dlamch('Overflow') ) THEN
                     cnorm( j ) = cnorm( j )*tscal
                  ELSE
*                    Recompute the 1-norm of each column without
*                    introducing Infinity in the summation.
                     tscal = two * tscal
                     cnorm( j ) = zero
                     IF( upper ) THEN
                        DO i = 1, j - 1
                           cnorm( j ) = cnorm( j ) +
     $                                  tscal * cabs2( a( i, j ) )
                        END DO
                     ELSE
                        DO i = j + 1, n
                           cnorm( j ) = cnorm( j ) +
     $                                  tscal * cabs2( a( i, j ) )
                        END DO
                     END IF
                     tscal = tscal * half
                  END IF
               END DO
            ELSE
*              At least one entry of A is not a valid floating-point
*              entry. Rely on TRSV to propagate Inf and NaN.
               CALL ztrsv( uplo, trans, diag, n, a, lda, x, 1 )
               RETURN
            END IF
         END IF
      END IF
*
*     Compute a bound on the computed solution vector to see if the
*     Level 2 BLAS routine ZTRSV can be used.
*
      xmax = zero
      DO 30 j = 1, n
         xmax = max( xmax, cabs2( x( j ) ) )
   30 CONTINUE
      xbnd = xmax
*
      IF( notran ) THEN
*
*        Compute the growth in A * x = b.
*
         IF( upper ) THEN
            jfirst = n
            jlast = 1
            jinc = -1
         ELSE
            jfirst = 1
            jlast = n
            jinc = 1
         END IF
*
         IF( tscal.NE.one ) THEN
            grow = zero
            GO TO 60
         END IF
*
         IF( nounit ) THEN
*
*           A is non-unit triangular.
*
*           Compute GROW = 1/G(j) and XBND = 1/M(j).
*           Initially, G(0) = max{x(i), i=1,...,n}.
*
            grow = half / max( xbnd, smlnum )
            xbnd = grow
            DO 40 j = jfirst, jlast, jinc
*
*              Exit the loop if the growth factor is too small.
*
               IF( grow.LE.smlnum )
     $            GO TO 60
*
               tjjs = a( j, j )
               tjj = cabs1( tjjs )
*
               IF( tjj.GE.smlnum ) THEN
*
*                 M(j) = G(j-1) / abs(A(j,j))
*
                  xbnd = min( xbnd, min( one, tjj )*grow )
               ELSE
*
*                 M(j) could overflow, set XBND to 0.
*
                  xbnd = zero
               END IF
*
               IF( tjj+cnorm( j ).GE.smlnum ) THEN
*
*                 G(j) = G(j-1)*( 1 + CNORM(j) / abs(A(j,j)) )
*
                  grow = grow*( tjj / ( tjj+cnorm( j ) ) )
               ELSE
*
*                 G(j) could overflow, set GROW to 0.
*
                  grow = zero
               END IF
   40       CONTINUE
            grow = xbnd
         ELSE
*
*           A is unit triangular.
*
*           Compute GROW = 1/G(j), where G(0) = max{x(i), i=1,...,n}.
*
            grow = min( one, half / max( xbnd, smlnum ) )
            DO 50 j = jfirst, jlast, jinc
*
*              Exit the loop if the growth factor is too small.
*
               IF( grow.LE.smlnum )
     $            GO TO 60
*
*              G(j) = G(j-1)*( 1 + CNORM(j) )
*
               grow = grow*( one / ( one+cnorm( j ) ) )
   50       CONTINUE
         END IF
   60    CONTINUE
*
      ELSE
*
*        Compute the growth in A**T * x = b  or  A**H * x = b.
*
         IF( upper ) THEN
            jfirst = 1
            jlast = n
            jinc = 1
         ELSE
            jfirst = n
            jlast = 1
            jinc = -1
         END IF
*
         IF( tscal.NE.one ) THEN
            grow = zero
            GO TO 90
         END IF
*
         IF( nounit ) THEN
*
*           A is non-unit triangular.
*
*           Compute GROW = 1/G(j) and XBND = 1/M(j).
*           Initially, M(0) = max{x(i), i=1,...,n}.
*
            grow = half / max( xbnd, smlnum )
            xbnd = grow
            DO 70 j = jfirst, jlast, jinc
*
*              Exit the loop if the growth factor is too small.
*
               IF( grow.LE.smlnum )
     $            GO TO 90
*
*              G(j) = max( G(j-1), M(j-1)*( 1 + CNORM(j) ) )
*
               xj = one + cnorm( j )
               grow = min( grow, xbnd / xj )
*
               tjjs = a( j, j )
               tjj = cabs1( tjjs )
*
               IF( tjj.GE.smlnum ) THEN
*
*                 M(j) = M(j-1)*( 1 + CNORM(j) ) / abs(A(j,j))
*
                  IF( xj.GT.tjj )
     $               xbnd = xbnd*( tjj / xj )
               ELSE
*
*                 M(j) could overflow, set XBND to 0.
*
                  xbnd = zero
               END IF
   70       CONTINUE
            grow = min( grow, xbnd )
         ELSE
*
*           A is unit triangular.
*
*           Compute GROW = 1/G(j), where G(0) = max{x(i), i=1,...,n}.
*
            grow = min( one, half / max( xbnd, smlnum ) )
            DO 80 j = jfirst, jlast, jinc
*
*              Exit the loop if the growth factor is too small.
*
               IF( grow.LE.smlnum )
     $            GO TO 90
*
*              G(j) = ( 1 + CNORM(j) )*G(j-1)
*
               xj = one + cnorm( j )
               grow = grow / xj
   80       CONTINUE
         END IF
   90    CONTINUE
      END IF
*
      IF( ( grow*tscal ).GT.smlnum ) THEN
*
*        Use the Level 2 BLAS solve if the reciprocal of the bound on
*        elements of X is not too small.
*
         CALL ztrsv( uplo, trans, diag, n, a, lda, x, 1 )
      ELSE
*
*        Use a Level 1 BLAS solve, scaling intermediate results.
*
         IF( xmax.GT.bignum*half ) THEN
*
*           Scale X so that its components are less than or equal to
*           BIGNUM in absolute value.
*
            scale = ( bignum*half ) / xmax
            CALL zdscal( n, scale, x, 1 )
            xmax = bignum
         ELSE
            xmax = xmax*two
         END IF
*
         IF( notran ) THEN
*
*           Solve A * x = b
*
            DO 120 j = jfirst, jlast, jinc
*
*              Compute x(j) = b(j) / A(j,j), scaling x if necessary.
*
               xj = cabs1( x( j ) )
               IF( nounit ) THEN
                  tjjs = a( j, j )*tscal
               ELSE
                  tjjs = tscal
                  IF( tscal.EQ.one )
     $               GO TO 110
               END IF
               tjj = cabs1( tjjs )
               IF( tjj.GT.smlnum ) THEN
*
*                    abs(A(j,j)) > SMLNUM:
*
                  IF( tjj.LT.one ) THEN
                     IF( xj.GT.tjj*bignum ) THEN
*
*                          Scale x by 1/b(j).
*
                        rec = one / xj
                        CALL zdscal( n, rec, x, 1 )
                        scale = scale*rec
                        xmax = xmax*rec
                     END IF
                  END IF
                  x( j ) = zladiv( x( j ), tjjs )
                  xj = cabs1( x( j ) )
               ELSE IF( tjj.GT.zero ) THEN
*
*                    0 < abs(A(j,j)) <= SMLNUM:
*
                  IF( xj.GT.tjj*bignum ) THEN
*
*                       Scale x by (1/abs(x(j)))*abs(A(j,j))*BIGNUM
*                       to avoid overflow when dividing by A(j,j).
*
                     rec = ( tjj*bignum ) / xj
                     IF( cnorm( j ).GT.one ) THEN
*
*                          Scale by 1/CNORM(j) to avoid overflow when
*                          multiplying x(j) times column j.
*
                        rec = rec / cnorm( j )
                     END IF
                     CALL zdscal( n, rec, x, 1 )
                     scale = scale*rec
                     xmax = xmax*rec
                  END IF
                  x( j ) = zladiv( x( j ), tjjs )
                  xj = cabs1( x( j ) )
               ELSE
*
*                    A(j,j) = 0:  Set x(1:n) = 0, x(j) = 1, and
*                    scale = 0, and compute a solution to A*x = 0.
*
                  DO 100 i = 1, n
                     x( i ) = zero
  100             CONTINUE
                  x( j ) = one
                  xj = one
                  scale = zero
                  xmax = zero
               END IF
  110          CONTINUE
*
*              Scale x if necessary to avoid overflow when adding a
*              multiple of column j of A.
*
               IF( xj.GT.one ) THEN
                  rec = one / xj
                  IF( cnorm( j ).GT.( bignum-xmax )*rec ) THEN
*
*                    Scale x by 1/(2*abs(x(j))).
*
                     rec = rec*half
                     CALL zdscal( n, rec, x, 1 )
                     scale = scale*rec
                  END IF
               ELSE IF( xj*cnorm( j ).GT.( bignum-xmax ) ) THEN
*
*                 Scale x by 1/2.
*
                  CALL zdscal( n, half, x, 1 )
                  scale = scale*half
               END IF
*
               IF( upper ) THEN
                  IF( j.GT.1 ) THEN
*
*                    Compute the update
*                       x(1:j-1) := x(1:j-1) - x(j) * A(1:j-1,j)
*
                     CALL zaxpy( j-1, -x( j )*tscal, a( 1, j ), 1, x,
     $                           1 )
                     i = izamax( j-1, x, 1 )
                     xmax = cabs1( x( i ) )
                  END IF
               ELSE
                  IF( j.LT.n ) THEN
*
*                    Compute the update
*                       x(j+1:n) := x(j+1:n) - x(j) * A(j+1:n,j)
*
                     CALL zaxpy( n-j, -x( j )*tscal, a( j+1, j ), 1,
     $                           x( j+1 ), 1 )
                     i = j + izamax( n-j, x( j+1 ), 1 )
                     xmax = cabs1( x( i ) )
                  END IF
               END IF
  120       CONTINUE
*
         ELSE IF( lsame( trans, 'T' ) ) THEN
*
*           Solve A**T * x = b
*
            DO 170 j = jfirst, jlast, jinc
*
*              Compute x(j) = b(j) - sum A(k,j)*x(k).
*                                    k<>j
*
               xj = cabs1( x( j ) )
               uscal = tscal
               rec = one / max( xmax, one )
               IF( cnorm( j ).GT.( bignum-xj )*rec ) THEN
*
*                 If x(j) could overflow, scale x by 1/(2*XMAX).
*
                  rec = rec*half
                  IF( nounit ) THEN
                     tjjs = a( j, j )*tscal
                  ELSE
                     tjjs = tscal
                  END IF
                  tjj = cabs1( tjjs )
                  IF( tjj.GT.one ) THEN
*
*                       Divide by A(j,j) when scaling x if A(j,j) > 1.
*
                     rec = min( one, rec*tjj )
                     uscal = zladiv( uscal, tjjs )
                  END IF
                  IF( rec.LT.one ) THEN
                     CALL zdscal( n, rec, x, 1 )
                     scale = scale*rec
                     xmax = xmax*rec
                  END IF
               END IF
*
               csumj = zero
               IF( uscal.EQ.dcmplx( one ) ) THEN
*
*                 If the scaling needed for A in the dot product is 1,
*                 call ZDOTU to perform the dot product.
*
                  IF( upper ) THEN
                     csumj = zdotu( j-1, a( 1, j ), 1, x, 1 )
                  ELSE IF( j.LT.n ) THEN
                     csumj = zdotu( n-j, a( j+1, j ), 1, x( j+1 ),
     $                              1 )
                  END IF
               ELSE
*
*                 Otherwise, use in-line code for the dot product.
*
                  IF( upper ) THEN
                     DO 130 i = 1, j - 1
                        csumj = csumj + ( a( i, j )*uscal )*x( i )
  130                CONTINUE
                  ELSE IF( j.LT.n ) THEN
                     DO 140 i = j + 1, n
                        csumj = csumj + ( a( i, j )*uscal )*x( i )
  140                CONTINUE
                  END IF
               END IF
*
               IF( uscal.EQ.dcmplx( tscal ) ) THEN
*
*                 Compute x(j) := ( x(j) - CSUMJ ) / A(j,j) if 1/A(j,j)
*                 was not used to scale the dotproduct.
*
                  x( j ) = x( j ) - csumj
                  xj = cabs1( x( j ) )
                  IF( nounit ) THEN
                     tjjs = a( j, j )*tscal
                  ELSE
                     tjjs = tscal
                     IF( tscal.EQ.one )
     $                  GO TO 160
                  END IF
*
*                    Compute x(j) = x(j) / A(j,j), scaling if necessary.
*
                  tjj = cabs1( tjjs )
                  IF( tjj.GT.smlnum ) THEN
*
*                       abs(A(j,j)) > SMLNUM:
*
                     IF( tjj.LT.one ) THEN
                        IF( xj.GT.tjj*bignum ) THEN
*
*                             Scale X by 1/abs(x(j)).
*
                           rec = one / xj
                           CALL zdscal( n, rec, x, 1 )
                           scale = scale*rec
                           xmax = xmax*rec
                        END IF
                     END IF
                     x( j ) = zladiv( x( j ), tjjs )
                  ELSE IF( tjj.GT.zero ) THEN
*
*                       0 < abs(A(j,j)) <= SMLNUM:
*
                     IF( xj.GT.tjj*bignum ) THEN
*
*                          Scale x by (1/abs(x(j)))*abs(A(j,j))*BIGNUM.
*
                        rec = ( tjj*bignum ) / xj
                        CALL zdscal( n, rec, x, 1 )
                        scale = scale*rec
                        xmax = xmax*rec
                     END IF
                     x( j ) = zladiv( x( j ), tjjs )
                  ELSE
*
*                       A(j,j) = 0:  Set x(1:n) = 0, x(j) = 1, and
*                       scale = 0 and compute a solution to A**T *x = 0.
*
                     DO 150 i = 1, n
                        x( i ) = zero
  150                CONTINUE
                     x( j ) = one
                     scale = zero
                     xmax = zero
                  END IF
  160             CONTINUE
               ELSE
*
*                 Compute x(j) := x(j) / A(j,j) - CSUMJ if the dot
*                 product has already been divided by 1/A(j,j).
*
                  x( j ) = zladiv( x( j ), tjjs ) - csumj
               END IF
               xmax = max( xmax, cabs1( x( j ) ) )
  170       CONTINUE
*
         ELSE
*
*           Solve A**H * x = b
*
            DO 220 j = jfirst, jlast, jinc
*
*              Compute x(j) = b(j) - sum A(k,j)*x(k).
*                                    k<>j
*
               xj = cabs1( x( j ) )
               uscal = tscal
               rec = one / max( xmax, one )
               IF( cnorm( j ).GT.( bignum-xj )*rec ) THEN
*
*                 If x(j) could overflow, scale x by 1/(2*XMAX).
*
                  rec = rec*half
                  IF( nounit ) THEN
                     tjjs = dconjg( a( j, j ) )*tscal
                  ELSE
                     tjjs = tscal
                  END IF
                  tjj = cabs1( tjjs )
                  IF( tjj.GT.one ) THEN
*
*                       Divide by A(j,j) when scaling x if A(j,j) > 1.
*
                     rec = min( one, rec*tjj )
                     uscal = zladiv( uscal, tjjs )
                  END IF
                  IF( rec.LT.one ) THEN
                     CALL zdscal( n, rec, x, 1 )
                     scale = scale*rec
                     xmax = xmax*rec
                  END IF
               END IF
*
               csumj = zero
               IF( uscal.EQ.dcmplx( one ) ) THEN
*
*                 If the scaling needed for A in the dot product is 1,
*                 call ZDOTC to perform the dot product.
*
                  IF( upper ) THEN
                     csumj = zdotc( j-1, a( 1, j ), 1, x, 1 )
                  ELSE IF( j.LT.n ) THEN
                     csumj = zdotc( n-j, a( j+1, j ), 1, x( j+1 ),
     $                              1 )
                  END IF
               ELSE
*
*                 Otherwise, use in-line code for the dot product.
*
                  IF( upper ) THEN
                     DO 180 i = 1, j - 1
                        csumj = csumj + ( dconjg( a( i, j ) )*uscal )*
     $                          x( i )
  180                CONTINUE
                  ELSE IF( j.LT.n ) THEN
                     DO 190 i = j + 1, n
                        csumj = csumj + ( dconjg( a( i, j ) )*uscal )*
     $                          x( i )
  190                CONTINUE
                  END IF
               END IF
*
               IF( uscal.EQ.dcmplx( tscal ) ) THEN
*
*                 Compute x(j) := ( x(j) - CSUMJ ) / A(j,j) if 1/A(j,j)
*                 was not used to scale the dotproduct.
*
                  x( j ) = x( j ) - csumj
                  xj = cabs1( x( j ) )
                  IF( nounit ) THEN
                     tjjs = dconjg( a( j, j ) )*tscal
                  ELSE
                     tjjs = tscal
                     IF( tscal.EQ.one )
     $                  GO TO 210
                  END IF
*
*                    Compute x(j) = x(j) / A(j,j), scaling if necessary.
*
                  tjj = cabs1( tjjs )
                  IF( tjj.GT.smlnum ) THEN
*
*                       abs(A(j,j)) > SMLNUM:
*
                     IF( tjj.LT.one ) THEN
                        IF( xj.GT.tjj*bignum ) THEN
*
*                             Scale X by 1/abs(x(j)).
*
                           rec = one / xj
                           CALL zdscal( n, rec, x, 1 )
                           scale = scale*rec
                           xmax = xmax*rec
                        END IF
                     END IF
                     x( j ) = zladiv( x( j ), tjjs )
                  ELSE IF( tjj.GT.zero ) THEN
*
*                       0 < abs(A(j,j)) <= SMLNUM:
*
                     IF( xj.GT.tjj*bignum ) THEN
*
*                          Scale x by (1/abs(x(j)))*abs(A(j,j))*BIGNUM.
*
                        rec = ( tjj*bignum ) / xj
                        CALL zdscal( n, rec, x, 1 )
                        scale = scale*rec
                        xmax = xmax*rec
                     END IF
                     x( j ) = zladiv( x( j ), tjjs )
                  ELSE
*
*                       A(j,j) = 0:  Set x(1:n) = 0, x(j) = 1, and
*                       scale = 0 and compute a solution to A**H *x = 0.
*
                     DO 200 i = 1, n
                        x( i ) = zero
  200                CONTINUE
                     x( j ) = one
                     scale = zero
                     xmax = zero
                  END IF
  210             CONTINUE
               ELSE
*
*                 Compute x(j) := x(j) / A(j,j) - CSUMJ if the dot
*                 product has already been divided by 1/A(j,j).
*
                  x( j ) = zladiv( x( j ), tjjs ) - csumj
               END IF
               xmax = max( xmax, cabs1( x( j ) ) )
  220       CONTINUE
         END IF
         scale = scale / tscal
      END IF
*
*     Scale the column norms by 1/TSCAL for return.
*
      IF( tscal.NE.one ) THEN
         CALL dscal( n, one / tscal, cnorm, 1 )
      END IF
*
      RETURN
*
*     End of ZLATRS
*

Here is the call graph for this function:

Here is the caller graph for this function: