zdotu()

complex*16 function zdotu	(	integer	n,
		complex*16, dimension(*)	zx,
		integer	incx,
		complex*16, dimension(*)	zy,
		integer	incy )

ZDOTU

Purpose:

!>
!> ZDOTU forms the dot product of two complex vectors
!>      ZDOTU = X^T * Y
!>
!> 

Parameters

[in]	N	!> N is INTEGER !> number of elements in input vector(s) !>
[in]	ZX	!> ZX is COMPLEX*16 array, dimension ( 1 + ( N - 1 )*abs( INCX ) ) !>
[in]	INCX	!> INCX is INTEGER !> storage spacing between elements of ZX !>
[in]	ZY	!> ZY is COMPLEX*16 array, dimension ( 1 + ( N - 1 )*abs( INCY ) ) !>
[in]	INCY	!> INCY is INTEGER !> storage spacing between elements of ZY !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Further Details:

!>
!>     jack dongarra, 3/11/78.
!>     modified 12/3/93, array(1) declarations changed to array(*)
!> 

Definition at line 82 of file zdotu.f.

*
*  -- Reference BLAS level1 routine --
*  -- Reference BLAS is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER INCX,INCY,N
*     ..
*     .. Array Arguments ..
      COMPLEX*16 ZX(*),ZY(*)
*     ..
*
*  =====================================================================
*
*     .. Local Scalars ..
      COMPLEX*16 ZTEMP
      INTEGER I,IX,IY
*     ..
      ztemp = (0.0d0,0.0d0)
      zdotu = (0.0d0,0.0d0)
      IF (n.LE.0) RETURN
      IF (incx.EQ.1 .AND. incy.EQ.1) THEN
*
*        code for both increments equal to 1
*
         DO i = 1,n
            ztemp = ztemp + zx(i)*zy(i)
         END DO
      ELSE
*
*        code for unequal increments or equal increments
*          not equal to 1
*
         ix = 1
         iy = 1
         IF (incx.LT.0) ix = (-n+1)*incx + 1
         IF (incy.LT.0) iy = (-n+1)*incy + 1
         DO i = 1,n
            ztemp = ztemp + zx(ix)*zy(iy)
            ix = ix + incx
            iy = iy + incy
         END DO
      END IF
      zdotu = ztemp
      RETURN
*
*     End of ZDOTU
*

Here is the call graph for this function:

Here is the caller graph for this function: