LAPACK 3.12.1
LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches

◆ sormrz()

subroutine sormrz ( character side,
character trans,
integer m,
integer n,
integer k,
integer l,
real, dimension( lda, * ) a,
integer lda,
real, dimension( * ) tau,
real, dimension( ldc, * ) c,
integer ldc,
real, dimension( * ) work,
integer lwork,
integer info )

SORMRZ

Download SORMRZ + dependencies [TGZ] [ZIP] [TXT]

Purpose:
!>
!> SORMRZ overwrites the general real M-by-N matrix C with
!>
!>                 SIDE = 'L'     SIDE = 'R'
!> TRANS = 'N':      Q * C          C * Q
!> TRANS = 'T':      Q**T * C       C * Q**T
!>
!> where Q is a real orthogonal matrix defined as the product of k
!> elementary reflectors
!>
!>       Q = H(1) H(2) . . . H(k)
!>
!> as returned by STZRZF. Q is of order M if SIDE = 'L' and of order N
!> if SIDE = 'R'.
!>
Parameters
[in]SIDE
!>          SIDE is CHARACTER*1
!>          = 'L': apply Q or Q**T from the Left;
!>          = 'R': apply Q or Q**T from the Right.
!>
[in]TRANS
!>          TRANS is CHARACTER*1
!>          = 'N':  No transpose, apply Q;
!>          = 'T':  Transpose, apply Q**T.
!>
[in]M
!>          M is INTEGER
!>          The number of rows of the matrix C. M >= 0.
!>
[in]N
!>          N is INTEGER
!>          The number of columns of the matrix C. N >= 0.
!>
[in]K
!>          K is INTEGER
!>          The number of elementary reflectors whose product defines
!>          the matrix Q.
!>          If SIDE = 'L', M >= K >= 0;
!>          if SIDE = 'R', N >= K >= 0.
!>
[in]L
!>          L is INTEGER
!>          The number of columns of the matrix A containing
!>          the meaningful part of the Householder reflectors.
!>          If SIDE = 'L', M >= L >= 0, if SIDE = 'R', N >= L >= 0.
!>
[in]A
!>          A is REAL array, dimension
!>                               (LDA,M) if SIDE = 'L',
!>                               (LDA,N) if SIDE = 'R'
!>          The i-th row must contain the vector which defines the
!>          elementary reflector H(i), for i = 1,2,...,k, as returned by
!>          STZRZF in the last k rows of its array argument A.
!>          A is modified by the routine but restored on exit.
!>
[in]LDA
!>          LDA is INTEGER
!>          The leading dimension of the array A. LDA >= max(1,K).
!>
[in]TAU
!>          TAU is REAL array, dimension (K)
!>          TAU(i) must contain the scalar factor of the elementary
!>          reflector H(i), as returned by STZRZF.
!>
[in,out]C
!>          C is REAL array, dimension (LDC,N)
!>          On entry, the M-by-N matrix C.
!>          On exit, C is overwritten by Q*C or Q**H*C or C*Q**H or C*Q.
!>
[in]LDC
!>          LDC is INTEGER
!>          The leading dimension of the array C. LDC >= max(1,M).
!>
[out]WORK
!>          WORK is REAL array, dimension (MAX(1,LWORK))
!>          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
!>
[in]LWORK
!>          LWORK is INTEGER
!>          The dimension of the array WORK.
!>          If SIDE = 'L', LWORK >= max(1,N);
!>          if SIDE = 'R', LWORK >= max(1,M).
!>          For good performance, LWORK should generally be larger.
!>
!>          If LWORK = -1, then a workspace query is assumed; the routine
!>          only calculates the optimal size of the WORK array, returns
!>          this value as the first entry of the WORK array, and no error
!>          message related to LWORK is issued by XERBLA.
!>
[out]INFO
!>          INFO is INTEGER
!>          = 0:  successful exit
!>          < 0:  if INFO = -i, the i-th argument had an illegal value
!>
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Contributors:
A. Petitet, Computer Science Dept., Univ. of Tenn., Knoxville, USA
Further Details:
!>

Definition at line 183 of file sormrz.f.

186*
187* -- LAPACK computational routine --
188* -- LAPACK is a software package provided by Univ. of Tennessee, --
189* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
190*
191* .. Scalar Arguments ..
192 CHARACTER SIDE, TRANS
193 INTEGER INFO, K, L, LDA, LDC, LWORK, M, N
194* ..
195* .. Array Arguments ..
196 REAL A( LDA, * ), C( LDC, * ), TAU( * ), WORK( * )
197* ..
198*
199* =====================================================================
200*
201* .. Parameters ..
202 INTEGER NBMAX, LDT, TSIZE
203 parameter( nbmax = 64, ldt = nbmax+1,
204 $ tsize = ldt*nbmax )
205* ..
206* .. Local Scalars ..
207 LOGICAL LEFT, LQUERY, NOTRAN
208 CHARACTER TRANST
209 INTEGER I, I1, I2, I3, IB, IC, IINFO, IWT, JA, JC,
210 $ LDWORK, LWKOPT, MI, NB, NBMIN, NI, NQ, NW
211* ..
212* .. External Functions ..
213 LOGICAL LSAME
214 INTEGER ILAENV
215 REAL SROUNDUP_LWORK
216 EXTERNAL lsame, ilaenv, sroundup_lwork
217* ..
218* .. External Subroutines ..
219 EXTERNAL slarzb, slarzt, sormr3, xerbla
220* ..
221* .. Intrinsic Functions ..
222 INTRINSIC max, min
223* ..
224* .. Executable Statements ..
225*
226* Test the input arguments
227*
228 info = 0
229 left = lsame( side, 'L' )
230 notran = lsame( trans, 'N' )
231 lquery = ( lwork.EQ.-1 )
232*
233* NQ is the order of Q and NW is the minimum dimension of WORK
234*
235 IF( left ) THEN
236 nq = m
237 nw = max( 1, n )
238 ELSE
239 nq = n
240 nw = max( 1, m )
241 END IF
242 IF( .NOT.left .AND. .NOT.lsame( side, 'R' ) ) THEN
243 info = -1
244 ELSE IF( .NOT.notran .AND. .NOT.lsame( trans, 'T' ) ) THEN
245 info = -2
246 ELSE IF( m.LT.0 ) THEN
247 info = -3
248 ELSE IF( n.LT.0 ) THEN
249 info = -4
250 ELSE IF( k.LT.0 .OR. k.GT.nq ) THEN
251 info = -5
252 ELSE IF( l.LT.0 .OR. ( left .AND. ( l.GT.m ) ) .OR.
253 $ ( .NOT.left .AND. ( l.GT.n ) ) ) THEN
254 info = -6
255 ELSE IF( lda.LT.max( 1, k ) ) THEN
256 info = -8
257 ELSE IF( ldc.LT.max( 1, m ) ) THEN
258 info = -11
259 ELSE IF( lwork.LT.nw .AND. .NOT.lquery ) THEN
260 info = -13
261 END IF
262*
263 IF( info.EQ.0 ) THEN
264*
265* Compute the workspace requirements
266*
267 IF( m.EQ.0 .OR. n.EQ.0 ) THEN
268 lwkopt = 1
269 ELSE
270 nb = min( nbmax, ilaenv( 1, 'SORMRQ', side // trans, m,
271 $ n,
272 $ k, -1 ) )
273 lwkopt = nw*nb + tsize
274 END IF
275 work( 1 ) = sroundup_lwork(lwkopt)
276 END IF
277*
278 IF( info.NE.0 ) THEN
279 CALL xerbla( 'SORMRZ', -info )
280 RETURN
281 ELSE IF( lquery ) THEN
282 RETURN
283 END IF
284*
285* Quick return if possible
286*
287 IF( m.EQ.0 .OR. n.EQ.0 ) THEN
288 RETURN
289 END IF
290*
291 nbmin = 2
292 ldwork = nw
293 IF( nb.GT.1 .AND. nb.LT.k ) THEN
294 IF( lwork.LT.lwkopt ) THEN
295 nb = (lwork-tsize) / ldwork
296 nbmin = max( 2, ilaenv( 2, 'SORMRQ', side // trans, m, n,
297 $ k,
298 $ -1 ) )
299 END IF
300 END IF
301*
302 IF( nb.LT.nbmin .OR. nb.GE.k ) THEN
303*
304* Use unblocked code
305*
306 CALL sormr3( side, trans, m, n, k, l, a, lda, tau, c, ldc,
307 $ work, iinfo )
308 ELSE
309*
310* Use blocked code
311*
312 iwt = 1 + nw*nb
313 IF( ( left .AND. .NOT.notran ) .OR.
314 $ ( .NOT.left .AND. notran ) ) THEN
315 i1 = 1
316 i2 = k
317 i3 = nb
318 ELSE
319 i1 = ( ( k-1 ) / nb )*nb + 1
320 i2 = 1
321 i3 = -nb
322 END IF
323*
324 IF( left ) THEN
325 ni = n
326 jc = 1
327 ja = m - l + 1
328 ELSE
329 mi = m
330 ic = 1
331 ja = n - l + 1
332 END IF
333*
334 IF( notran ) THEN
335 transt = 'T'
336 ELSE
337 transt = 'N'
338 END IF
339*
340 DO 10 i = i1, i2, i3
341 ib = min( nb, k-i+1 )
342*
343* Form the triangular factor of the block reflector
344* H = H(i+ib-1) . . . H(i+1) H(i)
345*
346 CALL slarzt( 'Backward', 'Rowwise', l, ib, a( i, ja ),
347 $ lda,
348 $ tau( i ), work( iwt ), ldt )
349*
350 IF( left ) THEN
351*
352* H or H**T is applied to C(i:m,1:n)
353*
354 mi = m - i + 1
355 ic = i
356 ELSE
357*
358* H or H**T is applied to C(1:m,i:n)
359*
360 ni = n - i + 1
361 jc = i
362 END IF
363*
364* Apply H or H**T
365*
366 CALL slarzb( side, transt, 'Backward', 'Rowwise', mi, ni,
367 $ ib, l, a( i, ja ), lda, work( iwt ), ldt,
368 $ c( ic, jc ), ldc, work, ldwork )
369 10 CONTINUE
370*
371 END IF
372*
373 work( 1 ) = sroundup_lwork(lwkopt)
374*
375 RETURN
376*
377* End of SORMRZ
378*
xerbla
subroutine xerbla(srname, info)
Definition cblat2.f:3285
ilaenv
integer function ilaenv(ispec, name, opts, n1, n2, n3, n4)
ILAENV
Definition ilaenv.f:160
slarzb
subroutine slarzb(side, trans, direct, storev, m, n, k, l, v, ldv, t, ldt, c, ldc, work, ldwork)
SLARZB applies a block reflector or its transpose to a general matrix.
Definition slarzb.f:181
slarzt
subroutine slarzt(direct, storev, n, k, v, ldv, tau, t, ldt)
SLARZT forms the triangular factor T of a block reflector H = I - vtvH.
Definition slarzt.f:183
lsame
logical function lsame(ca, cb)
LSAME
Definition lsame.f:48
sroundup_lwork
real function sroundup_lwork(lwork)
SROUNDUP_LWORK
Definition sroundup_lwork.f:59
sormr3
subroutine sormr3(side, trans, m, n, k, l, a, lda, tau, c, ldc, work, info)
SORMR3 multiplies a general matrix by the orthogonal matrix from a RZ factorization determined by stz...
Definition sormr3.f:177
Here is the call graph for this function:
Here is the caller graph for this function: