dlahr2.f

Go to the documentation of this file.

*> \brief \b DLAHR2 reduces the specified number of first columns of a general rectangular matrix A so that elements below the specified subdiagonal are zero, and returns auxiliary matrices which are needed to apply the transformation to the unreduced part of A.
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*> Download DLAHR2 + dependencies
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/dlahr2.f">
*> [TGZ]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/dlahr2.f">
*> [ZIP]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/dlahr2.f">
*> [TXT]</a>
*
*  Definition:
*  ===========
*
*       SUBROUTINE DLAHR2( N, K, NB, A, LDA, TAU, T, LDT, Y, LDY )
*
*       .. Scalar Arguments ..
*       INTEGER            K, LDA, LDT, LDY, N, NB
*       ..
*       .. Array Arguments ..
*       DOUBLE PRECISION  A( LDA, * ), T( LDT, NB ), TAU( NB ),
*      $                   Y( LDY, NB )
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> DLAHR2 reduces the first NB columns of A real general n-BY-(n-k+1)
*> matrix A so that elements below the k-th subdiagonal are zero. The
*> reduction is performed by an orthogonal similarity transformation
*> Q**T * A * Q. The routine returns the matrices V and T which determine
*> Q as a block reflector I - V*T*V**T, and also the matrix Y = A * V * T.
*>
*> This is an auxiliary routine called by DGEHRD.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The order of the matrix A.
*> \endverbatim
*>
*> \param[in] K
*> \verbatim
*>          K is INTEGER
*>          The offset for the reduction. Elements below the k-th
*>          subdiagonal in the first NB columns are reduced to zero.
*>          K < N.
*> \endverbatim
*>
*> \param[in] NB
*> \verbatim
*>          NB is INTEGER
*>          The number of columns to be reduced.
*> \endverbatim
*>
*> \param[in,out] A
*> \verbatim
*>          A is DOUBLE PRECISION array, dimension (LDA,N-K+1)
*>          On entry, the n-by-(n-k+1) general matrix A.
*>          On exit, the elements on and above the k-th subdiagonal in
*>          the first NB columns are overwritten with the corresponding
*>          elements of the reduced matrix; the elements below the k-th
*>          subdiagonal, with the array TAU, represent the matrix Q as a
*>          product of elementary reflectors. The other columns of A are
*>          unchanged. See Further Details.
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>          The leading dimension of the array A.  LDA >= max(1,N).
*> \endverbatim
*>
*> \param[out] TAU
*> \verbatim
*>          TAU is DOUBLE PRECISION array, dimension (NB)
*>          The scalar factors of the elementary reflectors. See Further
*>          Details.
*> \endverbatim
*>
*> \param[out] T
*> \verbatim
*>          T is DOUBLE PRECISION array, dimension (LDT,NB)
*>          The upper triangular matrix T.
*> \endverbatim
*>
*> \param[in] LDT
*> \verbatim
*>          LDT is INTEGER
*>          The leading dimension of the array T.  LDT >= NB.
*> \endverbatim
*>
*> \param[out] Y
*> \verbatim
*>          Y is DOUBLE PRECISION array, dimension (LDY,NB)
*>          The n-by-nb matrix Y.
*> \endverbatim
*>
*> \param[in] LDY
*> \verbatim
*>          LDY is INTEGER
*>          The leading dimension of the array Y. LDY >= N.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \ingroup lahr2
*
*> \par Further Details:
*  =====================
*>
*> \verbatim
*>
*>  The matrix Q is represented as a product of nb elementary reflectors
*>
*>     Q = H(1) H(2) . . . H(nb).
*>
*>  Each H(i) has the form
*>
*>     H(i) = I - tau * v * v**T
*>
*>  where tau is a real scalar, and v is a real vector with
*>  v(1:i+k-1) = 0, v(i+k) = 1; v(i+k+1:n) is stored on exit in
*>  A(i+k+1:n,i), and tau in TAU(i).
*>
*>  The elements of the vectors v together form the (n-k+1)-by-nb matrix
*>  V which is needed, with T and Y, to apply the transformation to the
*>  unreduced part of the matrix, using an update of the form:
*>  A := (I - V*T*V**T) * (A - Y*V**T).
*>
*>  The contents of A on exit are illustrated by the following example
*>  with n = 7, k = 3 and nb = 2:
*>
*>     ( a   a   a   a   a )
*>     ( a   a   a   a   a )
*>     ( a   a   a   a   a )
*>     ( h   h   a   a   a )
*>     ( v1  h   a   a   a )
*>     ( v1  v2  a   a   a )
*>     ( v1  v2  a   a   a )
*>
*>  where a denotes an element of the original matrix A, h denotes a
*>  modified element of the upper Hessenberg matrix H, and vi denotes an
*>  element of the vector defining H(i).
*>
*>  This subroutine is a slight modification of LAPACK-3.0's DLAHRD
*>  incorporating improvements proposed by Quintana-Orti and Van de
*>  Gejin. Note that the entries of A(1:K,2:NB) differ from those
*>  returned by the original LAPACK-3.0's DLAHRD routine. (This
*>  subroutine is not backward compatible with LAPACK-3.0's DLAHRD.)
*> \endverbatim
*
*> \par References:
*  ================
*>
*>  Gregorio Quintana-Orti and Robert van de Geijn, "Improving the
*>  performance of reduction to Hessenberg form," ACM Transactions on
*>  Mathematical Software, 32(2):180-194, June 2006.
*>
*  =====================================================================
      SUBROUTINE dlahr2( N, K, NB, A, LDA, TAU, T, LDT, Y, LDY )
*
*  -- LAPACK auxiliary routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            K, LDA, LDT, LDY, N, NB
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION  A( LDA, * ), T( LDT, NB ), TAU( NB ),
     $                   Y( LDY, NB )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION  ZERO, ONE
      parameter( zero = 0.0d+0,
     $                     one = 1.0d+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I
      DOUBLE PRECISION  EI
*     ..
*     .. External Subroutines ..
      EXTERNAL           daxpy, dcopy, dgemm, dgemv, dlacpy,
     $                   dlarfg, dscal, dtrmm, dtrmv
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          min
*     ..
*     .. Executable Statements ..
*
*     Quick return if possible
*
      IF( n.LE.1 )
     $   RETURN
*
      DO 10 i = 1, nb
         IF( i.GT.1 ) THEN
*
*           Update A(K+1:N,I)
*
*           Update I-th column of A - Y * V**T
*
            CALL dgemv( 'NO TRANSPOSE', n-k, i-1, -one, y(k+1,1),
     $                  ldy,
     $                  a( k+i-1, 1 ), lda, one, a( k+1, i ), 1 )
*
*           Apply I - V * T**T * V**T to this column (call it b) from the
*           left, using the last column of T as workspace
*
*           Let  V = ( V1 )   and   b = ( b1 )   (first I-1 rows)
*                    ( V2 )             ( b2 )
*
*           where V1 is unit lower triangular
*
*           w := V1**T * b1
*
            CALL dcopy( i-1, a( k+1, i ), 1, t( 1, nb ), 1 )
            CALL dtrmv( 'Lower', 'Transpose', 'UNIT',
     $                  i-1, a( k+1, 1 ),
     $                  lda, t( 1, nb ), 1 )
*
*           w := w + V2**T * b2
*
            CALL dgemv( 'Transpose', n-k-i+1, i-1,
     $                  one, a( k+i, 1 ),
     $                  lda, a( k+i, i ), 1, one, t( 1, nb ), 1 )
*
*           w := T**T * w
*
            CALL dtrmv( 'Upper', 'Transpose', 'NON-UNIT',
     $                  i-1, t, ldt,
     $                  t( 1, nb ), 1 )
*
*           b2 := b2 - V2*w
*
            CALL dgemv( 'NO TRANSPOSE', n-k-i+1, i-1, -one,
     $                  a( k+i, 1 ),
     $                  lda, t( 1, nb ), 1, one, a( k+i, i ), 1 )
*
*           b1 := b1 - V1*w
*
            CALL dtrmv( 'Lower', 'NO TRANSPOSE',
     $                  'UNIT', i-1,
     $                  a( k+1, 1 ), lda, t( 1, nb ), 1 )
            CALL daxpy( i-1, -one, t( 1, nb ), 1, a( k+1, i ), 1 )
*
            a( k+i-1, i-1 ) = ei
         END IF
*
*        Generate the elementary reflector H(I) to annihilate
*        A(K+I+1:N,I)
*
         CALL dlarfg( n-k-i+1, a( k+i, i ), a( min( k+i+1, n ), i ),
     $                1,
     $                tau( i ) )
         ei = a( k+i, i )
         a( k+i, i ) = one
*
*        Compute  Y(K+1:N,I)
*
         CALL dgemv( 'NO TRANSPOSE', n-k, n-k-i+1,
     $               one, a( k+1, i+1 ),
     $               lda, a( k+i, i ), 1, zero, y( k+1, i ), 1 )
         CALL dgemv( 'Transpose', n-k-i+1, i-1,
     $               one, a( k+i, 1 ), lda,
     $               a( k+i, i ), 1, zero, t( 1, i ), 1 )
         CALL dgemv( 'NO TRANSPOSE', n-k, i-1, -one,
     $               y( k+1, 1 ), ldy,
     $               t( 1, i ), 1, one, y( k+1, i ), 1 )
         CALL dscal( n-k, tau( i ), y( k+1, i ), 1 )
*
*        Compute T(1:I,I)
*
         CALL dscal( i-1, -tau( i ), t( 1, i ), 1 )
         CALL dtrmv( 'Upper', 'No Transpose', 'NON-UNIT',
     $               i-1, t, ldt,
     $               t( 1, i ), 1 )
         t( i, i ) = tau( i )
*
   10 CONTINUE
      a( k+nb, nb ) = ei
*
*     Compute Y(1:K,1:NB)
*
      CALL dlacpy( 'ALL', k, nb, a( 1, 2 ), lda, y, ldy )
      CALL dtrmm( 'RIGHT', 'Lower', 'NO TRANSPOSE',
     $            'UNIT', k, nb,
     $            one, a( k+1, 1 ), lda, y, ldy )
      IF( n.GT.k+nb )
     $   CALL dgemm( 'NO TRANSPOSE', 'NO TRANSPOSE', k,
     $               nb, n-k-nb, one,
     $               a( 1, 2+nb ), lda, a( k+1+nb, 1 ), lda, one, y,
     $               ldy )
      CALL dtrmm( 'RIGHT', 'Upper', 'NO TRANSPOSE',
     $            'NON-UNIT', k, nb,
     $            one, t, ldt, y, ldy )
*
      RETURN
*
*     End of DLAHR2
*
      END