chbt21()

subroutine chbt21	(	character	uplo,
		integer	n,
		integer	ka,
		integer	ks,
		complex, dimension( lda, * )	a,
		integer	lda,
		real, dimension( * )	d,
		real, dimension( * )	e,
		complex, dimension( ldu, * )	u,
		integer	ldu,
		complex, dimension( * )	work,
		real, dimension( * )	rwork,
		real, dimension( 2 )	result
	)

CHBT21

Purpose:

 CHBT21  generally checks a decomposition of the form

         A = U S U**H

 where **H means conjugate transpose, A is hermitian banded, U is
 unitary, and S is diagonal (if KS=0) or symmetric
 tridiagonal (if KS=1).

 Specifically:

         RESULT(1) = | A - U S U**H | / ( |A| n ulp ) and
         RESULT(2) = | I - U U**H | / ( n ulp )

Parameters

[in]	UPLO	UPLO is CHARACTER If UPLO='U', the upper triangle of A and V will be used and the (strictly) lower triangle will not be referenced. If UPLO='L', the lower triangle of A and V will be used and the (strictly) upper triangle will not be referenced.
[in]	N	N is INTEGER The size of the matrix. If it is zero, CHBT21 does nothing. It must be at least zero.
[in]	KA	KA is INTEGER The bandwidth of the matrix A. It must be at least zero. If it is larger than N-1, then max( 0, N-1 ) will be used.
[in]	KS	KS is INTEGER The bandwidth of the matrix S. It may only be zero or one. If zero, then S is diagonal, and E is not referenced. If one, then S is symmetric tri-diagonal.
[in]	A	A is COMPLEX array, dimension (LDA, N) The original (unfactored) matrix. It is assumed to be hermitian, and only the upper (UPLO='U') or only the lower (UPLO='L') will be referenced.
[in]	LDA	LDA is INTEGER The leading dimension of A. It must be at least 1 and at least min( KA, N-1 ).
[in]	D	D is REAL array, dimension (N) The diagonal of the (symmetric tri-) diagonal matrix S.
[in]	E	E is REAL array, dimension (N-1) The off-diagonal of the (symmetric tri-) diagonal matrix S. E(1) is the (1,2) and (2,1) element, E(2) is the (2,3) and (3,2) element, etc. Not referenced if KS=0.
[in]	U	U is COMPLEX array, dimension (LDU, N) The unitary matrix in the decomposition, expressed as a dense matrix (i.e., not as a product of Householder transformations, Givens transformations, etc.)
[in]	LDU	LDU is INTEGER The leading dimension of U. LDU must be at least N and at least 1.
[out]	WORK	WORK is COMPLEX array, dimension (N**2)
[out]	RWORK	RWORK is REAL array, dimension (N)
[out]	RESULT	RESULT is REAL array, dimension (2) The values computed by the two tests described above. The values are currently limited to 1/ulp, to avoid overflow.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 150 of file chbt21.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            KA, KS, LDA, LDU, N
*     ..
*     .. Array Arguments ..
      REAL               D( * ), E( * ), RESULT( 2 ), RWORK( * )
      COMPLEX            A( LDA, * ), U( LDU, * ), WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      COMPLEX            CZERO, CONE
      parameter( czero = ( 0.0e+0, 0.0e+0 ),
     $                   cone = ( 1.0e+0, 0.0e+0 ) )
      REAL               ZERO, ONE
      parameter( zero = 0.0e+0, one = 1.0e+0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            LOWER
      CHARACTER          CUPLO
      INTEGER            IKA, J, JC, JR
      REAL               ANORM, ULP, UNFL, WNORM
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      REAL               CLANGE, CLANHB, CLANHP, SLAMCH
      EXTERNAL           lsame, clange, clanhb, clanhp, slamch
*     ..
*     .. External Subroutines ..
      EXTERNAL           cgemm, chpr, chpr2
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          cmplx, max, min, real
*     ..
*     .. Executable Statements ..
*
*     Constants
*
      result( 1 ) = zero
      result( 2 ) = zero
      IF( n.LE.0 )
     $   RETURN
*
      ika = max( 0, min( n-1, ka ) )
*
      IF( lsame( uplo, 'U' ) ) THEN
         lower = .false.
         cuplo = 'U'
      ELSE
         lower = .true.
         cuplo = 'L'
      END IF
*
      unfl = slamch( 'Safe minimum' )
      ulp = slamch( 'Epsilon' )*slamch( 'Base' )
*
*     Some Error Checks
*
*     Do Test 1
*
*     Norm of A:
*
      anorm = max( clanhb( '1', cuplo, n, ika, a, lda, rwork ), unfl )
*
*     Compute error matrix:    Error = A - U S U**H
*
*     Copy A from SB to SP storage format.
*
      j = 0
      DO 50 jc = 1, n
         IF( lower ) THEN
            DO 10 jr = 1, min( ika+1, n+1-jc )
               j = j + 1
               work( j ) = a( jr, jc )
   10       CONTINUE
            DO 20 jr = ika + 2, n + 1 - jc
               j = j + 1
               work( j ) = zero
   20       CONTINUE
         ELSE
            DO 30 jr = ika + 2, jc
               j = j + 1
               work( j ) = zero
   30       CONTINUE
            DO 40 jr = min( ika, jc-1 ), 0, -1
               j = j + 1
               work( j ) = a( ika+1-jr, jc )
   40       CONTINUE
         END IF
   50 CONTINUE
*
      DO 60 j = 1, n
         CALL chpr( cuplo, n, -d( j ), u( 1, j ), 1, work )
   60 CONTINUE
*
      IF( n.GT.1 .AND. ks.EQ.1 ) THEN
         DO 70 j = 1, n - 1
            CALL chpr2( cuplo, n, -cmplx( e( j ) ), u( 1, j ), 1,
     $                  u( 1, j+1 ), 1, work )
   70    CONTINUE
      END IF
      wnorm = clanhp( '1', cuplo, n, work, rwork )
*
      IF( anorm.GT.wnorm ) THEN
         result( 1 ) = ( wnorm / anorm ) / ( n*ulp )
      ELSE
         IF( anorm.LT.one ) THEN
            result( 1 ) = ( min( wnorm, n*anorm ) / anorm ) / ( n*ulp )
         ELSE
            result( 1 ) = min( wnorm / anorm, real( n ) ) / ( n*ulp )
         END IF
      END IF
*
*     Do Test 2
*
*     Compute  U U**H - I
*
      CALL cgemm( 'N', 'C', n, n, n, cone, u, ldu, u, ldu, czero, work,
     $            n )
*
      DO 80 j = 1, n
         work( ( n+1 )*( j-1 )+1 ) = work( ( n+1 )*( j-1 )+1 ) - cone
   80 CONTINUE
*
      result( 2 ) = min( clange( '1', n, n, work, n, rwork ),
     $              real( n ) ) / ( n*ulp )
*
      RETURN
*
*     End of CHBT21
*

Here is the call graph for this function:

Here is the caller graph for this function: