LAPACK 3.12.1
LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches

◆ cla_gerfsx_extended()

subroutine cla_gerfsx_extended ( integer prec_type,
integer trans_type,
integer n,
integer nrhs,
complex, dimension( lda, * ) a,
integer lda,
complex, dimension( ldaf, * ) af,
integer ldaf,
integer, dimension( * ) ipiv,
logical colequ,
real, dimension( * ) c,
complex, dimension( ldb, * ) b,
integer ldb,
complex, dimension( ldy, * ) y,
integer ldy,
real, dimension( * ) berr_out,
integer n_norms,
real, dimension( nrhs, * ) errs_n,
real, dimension( nrhs, * ) errs_c,
complex, dimension( * ) res,
real, dimension( * ) ayb,
complex, dimension( * ) dy,
complex, dimension( * ) y_tail,
real rcond,
integer ithresh,
real rthresh,
real dz_ub,
logical ignore_cwise,
integer info )

CLA_GERFSX_EXTENDED

Download CLA_GERFSX_EXTENDED + dependencies [TGZ] [ZIP] [TXT]

Purpose:
!>
!>
!> CLA_GERFSX_EXTENDED improves the computed solution to a system of
!> linear equations by performing extra-precise iterative refinement
!> and provides error bounds and backward error estimates for the solution.
!> This subroutine is called by CGERFSX to perform iterative refinement.
!> In addition to normwise error bound, the code provides maximum
!> componentwise error bound if possible. See comments for ERRS_N
!> and ERRS_C for details of the error bounds. Note that this
!> subroutine is only responsible for setting the second fields of
!> ERRS_N and ERRS_C.
!>
Parameters
[in]PREC_TYPE
!>          PREC_TYPE is INTEGER
!>     Specifies the intermediate precision to be used in refinement.
!>     The value is defined by ILAPREC(P) where P is a CHARACTER and P
!>          = 'S':  Single
!>          = 'D':  Double
!>          = 'I':  Indigenous
!>          = 'X' or 'E':  Extra
!>
[in]TRANS_TYPE
!>          TRANS_TYPE is INTEGER
!>     Specifies the transposition operation on A.
!>     The value is defined by ILATRANS(T) where T is a CHARACTER and T
!>          = 'N':  No transpose
!>          = 'T':  Transpose
!>          = 'C':  Conjugate transpose
!>
[in]N
!>          N is INTEGER
!>     The number of linear equations, i.e., the order of the
!>     matrix A.  N >= 0.
!>
[in]NRHS
!>          NRHS is INTEGER
!>     The number of right-hand-sides, i.e., the number of columns of the
!>     matrix B.
!>
[in]A
!>          A is COMPLEX array, dimension (LDA,N)
!>     On entry, the N-by-N matrix A.
!>
[in]LDA
!>          LDA is INTEGER
!>     The leading dimension of the array A.  LDA >= max(1,N).
!>
[in]AF
!>          AF is COMPLEX array, dimension (LDAF,N)
!>     The factors L and U from the factorization
!>     A = P*L*U as computed by CGETRF.
!>
[in]LDAF
!>          LDAF is INTEGER
!>     The leading dimension of the array AF.  LDAF >= max(1,N).
!>
[in]IPIV
!>          IPIV is INTEGER array, dimension (N)
!>     The pivot indices from the factorization A = P*L*U
!>     as computed by CGETRF; row i of the matrix was interchanged
!>     with row IPIV(i).
!>
[in]COLEQU
!>          COLEQU is LOGICAL
!>     If .TRUE. then column equilibration was done to A before calling
!>     this routine. This is needed to compute the solution and error
!>     bounds correctly.
!>
[in]C
!>          C is REAL array, dimension (N)
!>     The column scale factors for A. If COLEQU = .FALSE., C
!>     is not accessed. If C is input, each element of C should be a power
!>     of the radix to ensure a reliable solution and error estimates.
!>     Scaling by powers of the radix does not cause rounding errors unless
!>     the result underflows or overflows. Rounding errors during scaling
!>     lead to refining with a matrix that is not equivalent to the
!>     input matrix, producing error estimates that may not be
!>     reliable.
!>
[in]B
!>          B is COMPLEX array, dimension (LDB,NRHS)
!>     The right-hand-side matrix B.
!>
[in]LDB
!>          LDB is INTEGER
!>     The leading dimension of the array B.  LDB >= max(1,N).
!>
[in,out]Y
!>          Y is COMPLEX array, dimension (LDY,NRHS)
!>     On entry, the solution matrix X, as computed by CGETRS.
!>     On exit, the improved solution matrix Y.
!>
[in]LDY
!>          LDY is INTEGER
!>     The leading dimension of the array Y.  LDY >= max(1,N).
!>
[out]BERR_OUT
!>          BERR_OUT is REAL array, dimension (NRHS)
!>     On exit, BERR_OUT(j) contains the componentwise relative backward
!>     error for right-hand-side j from the formula
!>         max(i) ( abs(RES(i)) / ( abs(op(A_s))*abs(Y) + abs(B_s) )(i) )
!>     where abs(Z) is the componentwise absolute value of the matrix
!>     or vector Z. This is computed by CLA_LIN_BERR.
!>
[in]N_NORMS
!>          N_NORMS is INTEGER
!>     Determines which error bounds to return (see ERRS_N
!>     and ERRS_C).
!>     If N_NORMS >= 1 return normwise error bounds.
!>     If N_NORMS >= 2 return componentwise error bounds.
!>
[in,out]ERRS_N
!>          ERRS_N is REAL array, dimension (NRHS, N_ERR_BNDS)
!>     For each right-hand side, this array contains information about
!>     various error bounds and condition numbers corresponding to the
!>     normwise relative error, which is defined as follows:
!>
!>     Normwise relative error in the ith solution vector:
!>             max_j (abs(XTRUE(j,i) - X(j,i)))
!>            ------------------------------
!>                  max_j abs(X(j,i))
!>
!>     The array is indexed by the type of error information as described
!>     below. There currently are up to three pieces of information
!>     returned.
!>
!>     The first index in ERRS_N(i,:) corresponds to the ith
!>     right-hand side.
!>
!>     The second index in ERRS_N(:,err) contains the following
!>     three fields:
!>     err = 1  boolean. Trust the answer if the
!>              reciprocal condition number is less than the threshold
!>              sqrt(n) * slamch('Epsilon').
!>
!>     err = 2  error bound: The estimated forward error,
!>              almost certainly within a factor of 10 of the true error
!>              so long as the next entry is greater than the threshold
!>              sqrt(n) * slamch('Epsilon'). This error bound should only
!>              be trusted if the previous boolean is true.
!>
!>     err = 3  Reciprocal condition number: Estimated normwise
!>              reciprocal condition number.  Compared with the threshold
!>              sqrt(n) * slamch('Epsilon') to determine if the error
!>              estimate is . These reciprocal condition
!>              numbers are 1 / (norm(Z^{-1},inf) * norm(Z,inf)) for some
!>              appropriately scaled matrix Z.
!>              Let Z = S*A, where S scales each row by a power of the
!>              radix so all absolute row sums of Z are approximately 1.
!>
!>     This subroutine is only responsible for setting the second field
!>     above.
!>     See Lapack Working Note 165 for further details and extra
!>     cautions.
!>
[in,out]ERRS_C
!>          ERRS_C is REAL array, dimension (NRHS, N_ERR_BNDS)
!>     For each right-hand side, this array contains information about
!>     various error bounds and condition numbers corresponding to the
!>     componentwise relative error, which is defined as follows:
!>
!>     Componentwise relative error in the ith solution vector:
!>                    abs(XTRUE(j,i) - X(j,i))
!>             max_j ----------------------
!>                         abs(X(j,i))
!>
!>     The array is indexed by the right-hand side i (on which the
!>     componentwise relative error depends), and the type of error
!>     information as described below. There currently are up to three
!>     pieces of information returned for each right-hand side. If
!>     componentwise accuracy is not requested (PARAMS(3) = 0.0), then
!>     ERRS_C is not accessed.  If N_ERR_BNDS < 3, then at most
!>     the first (:,N_ERR_BNDS) entries are returned.
!>
!>     The first index in ERRS_C(i,:) corresponds to the ith
!>     right-hand side.
!>
!>     The second index in ERRS_C(:,err) contains the following
!>     three fields:
!>     err = 1  boolean. Trust the answer if the
!>              reciprocal condition number is less than the threshold
!>              sqrt(n) * slamch('Epsilon').
!>
!>     err = 2  error bound: The estimated forward error,
!>              almost certainly within a factor of 10 of the true error
!>              so long as the next entry is greater than the threshold
!>              sqrt(n) * slamch('Epsilon'). This error bound should only
!>              be trusted if the previous boolean is true.
!>
!>     err = 3  Reciprocal condition number: Estimated componentwise
!>              reciprocal condition number.  Compared with the threshold
!>              sqrt(n) * slamch('Epsilon') to determine if the error
!>              estimate is . These reciprocal condition
!>              numbers are 1 / (norm(Z^{-1},inf) * norm(Z,inf)) for some
!>              appropriately scaled matrix Z.
!>              Let Z = S*(A*diag(x)), where x is the solution for the
!>              current right-hand side and S scales each row of
!>              A*diag(x) by a power of the radix so all absolute row
!>              sums of Z are approximately 1.
!>
!>     This subroutine is only responsible for setting the second field
!>     above.
!>     See Lapack Working Note 165 for further details and extra
!>     cautions.
!>
[in]RES
!>          RES is COMPLEX array, dimension (N)
!>     Workspace to hold the intermediate residual.
!>
[in]AYB
!>          AYB is REAL array, dimension (N)
!>     Workspace.
!>
[in]DY
!>          DY is COMPLEX array, dimension (N)
!>     Workspace to hold the intermediate solution.
!>
[in]Y_TAIL
!>          Y_TAIL is COMPLEX array, dimension (N)
!>     Workspace to hold the trailing bits of the intermediate solution.
!>
[in]RCOND
!>          RCOND is REAL
!>     Reciprocal scaled condition number.  This is an estimate of the
!>     reciprocal Skeel condition number of the matrix A after
!>     equilibration (if done).  If this is less than the machine
!>     precision (in particular, if it is zero), the matrix is singular
!>     to working precision.  Note that the error may still be small even
!>     if this number is very small and the matrix appears ill-
!>     conditioned.
!>
[in]ITHRESH
!>          ITHRESH is INTEGER
!>     The maximum number of residual computations allowed for
!>     refinement. The default is 10. For 'aggressive' set to 100 to
!>     permit convergence using approximate factorizations or
!>     factorizations other than LU. If the factorization uses a
!>     technique other than Gaussian elimination, the guarantees in
!>     ERRS_N and ERRS_C may no longer be trustworthy.
!>
[in]RTHRESH
!>          RTHRESH is REAL
!>     Determines when to stop refinement if the error estimate stops
!>     decreasing. Refinement will stop when the next solution no longer
!>     satisfies norm(dx_{i+1}) < RTHRESH * norm(dx_i) where norm(Z) is
!>     the infinity norm of Z. RTHRESH satisfies 0 < RTHRESH <= 1. The
!>     default value is 0.5. For 'aggressive' set to 0.9 to permit
!>     convergence on extremely ill-conditioned matrices. See LAWN 165
!>     for more details.
!>
[in]DZ_UB
!>          DZ_UB is REAL
!>     Determines when to start considering componentwise convergence.
!>     Componentwise convergence is only considered after each component
!>     of the solution Y is stable, which we define as the relative
!>     change in each component being less than DZ_UB. The default value
!>     is 0.25, requiring the first bit to be stable. See LAWN 165 for
!>     more details.
!>
[in]IGNORE_CWISE
!>          IGNORE_CWISE is LOGICAL
!>     If .TRUE. then ignore componentwise convergence. Default value
!>     is .FALSE..
!>
[out]INFO
!>          INFO is INTEGER
!>       = 0:  Successful exit.
!>       < 0:  if INFO = -i, the ith argument to CGETRS had an illegal
!>             value
!>
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.

Definition at line 389 of file cla_gerfsx_extended.f.

396*
397* -- LAPACK computational routine --
398* -- LAPACK is a software package provided by Univ. of Tennessee, --
399* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
400*
401* .. Scalar Arguments ..
402 INTEGER INFO, LDA, LDAF, LDB, LDY, N, NRHS, PREC_TYPE,
403 $ TRANS_TYPE, N_NORMS
404 LOGICAL COLEQU, IGNORE_CWISE
405 INTEGER ITHRESH
406 REAL RTHRESH, DZ_UB
407* ..
408* .. Array Arguments
409 INTEGER IPIV( * )
410 COMPLEX A( LDA, * ), AF( LDAF, * ), B( LDB, * ),
411 $ Y( LDY, * ), RES( * ), DY( * ), Y_TAIL( * )
412 REAL C( * ), AYB( * ), RCOND, BERR_OUT( * ),
413 $ ERRS_N( NRHS, * ), ERRS_C( NRHS, * )
414* ..
415*
416* =====================================================================
417*
418* .. Local Scalars ..
419 CHARACTER TRANS
420 INTEGER CNT, I, J, X_STATE, Z_STATE, Y_PREC_STATE
421 REAL YK, DYK, YMIN, NORMY, NORMX, NORMDX, DXRAT,
422 $ DZRAT, PREVNORMDX, PREV_DZ_Z, DXRATMAX,
423 $ DZRATMAX, DX_X, DZ_Z, FINAL_DX_X, FINAL_DZ_Z,
424 $ EPS, HUGEVAL, INCR_THRESH
425 LOGICAL INCR_PREC
426 COMPLEX ZDUM
427* ..
428* .. Parameters ..
429 INTEGER UNSTABLE_STATE, WORKING_STATE, CONV_STATE,
430 $ NOPROG_STATE, BASE_RESIDUAL, EXTRA_RESIDUAL,
431 $ EXTRA_Y
432 parameter( unstable_state = 0, working_state = 1,
433 $ conv_state = 2,
434 $ noprog_state = 3 )
435 parameter( base_residual = 0, extra_residual = 1,
436 $ extra_y = 2 )
437 INTEGER FINAL_NRM_ERR_I, FINAL_CMP_ERR_I, BERR_I
438 INTEGER RCOND_I, NRM_RCOND_I, NRM_ERR_I, CMP_RCOND_I
439 INTEGER CMP_ERR_I, PIV_GROWTH_I
440 parameter( final_nrm_err_i = 1, final_cmp_err_i = 2,
441 $ berr_i = 3 )
442 parameter( rcond_i = 4, nrm_rcond_i = 5, nrm_err_i = 6 )
443 parameter( cmp_rcond_i = 7, cmp_err_i = 8,
444 $ piv_growth_i = 9 )
445 INTEGER LA_LINRX_ITREF_I, LA_LINRX_ITHRESH_I,
446 $ LA_LINRX_CWISE_I
447 parameter( la_linrx_itref_i = 1,
448 $ la_linrx_ithresh_i = 2 )
449 parameter( la_linrx_cwise_i = 3 )
450 INTEGER LA_LINRX_TRUST_I, LA_LINRX_ERR_I,
451 $ LA_LINRX_RCOND_I
452 parameter( la_linrx_trust_i = 1, la_linrx_err_i = 2 )
453 parameter( la_linrx_rcond_i = 3 )
454* ..
455* .. External Subroutines ..
456 EXTERNAL caxpy, ccopy, cgetrs, cgemv,
457 $ blas_cgemv_x,
458 $ blas_cgemv2_x, cla_geamv, cla_wwaddw, slamch,
459 $ chla_transtype, cla_lin_berr
460 REAL SLAMCH
461 CHARACTER CHLA_TRANSTYPE
462* ..
463* .. Intrinsic Functions ..
464 INTRINSIC abs, max, min
465* ..
466* .. Statement Functions ..
467 REAL CABS1
468* ..
469* .. Statement Function Definitions ..
470 cabs1( zdum ) = abs( real( zdum ) ) + abs( aimag( zdum ) )
471* ..
472* .. Executable Statements ..
473*
474 IF ( info.NE.0 ) RETURN
475 trans = chla_transtype(trans_type)
476 eps = slamch( 'Epsilon' )
477 hugeval = slamch( 'Overflow' )
478* Force HUGEVAL to Inf
479 hugeval = hugeval * hugeval
480* Using HUGEVAL may lead to spurious underflows.
481 incr_thresh = real( n ) * eps
482*
483 DO j = 1, nrhs
484 y_prec_state = extra_residual
485 IF ( y_prec_state .EQ. extra_y ) THEN
486 DO i = 1, n
487 y_tail( i ) = 0.0
488 END DO
489 END IF
490
491 dxrat = 0.0
492 dxratmax = 0.0
493 dzrat = 0.0
494 dzratmax = 0.0
495 final_dx_x = hugeval
496 final_dz_z = hugeval
497 prevnormdx = hugeval
498 prev_dz_z = hugeval
499 dz_z = hugeval
500 dx_x = hugeval
501
502 x_state = working_state
503 z_state = unstable_state
504 incr_prec = .false.
505
506 DO cnt = 1, ithresh
507*
508* Compute residual RES = B_s - op(A_s) * Y,
509* op(A) = A, A**T, or A**H depending on TRANS (and type).
510*
511 CALL ccopy( n, b( 1, j ), 1, res, 1 )
512 IF ( y_prec_state .EQ. base_residual ) THEN
513 CALL cgemv( trans, n, n, (-1.0e+0,0.0e+0), a, lda,
514 $ y( 1, j ), 1, (1.0e+0,0.0e+0), res, 1)
515 ELSE IF (y_prec_state .EQ. extra_residual) THEN
516 CALL blas_cgemv_x( trans_type, n, n, (-1.0e+0,0.0e+0),
517 $ a,
518 $ lda, y( 1, j ), 1, (1.0e+0,0.0e+0),
519 $ res, 1, prec_type )
520 ELSE
521 CALL blas_cgemv2_x( trans_type, n, n,
522 $ (-1.0e+0,0.0e+0),
523 $ a, lda, y(1, j), y_tail, 1, (1.0e+0,0.0e+0), res, 1,
524 $ prec_type)
525 END IF
526
527! XXX: RES is no longer needed.
528 CALL ccopy( n, res, 1, dy, 1 )
529 CALL cgetrs( trans, n, 1, af, ldaf, ipiv, dy, n, info )
530*
531* Calculate relative changes DX_X, DZ_Z and ratios DXRAT, DZRAT.
532*
533 normx = 0.0e+0
534 normy = 0.0e+0
535 normdx = 0.0e+0
536 dz_z = 0.0e+0
537 ymin = hugeval
538*
539 DO i = 1, n
540 yk = cabs1( y( i, j ) )
541 dyk = cabs1( dy( i ) )
542
543 IF ( yk .NE. 0.0e+0 ) THEN
544 dz_z = max( dz_z, dyk / yk )
545 ELSE IF ( dyk .NE. 0.0 ) THEN
546 dz_z = hugeval
547 END IF
548
549 ymin = min( ymin, yk )
550
551 normy = max( normy, yk )
552
553 IF ( colequ ) THEN
554 normx = max( normx, yk * c( i ) )
555 normdx = max( normdx, dyk * c( i ) )
556 ELSE
557 normx = normy
558 normdx = max(normdx, dyk)
559 END IF
560 END DO
561
562 IF ( normx .NE. 0.0 ) THEN
563 dx_x = normdx / normx
564 ELSE IF ( normdx .EQ. 0.0 ) THEN
565 dx_x = 0.0
566 ELSE
567 dx_x = hugeval
568 END IF
569
570 dxrat = normdx / prevnormdx
571 dzrat = dz_z / prev_dz_z
572*
573* Check termination criteria
574*
575 IF (.NOT.ignore_cwise
576 $ .AND. ymin*rcond .LT. incr_thresh*normy
577 $ .AND. y_prec_state .LT. extra_y )
578 $ incr_prec = .true.
579
580 IF ( x_state .EQ. noprog_state .AND. dxrat .LE. rthresh )
581 $ x_state = working_state
582 IF ( x_state .EQ. working_state ) THEN
583 IF (dx_x .LE. eps) THEN
584 x_state = conv_state
585 ELSE IF ( dxrat .GT. rthresh ) THEN
586 IF ( y_prec_state .NE. extra_y ) THEN
587 incr_prec = .true.
588 ELSE
589 x_state = noprog_state
590 END IF
591 ELSE
592 IF ( dxrat .GT. dxratmax ) dxratmax = dxrat
593 END IF
594 IF ( x_state .GT. working_state ) final_dx_x = dx_x
595 END IF
596
597 IF ( z_state .EQ. unstable_state .AND. dz_z .LE. dz_ub )
598 $ z_state = working_state
599 IF ( z_state .EQ. noprog_state .AND. dzrat .LE. rthresh )
600 $ z_state = working_state
601 IF ( z_state .EQ. working_state ) THEN
602 IF ( dz_z .LE. eps ) THEN
603 z_state = conv_state
604 ELSE IF ( dz_z .GT. dz_ub ) THEN
605 z_state = unstable_state
606 dzratmax = 0.0
607 final_dz_z = hugeval
608 ELSE IF ( dzrat .GT. rthresh ) THEN
609 IF ( y_prec_state .NE. extra_y ) THEN
610 incr_prec = .true.
611 ELSE
612 z_state = noprog_state
613 END IF
614 ELSE
615 IF ( dzrat .GT. dzratmax ) dzratmax = dzrat
616 END IF
617 IF ( z_state .GT. working_state ) final_dz_z = dz_z
618 END IF
619*
620* Exit if both normwise and componentwise stopped working,
621* but if componentwise is unstable, let it go at least two
622* iterations.
623*
624 IF ( x_state.NE.working_state ) THEN
625 IF ( ignore_cwise ) GOTO 666
626 IF ( z_state.EQ.noprog_state .OR. z_state.EQ.conv_state )
627 $ GOTO 666
628 IF ( z_state.EQ.unstable_state .AND. cnt.GT.1 ) GOTO 666
629 END IF
630
631 IF ( incr_prec ) THEN
632 incr_prec = .false.
633 y_prec_state = y_prec_state + 1
634 DO i = 1, n
635 y_tail( i ) = 0.0
636 END DO
637 END IF
638
639 prevnormdx = normdx
640 prev_dz_z = dz_z
641*
642* Update solution.
643*
644 IF ( y_prec_state .LT. extra_y ) THEN
645 CALL caxpy( n, (1.0e+0,0.0e+0), dy, 1, y(1,j), 1 )
646 ELSE
647 CALL cla_wwaddw( n, y( 1, j ), y_tail, dy )
648 END IF
649
650 END DO
651* Target of "IF (Z_STOP .AND. X_STOP)". Sun's f77 won't EXIT.
652 666 CONTINUE
653*
654* Set final_* when cnt hits ithresh
655*
656 IF ( x_state .EQ. working_state ) final_dx_x = dx_x
657 IF ( z_state .EQ. working_state ) final_dz_z = dz_z
658*
659* Compute error bounds
660*
661 IF (n_norms .GE. 1) THEN
662 errs_n( j, la_linrx_err_i ) = final_dx_x / (1 - dxratmax)
663
664 END IF
665 IF ( n_norms .GE. 2 ) THEN
666 errs_c( j, la_linrx_err_i ) = final_dz_z / (1 - dzratmax)
667 END IF
668*
669* Compute componentwise relative backward error from formula
670* max(i) ( abs(R(i)) / ( abs(op(A_s))*abs(Y) + abs(B_s) )(i) )
671* where abs(Z) is the componentwise absolute value of the matrix
672* or vector Z.
673*
674* Compute residual RES = B_s - op(A_s) * Y,
675* op(A) = A, A**T, or A**H depending on TRANS (and type).
676*
677 CALL ccopy( n, b( 1, j ), 1, res, 1 )
678 CALL cgemv( trans, n, n, (-1.0e+0,0.0e+0), a, lda, y(1,j),
679 $ 1,
680 $ (1.0e+0,0.0e+0), res, 1 )
681
682 DO i = 1, n
683 ayb( i ) = cabs1( b( i, j ) )
684 END DO
685*
686* Compute abs(op(A_s))*abs(Y) + abs(B_s).
687*
688 CALL cla_geamv ( trans_type, n, n, 1.0e+0,
689 $ a, lda, y(1, j), 1, 1.0e+0, ayb, 1 )
690
691 CALL cla_lin_berr ( n, n, 1, res, ayb, berr_out( j ) )
692*
693* End of loop for each RHS.
694*
695 END DO
696*
697 RETURN
698*
699* End of CLA_GERFSX_EXTENDED
700*
caxpy
subroutine caxpy(n, ca, cx, incx, cy, incy)
CAXPY
Definition caxpy.f:88
ccopy
subroutine ccopy(n, cx, incx, cy, incy)
CCOPY
Definition ccopy.f:81
cgemv
subroutine cgemv(trans, m, n, alpha, a, lda, x, incx, beta, y, incy)
CGEMV
Definition cgemv.f:160
cgetrs
subroutine cgetrs(trans, n, nrhs, a, lda, ipiv, b, ldb, info)
CGETRS
Definition cgetrs.f:119
cla_geamv
subroutine cla_geamv(trans, m, n, alpha, a, lda, x, incx, beta, y, incy)
CLA_GEAMV computes a matrix-vector product using a general matrix to calculate error bounds.
Definition cla_geamv.f:176
cla_lin_berr
subroutine cla_lin_berr(n, nz, nrhs, res, ayb, berr)
CLA_LIN_BERR computes a component-wise relative backward error.
Definition cla_lin_berr.f:99
chla_transtype
character *1 function chla_transtype(trans)
CHLA_TRANSTYPE
Definition chla_transtype.f:56
cla_wwaddw
subroutine cla_wwaddw(n, x, y, w)
CLA_WWADDW adds a vector into a doubled-single vector.
Definition cla_wwaddw.f:79
slamch
real function slamch(cmach)
SLAMCH
Definition slamch.f:68
Here is the call graph for this function:
Here is the caller graph for this function: