cla_lin_berr()

subroutine cla_lin_berr	(	integer	n,
		integer	nz,
		integer	nrhs,
		complex, dimension( n, nrhs )	res,
		real, dimension( n, nrhs )	ayb,
		real, dimension( nrhs )	berr )

CLA_LIN_BERR computes a component-wise relative backward error.

Download CLA_LIN_BERR + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!>    CLA_LIN_BERR computes componentwise relative backward error from
!>    the formula
!>        max(i) ( abs(R(i)) / ( abs(op(A_s))*abs(Y) + abs(B_s) )(i) )
!>    where abs(Z) is the componentwise absolute value of the matrix
!>    or vector Z.
!> 

Parameters

[in]	N	!> N is INTEGER !> The number of linear equations, i.e., the order of the !> matrix A. N >= 0. !>
[in]	NZ	!> NZ is INTEGER !> We add (NZ+1)*SLAMCH( 'Safe minimum' ) to R(i) in the numerator to !> guard against spuriously zero residuals. Default value is N. !>
[in]	NRHS	!> NRHS is INTEGER !> The number of right hand sides, i.e., the number of columns !> of the matrices AYB, RES, and BERR. NRHS >= 0. !>
[in]	RES	!> RES is COMPLEX array, dimension (N,NRHS) !> The residual matrix, i.e., the matrix R in the relative backward !> error formula above. !>
[in]	AYB	!> AYB is REAL array, dimension (N, NRHS) !> The denominator in the relative backward error formula above, i.e., !> the matrix abs(op(A_s))*abs(Y) + abs(B_s). The matrices A, Y, and B !> are from iterative refinement (see cla_gerfsx_extended.f). !>
[out]	BERR	!> BERR is REAL array, dimension (NRHS) !> The componentwise relative backward error from the formula above. !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 98 of file cla_lin_berr.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            N, NZ, NRHS
*     ..
*     .. Array Arguments ..
      REAL               AYB( N, NRHS ), BERR( NRHS )
      COMPLEX            RES( N, NRHS )
*     ..
*
*  =====================================================================
*
*     .. Local Scalars ..
      REAL               TMP
      INTEGER            I, J
      COMPLEX            CDUM
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, real, aimag, max
*     ..
*     .. External Functions ..
      EXTERNAL           slamch
      REAL               SLAMCH
      REAL               SAFE1
*     ..
*     .. Statement Functions ..
      COMPLEX            CABS1
*     ..
*     .. Statement Function Definitions ..
      cabs1( cdum ) = abs( real( cdum ) ) + abs( aimag( cdum ) )
*     ..
*     .. Executable Statements ..
*
*     Adding SAFE1 to the numerator guards against spuriously zero
*     residuals.  A similar safeguard is in the CLA_yyAMV routine used
*     to compute AYB.
*
      safe1 = slamch( 'Safe minimum' )
      safe1 = (nz+1)*safe1
 
      DO j = 1, nrhs
         berr(j) = 0.0
         DO i = 1, n
            IF (ayb(i,j) .NE. 0.0) THEN
               tmp = (safe1 + cabs1(res(i,j)))/ayb(i,j)
               berr(j) = max( berr(j), tmp )
            END IF
*
*     If AYB is exactly 0.0 (and if computed by CLA_yyAMV), then we know
*     the true residual also must be exactly 0.0.
*
         END DO
      END DO
*
*     End of CLA_LIN_BERR
*

Here is the call graph for this function:

Here is the caller graph for this function: