cglmts()

subroutine cglmts	(	integer	n,
		integer	m,
		integer	p,
		complex, dimension( lda, * )	a,
		complex, dimension( lda, * )	af,
		integer	lda,
		complex, dimension( ldb, * )	b,
		complex, dimension( ldb, * )	bf,
		integer	ldb,
		complex, dimension( * )	d,
		complex, dimension( * )	df,
		complex, dimension( * )	x,
		complex, dimension( * )	u,
		complex, dimension( lwork )	work,
		integer	lwork,
		real, dimension( * )	rwork,
		real	result )

CGLMTS

Purpose:

!>
!> CGLMTS tests CGGGLM - a subroutine for solving the generalized
!> linear model problem.
!> 

Parameters

[in]	N	!> N is INTEGER !> The number of rows of the matrices A and B. N >= 0. !>
[in]	M	!> M is INTEGER !> The number of columns of the matrix A. M >= 0. !>
[in]	P	!> P is INTEGER !> The number of columns of the matrix B. P >= 0. !>
[in]	A	!> A is COMPLEX array, dimension (LDA,M) !> The N-by-M matrix A. !>
[out]	AF	!> AF is COMPLEX array, dimension (LDA,M) !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the arrays A, AF. LDA >= max(M,N). !>
[in]	B	!> B is COMPLEX array, dimension (LDB,P) !> The N-by-P matrix A. !>
[out]	BF	!> BF is COMPLEX array, dimension (LDB,P) !>
[in]	LDB	!> LDB is INTEGER !> The leading dimension of the arrays B, BF. LDB >= max(P,N). !>
[in]	D	!> D is COMPLEX array, dimension( N ) !> On input, the left hand side of the GLM. !>
[out]	DF	!> DF is COMPLEX array, dimension( N ) !>
[out]	X	!> X is COMPLEX array, dimension( M ) !> solution vector X in the GLM problem. !>
[out]	U	!> U is COMPLEX array, dimension( P ) !> solution vector U in the GLM problem. !>
[out]	WORK	!> WORK is COMPLEX array, dimension (LWORK) !>
[in]	LWORK	!> LWORK is INTEGER !> The dimension of the array WORK. !>
[out]	RWORK	!> RWORK is REAL array, dimension (M) !>
[out]	RESULT	!> RESULT is REAL !> The test ratio: !> norm( d - A*x - B*u ) !> RESULT = ----------------------------------------- !> (norm(A)+norm(B))*(norm(x)+norm(u))*EPS !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 148 of file cglmts.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            LDA, LDB, LWORK, M, P, N
      REAL               RESULT
*     ..
*     .. Array Arguments ..
      REAL               RWORK( * )
      COMPLEX            A( LDA, * ), AF( LDA, * ), B( LDB, * ),
     $                   BF( LDB, * ), D( * ), DF( * ), U( * ),
     $                   WORK( LWORK ), X( * )
*
*  ====================================================================
*
*     .. Parameters ..
      REAL               ZERO
      parameter( zero = 0.0e+0 )
      COMPLEX            CONE
      parameter( cone = 1.0e+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            INFO
      REAL               ANORM, BNORM, EPS, XNORM, YNORM, DNORM, UNFL
*     ..
*     .. External Functions ..
      REAL               SCASUM, SLAMCH, CLANGE
      EXTERNAL           scasum, slamch, clange
*     ..
*     .. External Subroutines ..
      EXTERNAL           clacpy
*
*     .. Intrinsic Functions ..
      INTRINSIC          max
*     ..
*     .. Executable Statements ..
*
      eps = slamch( 'Epsilon' )
      unfl = slamch( 'Safe minimum' )
      anorm = max( clange( '1', n, m, a, lda, rwork ), unfl )
      bnorm = max( clange( '1', n, p, b, ldb, rwork ), unfl )
*
*     Copy the matrices A and B to the arrays AF and BF,
*     and the vector D the array DF.
*
      CALL clacpy( 'Full', n, m, a, lda, af, lda )
      CALL clacpy( 'Full', n, p, b, ldb, bf, ldb )
      CALL ccopy( n, d, 1, df, 1 )
*
*     Solve GLM problem
*
      CALL cggglm( n, m, p, af, lda, bf, ldb, df, x, u, work, lwork,
     $             info )
*
*     Test the residual for the solution of LSE
*
*                       norm( d - A*x - B*u )
*       RESULT = -----------------------------------------
*                (norm(A)+norm(B))*(norm(x)+norm(u))*EPS
*
      CALL ccopy( n, d, 1, df, 1 )
      CALL cgemv( 'No transpose', n, m, -cone, a, lda, x, 1, cone,
     $            df, 1 )
*
      CALL cgemv( 'No transpose', n, p, -cone, b, ldb, u, 1, cone,
     $            df, 1 )
*
      dnorm = scasum( n, df, 1 )
      xnorm = scasum( m, x, 1 ) + scasum( p, u, 1 )
      ynorm = anorm + bnorm
*
      IF( xnorm.LE.zero ) THEN
         result = zero
      ELSE
         result =  ( ( dnorm / ynorm ) / xnorm ) /eps
      END IF
*
      RETURN
*
*     End of CGLMTS
*

Here is the call graph for this function:

Here is the caller graph for this function: