zlaein()

subroutine zlaein	(	logical	rightv,
		logical	noinit,
		integer	n,
		complex*16, dimension( ldh, * )	h,
		integer	ldh,
		complex*16	w,
		complex*16, dimension( * )	v,
		complex*16, dimension( ldb, * )	b,
		integer	ldb,
		double precision, dimension( * )	rwork,
		double precision	eps3,
		double precision	smlnum,
		integer	info )

ZLAEIN computes a specified right or left eigenvector of an upper Hessenberg matrix by inverse iteration.

Download ZLAEIN + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> ZLAEIN uses inverse iteration to find a right or left eigenvector
!> corresponding to the eigenvalue W of a complex upper Hessenberg
!> matrix H.
!> 

Parameters

[in]	RIGHTV	!> RIGHTV is LOGICAL !> = .TRUE. : compute right eigenvector; !> = .FALSE.: compute left eigenvector. !>
[in]	NOINIT	!> NOINIT is LOGICAL !> = .TRUE. : no initial vector supplied in V !> = .FALSE.: initial vector supplied in V. !>
[in]	N	!> N is INTEGER !> The order of the matrix H. N >= 0. !>
[in]	H	!> H is COMPLEX*16 array, dimension (LDH,N) !> The upper Hessenberg matrix H. !>
[in]	LDH	!> LDH is INTEGER !> The leading dimension of the array H. LDH >= max(1,N). !>
[in]	W	!> W is COMPLEX*16 !> The eigenvalue of H whose corresponding right or left !> eigenvector is to be computed. !>
[in,out]	V	!> V is COMPLEX*16 array, dimension (N) !> On entry, if NOINIT = .FALSE., V must contain a starting !> vector for inverse iteration; otherwise V need not be set. !> On exit, V contains the computed eigenvector, normalized so !> that the component of largest magnitude has magnitude 1; here !> the magnitude of a complex number (x,y) is taken to be !> |x| + |y|. !>
[out]	B	!> B is COMPLEX*16 array, dimension (LDB,N) !>
[in]	LDB	!> LDB is INTEGER !> The leading dimension of the array B. LDB >= max(1,N). !>
[out]	RWORK	!> RWORK is DOUBLE PRECISION array, dimension (N) !>
[in]	EPS3	!> EPS3 is DOUBLE PRECISION !> A small machine-dependent value which is used to perturb !> close eigenvalues, and to replace zero pivots. !>
[in]	SMLNUM	!> SMLNUM is DOUBLE PRECISION !> A machine-dependent value close to the underflow threshold. !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit !> = 1: inverse iteration did not converge; V is set to the !> last iterate. !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 145 of file zlaein.f.

*
*  -- LAPACK auxiliary routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      LOGICAL            NOINIT, RIGHTV
      INTEGER            INFO, LDB, LDH, N
      DOUBLE PRECISION   EPS3, SMLNUM
      COMPLEX*16         W
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   RWORK( * )
      COMPLEX*16         B( LDB, * ), H( LDH, * ), V( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ONE, TENTH
      parameter( one = 1.0d+0, tenth = 1.0d-1 )
      COMPLEX*16         ZERO
      parameter( zero = ( 0.0d+0, 0.0d+0 ) )
*     ..
*     .. Local Scalars ..
      CHARACTER          NORMIN, TRANS
      INTEGER            I, IERR, ITS, J
      DOUBLE PRECISION   GROWTO, NRMSML, ROOTN, RTEMP, SCALE, VNORM
      COMPLEX*16         CDUM, EI, EJ, TEMP, X
*     ..
*     .. External Functions ..
      INTEGER            IZAMAX
      DOUBLE PRECISION   DZASUM, DZNRM2
      COMPLEX*16         ZLADIV
      EXTERNAL           izamax, dzasum, dznrm2, zladiv
*     ..
*     .. External Subroutines ..
      EXTERNAL           zdscal, zlatrs
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, dble, dimag, max, sqrt
*     ..
*     .. Statement Functions ..
      DOUBLE PRECISION   CABS1
*     ..
*     .. Statement Function definitions ..
      cabs1( cdum ) = abs( dble( cdum ) ) + abs( dimag( cdum ) )
*     ..
*     .. Executable Statements ..
*
      info = 0
*
*     GROWTO is the threshold used in the acceptance test for an
*     eigenvector.
*
      rootn = sqrt( dble( n ) )
      growto = tenth / rootn
      nrmsml = max( one, eps3*rootn )*smlnum
*
*     Form B = H - W*I (except that the subdiagonal elements are not
*     stored).
*
      DO 20 j = 1, n
         DO 10 i = 1, j - 1
            b( i, j ) = h( i, j )
   10    CONTINUE
         b( j, j ) = h( j, j ) - w
   20 CONTINUE
*
      IF( noinit ) THEN
*
*        Initialize V.
*
         DO 30 i = 1, n
            v( i ) = eps3
   30    CONTINUE
      ELSE
*
*        Scale supplied initial vector.
*
         vnorm = dznrm2( n, v, 1 )
         CALL zdscal( n, ( eps3*rootn ) / max( vnorm, nrmsml ), v,
     $                1 )
      END IF
*
      IF( rightv ) THEN
*
*        LU decomposition with partial pivoting of B, replacing zero
*        pivots by EPS3.
*
         DO 60 i = 1, n - 1
            ei = h( i+1, i )
            IF( cabs1( b( i, i ) ).LT.cabs1( ei ) ) THEN
*
*              Interchange rows and eliminate.
*
               x = zladiv( b( i, i ), ei )
               b( i, i ) = ei
               DO 40 j = i + 1, n
                  temp = b( i+1, j )
                  b( i+1, j ) = b( i, j ) - x*temp
                  b( i, j ) = temp
   40          CONTINUE
            ELSE
*
*              Eliminate without interchange.
*
               IF( b( i, i ).EQ.zero )
     $            b( i, i ) = eps3
               x = zladiv( ei, b( i, i ) )
               IF( x.NE.zero ) THEN
                  DO 50 j = i + 1, n
                     b( i+1, j ) = b( i+1, j ) - x*b( i, j )
   50             CONTINUE
               END IF
            END IF
   60    CONTINUE
         IF( b( n, n ).EQ.zero )
     $      b( n, n ) = eps3
*
         trans = 'N'
*
      ELSE
*
*        UL decomposition with partial pivoting of B, replacing zero
*        pivots by EPS3.
*
         DO 90 j = n, 2, -1
            ej = h( j, j-1 )
            IF( cabs1( b( j, j ) ).LT.cabs1( ej ) ) THEN
*
*              Interchange columns and eliminate.
*
               x = zladiv( b( j, j ), ej )
               b( j, j ) = ej
               DO 70 i = 1, j - 1
                  temp = b( i, j-1 )
                  b( i, j-1 ) = b( i, j ) - x*temp
                  b( i, j ) = temp
   70          CONTINUE
            ELSE
*
*              Eliminate without interchange.
*
               IF( b( j, j ).EQ.zero )
     $            b( j, j ) = eps3
               x = zladiv( ej, b( j, j ) )
               IF( x.NE.zero ) THEN
                  DO 80 i = 1, j - 1
                     b( i, j-1 ) = b( i, j-1 ) - x*b( i, j )
   80             CONTINUE
               END IF
            END IF
   90    CONTINUE
         IF( b( 1, 1 ).EQ.zero )
     $      b( 1, 1 ) = eps3
*
         trans = 'C'
*
      END IF
*
      normin = 'N'
      DO 110 its = 1, n
*
*        Solve U*x = scale*v for a right eigenvector
*          or U**H *x = scale*v for a left eigenvector,
*        overwriting x on v.
*
         CALL zlatrs( 'Upper', trans, 'Nonunit', normin, n, b, ldb,
     $                v,
     $                scale, rwork, ierr )
         normin = 'Y'
*
*        Test for sufficient growth in the norm of v.
*
         vnorm = dzasum( n, v, 1 )
         IF( vnorm.GE.growto*scale )
     $      GO TO 120
*
*        Choose new orthogonal starting vector and try again.
*
         rtemp = eps3 / ( rootn+one )
         v( 1 ) = eps3
         DO 100 i = 2, n
            v( i ) = rtemp
  100    CONTINUE
         v( n-its+1 ) = v( n-its+1 ) - eps3*rootn
  110 CONTINUE
*
*     Failure to find eigenvector in N iterations.
*
      info = 1
*
  120 CONTINUE
*
*     Normalize eigenvector.
*
      i = izamax( n, v, 1 )
      CALL zdscal( n, one / cabs1( v( i ) ), v, 1 )
*
      RETURN
*
*     End of ZLAEIN
*

Here is the call graph for this function:

Here is the caller graph for this function: