zla_gerpvgrw()

double precision function zla_gerpvgrw	(	integer	n,
		integer	ncols,
		complex*16, dimension( lda, * )	a,
		integer	lda,
		complex*16, dimension( ldaf, * )	af,
		integer	ldaf )

ZLA_GERPVGRW multiplies a square real matrix by a complex matrix.

Download ZLA_GERPVGRW + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!>
!> ZLA_GERPVGRW computes the reciprocal pivot growth factor
!> norm(A)/norm(U). The  norm is used. If this is
!> much less than 1, the stability of the LU factorization of the
!> (equilibrated) matrix A could be poor. This also means that the
!> solution X, estimated condition numbers, and error bounds could be
!> unreliable.
!> 

Parameters

[in]	N	!> N is INTEGER !> The number of linear equations, i.e., the order of the !> matrix A. N >= 0. !>
[in]	NCOLS	!> NCOLS is INTEGER !> The number of columns of the matrix A. NCOLS >= 0. !>
[in]	A	!> A is COMPLEX*16 array, dimension (LDA,N) !> On entry, the N-by-N matrix A. !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the array A. LDA >= max(1,N). !>
[in]	AF	!> AF is COMPLEX*16 array, dimension (LDAF,N) !> The factors L and U from the factorization !> A = P*L*U as computed by ZGETRF. !>
[in]	LDAF	!> LDAF is INTEGER !> The leading dimension of the array AF. LDAF >= max(1,N). !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 96 of file zla_gerpvgrw.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            N, NCOLS, LDA, LDAF
*     ..
*     .. Array Arguments ..
      COMPLEX*16         A( LDA, * ), AF( LDAF, * )
*     ..
*
*  =====================================================================
*
*     .. Local Scalars ..
      INTEGER            I, J
      DOUBLE PRECISION   AMAX, UMAX, RPVGRW
      COMPLEX*16         ZDUM
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min, abs, real, dimag
*     ..
*     .. Statement Functions ..
      DOUBLE PRECISION   CABS1
*     ..
*     .. Statement Function Definitions ..
      cabs1( zdum ) = abs( dble( zdum ) ) + abs( dimag( zdum ) )
*     ..
*     .. Executable Statements ..
*
      rpvgrw = 1.0d+0
 
      DO j = 1, ncols
         amax = 0.0d+0
         umax = 0.0d+0
         DO i = 1, n
            amax = max( cabs1( a( i, j ) ), amax )
         END DO
         DO i = 1, j
            umax = max( cabs1( af( i, j ) ), umax )
         END DO
         IF ( umax /= 0.0d+0 ) THEN
            rpvgrw = min( amax / umax, rpvgrw )
         END IF
      END DO
      zla_gerpvgrw = rpvgrw
*
*     End of ZLA_GERPVGRW
*

Here is the call graph for this function:

Here is the caller graph for this function: