zggevx()

subroutine zggevx	(	character	balanc,
		character	jobvl,
		character	jobvr,
		character	sense,
		integer	n,
		complex*16, dimension( lda, * )	a,
		integer	lda,
		complex*16, dimension( ldb, * )	b,
		integer	ldb,
		complex*16, dimension( * )	alpha,
		complex*16, dimension( * )	beta,
		complex*16, dimension( ldvl, * )	vl,
		integer	ldvl,
		complex*16, dimension( ldvr, * )	vr,
		integer	ldvr,
		integer	ilo,
		integer	ihi,
		double precision, dimension( * )	lscale,
		double precision, dimension( * )	rscale,
		double precision	abnrm,
		double precision	bbnrm,
		double precision, dimension( * )	rconde,
		double precision, dimension( * )	rcondv,
		complex*16, dimension( * )	work,
		integer	lwork,
		double precision, dimension( * )	rwork,
		integer, dimension( * )	iwork,
		logical, dimension( * )	bwork,
		integer	info )

ZGGEVX computes the eigenvalues and, optionally, the left and/or right eigenvectors for GE matrices

Download ZGGEVX + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> ZGGEVX computes for a pair of N-by-N complex nonsymmetric matrices
!> (A,B) the generalized eigenvalues, and optionally, the left and/or
!> right generalized eigenvectors.
!>
!> Optionally, it also computes a balancing transformation to improve
!> the conditioning of the eigenvalues and eigenvectors (ILO, IHI,
!> LSCALE, RSCALE, ABNRM, and BBNRM), reciprocal condition numbers for
!> the eigenvalues (RCONDE), and reciprocal condition numbers for the
!> right eigenvectors (RCONDV).
!>
!> A generalized eigenvalue for a pair of matrices (A,B) is a scalar
!> lambda or a ratio alpha/beta = lambda, such that A - lambda*B is
!> singular. It is usually represented as the pair (alpha,beta), as
!> there is a reasonable interpretation for beta=0, and even for both
!> being zero.
!>
!> The right eigenvector v(j) corresponding to the eigenvalue lambda(j)
!> of (A,B) satisfies
!>                  A * v(j) = lambda(j) * B * v(j) .
!> The left eigenvector u(j) corresponding to the eigenvalue lambda(j)
!> of (A,B) satisfies
!>                  u(j)**H * A  = lambda(j) * u(j)**H * B.
!> where u(j)**H is the conjugate-transpose of u(j).
!>
!> 

Parameters

[in]	BALANC	!> BALANC is CHARACTER*1 !> Specifies the balance option to be performed: !> = 'N': do not diagonally scale or permute; !> = 'P': permute only; !> = 'S': scale only; !> = 'B': both permute and scale. !> Computed reciprocal condition numbers will be for the !> matrices after permuting and/or balancing. Permuting does !> not change condition numbers (in exact arithmetic), but !> balancing does. !>
[in]	JOBVL	!> JOBVL is CHARACTER*1 !> = 'N': do not compute the left generalized eigenvectors; !> = 'V': compute the left generalized eigenvectors. !>
[in]	JOBVR	!> JOBVR is CHARACTER*1 !> = 'N': do not compute the right generalized eigenvectors; !> = 'V': compute the right generalized eigenvectors. !>
[in]	SENSE	!> SENSE is CHARACTER*1 !> Determines which reciprocal condition numbers are computed. !> = 'N': none are computed; !> = 'E': computed for eigenvalues only; !> = 'V': computed for eigenvectors only; !> = 'B': computed for eigenvalues and eigenvectors. !>
[in]	N	!> N is INTEGER !> The order of the matrices A, B, VL, and VR. N >= 0. !>
[in,out]	A	!> A is COMPLEX*16 array, dimension (LDA, N) !> On entry, the matrix A in the pair (A,B). !> On exit, A has been overwritten. If JOBVL='V' or JOBVR='V' !> or both, then A contains the first part of the complex Schur !> form of the versions of the input A and B. !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of A. LDA >= max(1,N). !>
[in,out]	B	!> B is COMPLEX*16 array, dimension (LDB, N) !> On entry, the matrix B in the pair (A,B). !> On exit, B has been overwritten. If JOBVL='V' or JOBVR='V' !> or both, then B contains the second part of the complex !> Schur form of the versions of the input A and B. !>
[in]	LDB	!> LDB is INTEGER !> The leading dimension of B. LDB >= max(1,N). !>
[out]	ALPHA	!> ALPHA is COMPLEX*16 array, dimension (N) !>
[out]	BETA	!> BETA is COMPLEX*16 array, dimension (N) !> On exit, ALPHA(j)/BETA(j), j=1,...,N, will be the generalized !> eigenvalues. !> !> Note: the quotient ALPHA(j)/BETA(j) ) may easily over- or !> underflow, and BETA(j) may even be zero. Thus, the user !> should avoid naively computing the ratio ALPHA/BETA. !> However, ALPHA will be always less than and usually !> comparable with norm(A) in magnitude, and BETA always less !> than and usually comparable with norm(B). !>
[out]	VL	!> VL is COMPLEX*16 array, dimension (LDVL,N) !> If JOBVL = 'V', the left generalized eigenvectors u(j) are !> stored one after another in the columns of VL, in the same !> order as their eigenvalues. !> Each eigenvector will be scaled so the largest component !> will have abs(real part) + abs(imag. part) = 1. !> Not referenced if JOBVL = 'N'. !>
[in]	LDVL	!> LDVL is INTEGER !> The leading dimension of the matrix VL. LDVL >= 1, and !> if JOBVL = 'V', LDVL >= N. !>
[out]	VR	!> VR is COMPLEX*16 array, dimension (LDVR,N) !> If JOBVR = 'V', the right generalized eigenvectors v(j) are !> stored one after another in the columns of VR, in the same !> order as their eigenvalues. !> Each eigenvector will be scaled so the largest component !> will have abs(real part) + abs(imag. part) = 1. !> Not referenced if JOBVR = 'N'. !>
[in]	LDVR	!> LDVR is INTEGER !> The leading dimension of the matrix VR. LDVR >= 1, and !> if JOBVR = 'V', LDVR >= N. !>
[out]	ILO	!> ILO is INTEGER !>
[out]	IHI	!> IHI is INTEGER !> ILO and IHI are integer values such that on exit !> A(i,j) = 0 and B(i,j) = 0 if i > j and !> j = 1,...,ILO-1 or i = IHI+1,...,N. !> If BALANC = 'N' or 'S', ILO = 1 and IHI = N. !>
[out]	LSCALE	!> LSCALE is DOUBLE PRECISION array, dimension (N) !> Details of the permutations and scaling factors applied !> to the left side of A and B. If PL(j) is the index of the !> row interchanged with row j, and DL(j) is the scaling !> factor applied to row j, then !> LSCALE(j) = PL(j) for j = 1,...,ILO-1 !> = DL(j) for j = ILO,...,IHI !> = PL(j) for j = IHI+1,...,N. !> The order in which the interchanges are made is N to IHI+1, !> then 1 to ILO-1. !>
[out]	RSCALE	!> RSCALE is DOUBLE PRECISION array, dimension (N) !> Details of the permutations and scaling factors applied !> to the right side of A and B. If PR(j) is the index of the !> column interchanged with column j, and DR(j) is the scaling !> factor applied to column j, then !> RSCALE(j) = PR(j) for j = 1,...,ILO-1 !> = DR(j) for j = ILO,...,IHI !> = PR(j) for j = IHI+1,...,N !> The order in which the interchanges are made is N to IHI+1, !> then 1 to ILO-1. !>
[out]	ABNRM	!> ABNRM is DOUBLE PRECISION !> The one-norm of the balanced matrix A. !>
[out]	BBNRM	!> BBNRM is DOUBLE PRECISION !> The one-norm of the balanced matrix B. !>
[out]	RCONDE	!> RCONDE is DOUBLE PRECISION array, dimension (N) !> If SENSE = 'E' or 'B', the reciprocal condition numbers of !> the eigenvalues, stored in consecutive elements of the array. !> If SENSE = 'N' or 'V', RCONDE is not referenced. !>
[out]	RCONDV	!> RCONDV is DOUBLE PRECISION array, dimension (N) !> If JOB = 'V' or 'B', the estimated reciprocal condition !> numbers of the eigenvectors, stored in consecutive elements !> of the array. If the eigenvalues cannot be reordered to !> compute RCONDV(j), RCONDV(j) is set to 0; this can only occur !> when the true value would be very small anyway. !> If SENSE = 'N' or 'E', RCONDV is not referenced. !>
[out]	WORK	!> WORK is COMPLEX*16 array, dimension (MAX(1,LWORK)) !> On exit, if INFO = 0, WORK(1) returns the optimal LWORK. !>
[in]	LWORK	!> LWORK is INTEGER !> The dimension of the array WORK. LWORK >= max(1,2*N). !> If SENSE = 'E', LWORK >= max(1,4*N). !> If SENSE = 'V' or 'B', LWORK >= max(1,2*N*N+2*N). !> !> If LWORK = -1, then a workspace query is assumed; the routine !> only calculates the optimal size of the WORK array, returns !> this value as the first entry of the WORK array, and no error !> message related to LWORK is issued by XERBLA. !>
[out]	RWORK	!> RWORK is DOUBLE PRECISION array, dimension (lrwork) !> lrwork must be at least max(1,6*N) if BALANC = 'S' or 'B', !> and at least max(1,2*N) otherwise. !> Real workspace. !>
[out]	IWORK	!> IWORK is INTEGER array, dimension (N+2) !> If SENSE = 'E', IWORK is not referenced. !>
[out]	BWORK	!> BWORK is LOGICAL array, dimension (N) !> If SENSE = 'N', BWORK is not referenced. !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit !> < 0: if INFO = -i, the i-th argument had an illegal value. !> = 1,...,N: !> The QZ iteration failed. No eigenvectors have been !> calculated, but ALPHA(j) and BETA(j) should be correct !> for j=INFO+1,...,N. !> > N: =N+1: other than QZ iteration failed in ZHGEQZ. !> =N+2: error return from ZTGEVC. !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Further Details:

!>
!>  Balancing a matrix pair (A,B) includes, first, permuting rows and
!>  columns to isolate eigenvalues, second, applying diagonal similarity
!>  transformation to the rows and columns to make the rows and columns
!>  as close in norm as possible. The computed reciprocal condition
!>  numbers correspond to the balanced matrix. Permuting rows and columns
!>  will not change the condition numbers (in exact arithmetic) but
!>  diagonal scaling will.  For further explanation of balancing, see
!>  section 4.11.1.2 of LAPACK Users' Guide.
!>
!>  An approximate error bound on the chordal distance between the i-th
!>  computed generalized eigenvalue w and the corresponding exact
!>  eigenvalue lambda is
!>
!>       chord(w, lambda) <= EPS * norm(ABNRM, BBNRM) / RCONDE(I)
!>
!>  An approximate error bound for the angle between the i-th computed
!>  eigenvector VL(i) or VR(i) is given by
!>
!>       EPS * norm(ABNRM, BBNRM) / DIF(i).
!>
!>  For further explanation of the reciprocal condition numbers RCONDE
!>  and RCONDV, see section 4.11 of LAPACK User's Guide.
!> 

Definition at line 368 of file zggevx.f.

*
*  -- LAPACK driver routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          BALANC, JOBVL, JOBVR, SENSE
      INTEGER            IHI, ILO, INFO, LDA, LDB, LDVL, LDVR, LWORK, N
      DOUBLE PRECISION   ABNRM, BBNRM
*     ..
*     .. Array Arguments ..
      LOGICAL            BWORK( * )
      INTEGER            IWORK( * )
      DOUBLE PRECISION   LSCALE( * ), RCONDE( * ), RCONDV( * ),
     $                   RSCALE( * ), RWORK( * )
      COMPLEX*16         A( LDA, * ), ALPHA( * ), B( LDB, * ),
     $                   BETA( * ), VL( LDVL, * ), VR( LDVR, * ),
     $                   WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO, ONE
      parameter( zero = 0.0d+0, one = 1.0d+0 )
      COMPLEX*16         CZERO, CONE
      parameter( czero = ( 0.0d+0, 0.0d+0 ),
     $                   cone = ( 1.0d+0, 0.0d+0 ) )
*     ..
*     .. Local Scalars ..
      LOGICAL            ILASCL, ILBSCL, ILV, ILVL, ILVR, LQUERY, NOSCL,
     $                   WANTSB, WANTSE, WANTSN, WANTSV
      CHARACTER          CHTEMP
      INTEGER            I, ICOLS, IERR, IJOBVL, IJOBVR, IN, IROWS,
     $                   ITAU, IWRK, IWRK1, J, JC, JR, M, MAXWRK, MINWRK
      DOUBLE PRECISION   ANRM, ANRMTO, BIGNUM, BNRM, BNRMTO, EPS,
     $                   SMLNUM, TEMP
      COMPLEX*16         X
*     ..
*     .. Local Arrays ..
      LOGICAL            LDUMMA( 1 )
*     ..
*     .. External Subroutines ..
      EXTERNAL           dlascl, xerbla, zgeqrf, zggbak, zggbal,
     $                   zgghrd,
     $                   zhgeqz, zlacpy, zlascl, zlaset, ztgevc, ztgsna,
     $                   zungqr, zunmqr
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      INTEGER            ILAENV
      DOUBLE PRECISION   DLAMCH, ZLANGE
      EXTERNAL           lsame, ilaenv, dlamch, zlange
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, dble, dimag, max, sqrt
*     ..
*     .. Statement Functions ..
      DOUBLE PRECISION   ABS1
*     ..
*     .. Statement Function definitions ..
      abs1( x ) = abs( dble( x ) ) + abs( dimag( x ) )
*     ..
*     .. Executable Statements ..
*
*     Decode the input arguments
*
      IF( lsame( jobvl, 'N' ) ) THEN
         ijobvl = 1
         ilvl = .false.
      ELSE IF( lsame( jobvl, 'V' ) ) THEN
         ijobvl = 2
         ilvl = .true.
      ELSE
         ijobvl = -1
         ilvl = .false.
      END IF
*
      IF( lsame( jobvr, 'N' ) ) THEN
         ijobvr = 1
         ilvr = .false.
      ELSE IF( lsame( jobvr, 'V' ) ) THEN
         ijobvr = 2
         ilvr = .true.
      ELSE
         ijobvr = -1
         ilvr = .false.
      END IF
      ilv = ilvl .OR. ilvr
*
      noscl  = lsame( balanc, 'N' ) .OR. lsame( balanc, 'P' )
      wantsn = lsame( sense, 'N' )
      wantse = lsame( sense, 'E' )
      wantsv = lsame( sense, 'V' )
      wantsb = lsame( sense, 'B' )
*
*     Test the input arguments
*
      info = 0
      lquery = ( lwork.EQ.-1 )
      IF( .NOT.( noscl .OR. lsame( balanc,'S' ) .OR.
     $    lsame( balanc, 'B' ) ) ) THEN
         info = -1
      ELSE IF( ijobvl.LE.0 ) THEN
         info = -2
      ELSE IF( ijobvr.LE.0 ) THEN
         info = -3
      ELSE IF( .NOT.( wantsn .OR. wantse .OR. wantsb .OR. wantsv ) )
     $          THEN
         info = -4
      ELSE IF( n.LT.0 ) THEN
         info = -5
      ELSE IF( lda.LT.max( 1, n ) ) THEN
         info = -7
      ELSE IF( ldb.LT.max( 1, n ) ) THEN
         info = -9
      ELSE IF( ldvl.LT.1 .OR. ( ilvl .AND. ldvl.LT.n ) ) THEN
         info = -13
      ELSE IF( ldvr.LT.1 .OR. ( ilvr .AND. ldvr.LT.n ) ) THEN
         info = -15
      END IF
*
*     Compute workspace
*      (Note: Comments in the code beginning "Workspace:" describe the
*       minimal amount of workspace needed at that point in the code,
*       as well as the preferred amount for good performance.
*       NB refers to the optimal block size for the immediately
*       following subroutine, as returned by ILAENV. The workspace is
*       computed assuming ILO = 1 and IHI = N, the worst case.)
*
      IF( info.EQ.0 ) THEN
         IF( n.EQ.0 ) THEN
            minwrk = 1
            maxwrk = 1
         ELSE
            minwrk = 2*n
            IF( wantse ) THEN
               minwrk = 4*n
            ELSE IF( wantsv .OR. wantsb ) THEN
               minwrk = 2*n*( n + 1)
            END IF
            maxwrk = minwrk
            maxwrk = max( maxwrk,
     $                    n + n*ilaenv( 1, 'ZGEQRF', ' ', n, 1, n,
     $                                  0 ) )
            maxwrk = max( maxwrk,
     $                    n + n*ilaenv( 1, 'ZUNMQR', ' ', n, 1, n,
     $                                  0 ) )
            IF( ilvl ) THEN
               maxwrk = max( maxwrk, n +
     $                       n*ilaenv( 1, 'ZUNGQR', ' ', n, 1, n,
     $                                 0 ) )
            END IF
         END IF
         work( 1 ) = maxwrk
*
         IF( lwork.LT.minwrk .AND. .NOT.lquery ) THEN
            info = -25
         END IF
      END IF
*
      IF( info.NE.0 ) THEN
         CALL xerbla( 'ZGGEVX', -info )
         RETURN
      ELSE IF( lquery ) THEN
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 )
     $   RETURN
*
*     Get machine constants
*
      eps = dlamch( 'P' )
      smlnum = dlamch( 'S' )
      bignum = one / smlnum
      smlnum = sqrt( smlnum ) / eps
      bignum = one / smlnum
*
*     Scale A if max element outside range [SMLNUM,BIGNUM]
*
      anrm = zlange( 'M', n, n, a, lda, rwork )
      ilascl = .false.
      IF( anrm.GT.zero .AND. anrm.LT.smlnum ) THEN
         anrmto = smlnum
         ilascl = .true.
      ELSE IF( anrm.GT.bignum ) THEN
         anrmto = bignum
         ilascl = .true.
      END IF
      IF( ilascl )
     $   CALL zlascl( 'G', 0, 0, anrm, anrmto, n, n, a, lda, ierr )
*
*     Scale B if max element outside range [SMLNUM,BIGNUM]
*
      bnrm = zlange( 'M', n, n, b, ldb, rwork )
      ilbscl = .false.
      IF( bnrm.GT.zero .AND. bnrm.LT.smlnum ) THEN
         bnrmto = smlnum
         ilbscl = .true.
      ELSE IF( bnrm.GT.bignum ) THEN
         bnrmto = bignum
         ilbscl = .true.
      END IF
      IF( ilbscl )
     $   CALL zlascl( 'G', 0, 0, bnrm, bnrmto, n, n, b, ldb, ierr )
*
*     Permute and/or balance the matrix pair (A,B)
*     (Real Workspace: need 6*N if BALANC = 'S' or 'B', 1 otherwise)
*
      CALL zggbal( balanc, n, a, lda, b, ldb, ilo, ihi, lscale,
     $             rscale,
     $             rwork, ierr )
*
*     Compute ABNRM and BBNRM
*
      abnrm = zlange( '1', n, n, a, lda, rwork( 1 ) )
      IF( ilascl ) THEN
         rwork( 1 ) = abnrm
         CALL dlascl( 'G', 0, 0, anrmto, anrm, 1, 1, rwork( 1 ), 1,
     $                ierr )
         abnrm = rwork( 1 )
      END IF
*
      bbnrm = zlange( '1', n, n, b, ldb, rwork( 1 ) )
      IF( ilbscl ) THEN
         rwork( 1 ) = bbnrm
         CALL dlascl( 'G', 0, 0, bnrmto, bnrm, 1, 1, rwork( 1 ), 1,
     $                ierr )
         bbnrm = rwork( 1 )
      END IF
*
*     Reduce B to triangular form (QR decomposition of B)
*     (Complex Workspace: need N, prefer N*NB )
*
      irows = ihi + 1 - ilo
      IF( ilv .OR. .NOT.wantsn ) THEN
         icols = n + 1 - ilo
      ELSE
         icols = irows
      END IF
      itau = 1
      iwrk = itau + irows
      CALL zgeqrf( irows, icols, b( ilo, ilo ), ldb, work( itau ),
     $             work( iwrk ), lwork+1-iwrk, ierr )
*
*     Apply the unitary transformation to A
*     (Complex Workspace: need N, prefer N*NB)
*
      CALL zunmqr( 'L', 'C', irows, icols, irows, b( ilo, ilo ), ldb,
     $             work( itau ), a( ilo, ilo ), lda, work( iwrk ),
     $             lwork+1-iwrk, ierr )
*
*     Initialize VL and/or VR
*     (Workspace: need N, prefer N*NB)
*
      IF( ilvl ) THEN
         CALL zlaset( 'Full', n, n, czero, cone, vl, ldvl )
         IF( irows.GT.1 ) THEN
            CALL zlacpy( 'L', irows-1, irows-1, b( ilo+1, ilo ), ldb,
     $                   vl( ilo+1, ilo ), ldvl )
         END IF
         CALL zungqr( irows, irows, irows, vl( ilo, ilo ), ldvl,
     $                work( itau ), work( iwrk ), lwork+1-iwrk, ierr )
      END IF
*
      IF( ilvr )
     $   CALL zlaset( 'Full', n, n, czero, cone, vr, ldvr )
*
*     Reduce to generalized Hessenberg form
*     (Workspace: none needed)
*
      IF( ilv .OR. .NOT.wantsn ) THEN
*
*        Eigenvectors requested -- work on whole matrix.
*
         CALL zgghrd( jobvl, jobvr, n, ilo, ihi, a, lda, b, ldb, vl,
     $                ldvl, vr, ldvr, ierr )
      ELSE
         CALL zgghrd( 'N', 'N', irows, 1, irows, a( ilo, ilo ), lda,
     $                b( ilo, ilo ), ldb, vl, ldvl, vr, ldvr, ierr )
      END IF
*
*     Perform QZ algorithm (Compute eigenvalues, and optionally, the
*     Schur forms and Schur vectors)
*     (Complex Workspace: need N)
*     (Real Workspace: need N)
*
      iwrk = itau
      IF( ilv .OR. .NOT.wantsn ) THEN
         chtemp = 'S'
      ELSE
         chtemp = 'E'
      END IF
*
      CALL zhgeqz( chtemp, jobvl, jobvr, n, ilo, ihi, a, lda, b, ldb,
     $             alpha, beta, vl, ldvl, vr, ldvr, work( iwrk ),
     $             lwork+1-iwrk, rwork, ierr )
      IF( ierr.NE.0 ) THEN
         IF( ierr.GT.0 .AND. ierr.LE.n ) THEN
            info = ierr
         ELSE IF( ierr.GT.n .AND. ierr.LE.2*n ) THEN
            info = ierr - n
         ELSE
            info = n + 1
         END IF
         GO TO 90
      END IF
*
*     Compute Eigenvectors and estimate condition numbers if desired
*     ZTGEVC: (Complex Workspace: need 2*N )
*             (Real Workspace:    need 2*N )
*     ZTGSNA: (Complex Workspace: need 2*N*N if SENSE='V' or 'B')
*             (Integer Workspace: need N+2 )
*
      IF( ilv .OR. .NOT.wantsn ) THEN
         IF( ilv ) THEN
            IF( ilvl ) THEN
               IF( ilvr ) THEN
                  chtemp = 'B'
               ELSE
                  chtemp = 'L'
               END IF
            ELSE
               chtemp = 'R'
            END IF
*
            CALL ztgevc( chtemp, 'B', ldumma, n, a, lda, b, ldb, vl,
     $                   ldvl, vr, ldvr, n, in, work( iwrk ), rwork,
     $                   ierr )
            IF( ierr.NE.0 ) THEN
               info = n + 2
               GO TO 90
            END IF
         END IF
*
         IF( .NOT.wantsn ) THEN
*
*           compute eigenvectors (ZTGEVC) and estimate condition
*           numbers (ZTGSNA). Note that the definition of the condition
*           number is not invariant under transformation (u,v) to
*           (Q*u, Z*v), where (u,v) are eigenvectors of the generalized
*           Schur form (S,T), Q and Z are orthogonal matrices. In order
*           to avoid using extra 2*N*N workspace, we have to
*           re-calculate eigenvectors and estimate the condition numbers
*           one at a time.
*
            DO 20 i = 1, n
*
               DO 10 j = 1, n
                  bwork( j ) = .false.
   10          CONTINUE
               bwork( i ) = .true.
*
               iwrk = n + 1
               iwrk1 = iwrk + n
*
               IF( wantse .OR. wantsb ) THEN
                  CALL ztgevc( 'B', 'S', bwork, n, a, lda, b, ldb,
     $                         work( 1 ), n, work( iwrk ), n, 1, m,
     $                         work( iwrk1 ), rwork, ierr )
                  IF( ierr.NE.0 ) THEN
                     info = n + 2
                     GO TO 90
                  END IF
               END IF
*
               CALL ztgsna( sense, 'S', bwork, n, a, lda, b, ldb,
     $                      work( 1 ), n, work( iwrk ), n, rconde( i ),
     $                      rcondv( i ), 1, m, work( iwrk1 ),
     $                      lwork-iwrk1+1, iwork, ierr )
*
   20       CONTINUE
         END IF
      END IF
*
*     Undo balancing on VL and VR and normalization
*     (Workspace: none needed)
*
      IF( ilvl ) THEN
         CALL zggbak( balanc, 'L', n, ilo, ihi, lscale, rscale, n,
     $                vl,
     $                ldvl, ierr )
*
         DO 50 jc = 1, n
            temp = zero
            DO 30 jr = 1, n
               temp = max( temp, abs1( vl( jr, jc ) ) )
   30       CONTINUE
            IF( temp.LT.smlnum )
     $         GO TO 50
            temp = one / temp
            DO 40 jr = 1, n
               vl( jr, jc ) = vl( jr, jc )*temp
   40       CONTINUE
   50    CONTINUE
      END IF
*
      IF( ilvr ) THEN
         CALL zggbak( balanc, 'R', n, ilo, ihi, lscale, rscale, n,
     $                vr,
     $                ldvr, ierr )
         DO 80 jc = 1, n
            temp = zero
            DO 60 jr = 1, n
               temp = max( temp, abs1( vr( jr, jc ) ) )
   60       CONTINUE
            IF( temp.LT.smlnum )
     $         GO TO 80
            temp = one / temp
            DO 70 jr = 1, n
               vr( jr, jc ) = vr( jr, jc )*temp
   70       CONTINUE
   80    CONTINUE
      END IF
*
*     Undo scaling if necessary
*
   90 CONTINUE
*
      IF( ilascl )
     $   CALL zlascl( 'G', 0, 0, anrmto, anrm, n, 1, alpha, n, ierr )
*
      IF( ilbscl )
     $   CALL zlascl( 'G', 0, 0, bnrmto, bnrm, n, 1, beta, n, ierr )
*
      work( 1 ) = maxwrk
      RETURN
*
*     End of ZGGEVX
*

Here is the call graph for this function:

Here is the caller graph for this function: