cgbt01()

subroutine cgbt01	(	integer	m,
		integer	n,
		integer	kl,
		integer	ku,
		complex, dimension( lda, * )	a,
		integer	lda,
		complex, dimension( ldafac, * )	afac,
		integer	ldafac,
		integer, dimension( * )	ipiv,
		complex, dimension( * )	work,
		real	resid )

CGBT01

Purpose:

!>
!> CGBT01 reconstructs a band matrix A from its L*U factorization and
!> computes the residual:
!>    norm(L*U - A) / ( N * norm(A) * EPS ),
!> where EPS is the machine epsilon.
!>
!> The expression L*U - A is computed one column at a time, so A and
!> AFAC are not modified.
!> 

Parameters

[in]	M	!> M is INTEGER !> The number of rows of the matrix A. M >= 0. !>
[in]	N	!> N is INTEGER !> The number of columns of the matrix A. N >= 0. !>
[in]	KL	!> KL is INTEGER !> The number of subdiagonals within the band of A. KL >= 0. !>
[in]	KU	!> KU is INTEGER !> The number of superdiagonals within the band of A. KU >= 0. !>
[in,out]	A	!> A is COMPLEX array, dimension (LDA,N) !> The original matrix A in band storage, stored in rows 1 to !> KL+KU+1. !>
[in]	LDA	!> LDA is INTEGER. !> The leading dimension of the array A. LDA >= max(1,KL+KU+1). !>
[in]	AFAC	!> AFAC is COMPLEX array, dimension (LDAFAC,N) !> The factored form of the matrix A. AFAC contains the banded !> factors L and U from the L*U factorization, as computed by !> CGBTRF. U is stored as an upper triangular band matrix with !> KL+KU superdiagonals in rows 1 to KL+KU+1, and the !> multipliers used during the factorization are stored in rows !> KL+KU+2 to 2*KL+KU+1. See CGBTRF for further details. !>
[in]	LDAFAC	!> LDAFAC is INTEGER !> The leading dimension of the array AFAC. !> LDAFAC >= max(1,2*KL*KU+1). !>
[in]	IPIV	!> IPIV is INTEGER array, dimension (min(M,N)) !> The pivot indices from CGBTRF. !>
[out]	WORK	!> WORK is COMPLEX array, dimension (2*KL+KU+1) !>
[out]	RESID	!> RESID is REAL !> norm(L*U - A) / ( N * norm(A) * EPS ) !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 124 of file cgbt01.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            KL, KU, LDA, LDAFAC, M, N
      REAL               RESID
*     ..
*     .. Array Arguments ..
      INTEGER            IPIV( * )
      COMPLEX            A( LDA, * ), AFAC( LDAFAC, * ), WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ZERO, ONE
      parameter( zero = 0.0e+0, one = 1.0e+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, I1, I2, IL, IP, IW, J, JL, JU, JUA, KD, LENJ
      REAL               ANORM, EPS
      COMPLEX            T
*     ..
*     .. External Functions ..
      REAL               SCASUM, SLAMCH
      EXTERNAL           scasum, slamch
*     ..
*     .. External Subroutines ..
      EXTERNAL           caxpy, ccopy
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          cmplx, max, min, real
*     ..
*     .. Executable Statements ..
*
*     Quick exit if M = 0 or N = 0.
*
      resid = zero
      IF( m.LE.0 .OR. n.LE.0 )
     $   RETURN
*
*     Determine EPS and the norm of A.
*
      eps = slamch( 'Epsilon' )
      kd = ku + 1
      anorm = zero
      DO 10 j = 1, n
         i1 = max( kd+1-j, 1 )
         i2 = min( kd+m-j, kl+kd )
         IF( i2.GE.i1 )
     $      anorm = max( anorm, scasum( i2-i1+1, a( i1, j ), 1 ) )
   10 CONTINUE
*
*     Compute one column at a time of L*U - A.
*
      kd = kl + ku + 1
      DO 40 j = 1, n
*
*        Copy the J-th column of U to WORK.
*
         ju = min( kl+ku, j-1 )
         jl = min( kl, m-j )
         lenj = min( m, j ) - j + ju + 1
         IF( lenj.GT.0 ) THEN
            CALL ccopy( lenj, afac( kd-ju, j ), 1, work, 1 )
            DO 20 i = lenj + 1, ju + jl + 1
               work( i ) = zero
   20       CONTINUE
*
*           Multiply by the unit lower triangular matrix L.  Note that L
*           is stored as a product of transformations and permutations.
*
            DO 30 i = min( m-1, j ), j - ju, -1
               il = min( kl, m-i )
               IF( il.GT.0 ) THEN
                  iw = i - j + ju + 1
                  t = work( iw )
                  CALL caxpy( il, t, afac( kd+1, i ), 1, work( iw+1 ),
     $                        1 )
                  ip = ipiv( i )
                  IF( i.NE.ip ) THEN
                     ip = ip - j + ju + 1
                     work( iw ) = work( ip )
                     work( ip ) = t
                  END IF
               END IF
   30       CONTINUE
*
*           Subtract the corresponding column of A.
*
            jua = min( ju, ku )
            IF( jua+jl+1.GT.0 )
     $         CALL caxpy( jua+jl+1, -cmplx( one ), a( ku+1-jua, j ), 1,
     $                     work( ju+1-jua ), 1 )
*
*           Compute the 1-norm of the column.
*
            resid = max( resid, scasum( ju+jl+1, work, 1 ) )
         END IF
   40 CONTINUE
*
*     Compute norm(L*U - A) / ( N * norm(A) * EPS )
*
      IF( anorm.LE.zero ) THEN
         IF( resid.NE.zero )
     $      resid = one / eps
      ELSE
         resid = ( ( resid / real( n ) ) / anorm ) / eps
      END IF
*
      RETURN
*
*     End of CGBT01
*

Here is the call graph for this function:

Here is the caller graph for this function: