LAPACK 3.12.1
LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches

◆ csysvx()

subroutine csysvx ( character fact,
character uplo,
integer n,
integer nrhs,
complex, dimension( lda, * ) a,
integer lda,
complex, dimension( ldaf, * ) af,
integer ldaf,
integer, dimension( * ) ipiv,
complex, dimension( ldb, * ) b,
integer ldb,
complex, dimension( ldx, * ) x,
integer ldx,
real rcond,
real, dimension( * ) ferr,
real, dimension( * ) berr,
complex, dimension( * ) work,
integer lwork,
real, dimension( * ) rwork,
integer info )

CSYSVX computes the solution to system of linear equations A * X = B for SY matrices

Download CSYSVX + dependencies [TGZ] [ZIP] [TXT]

Purpose:
!>
!> CSYSVX uses the diagonal pivoting factorization to compute the
!> solution to a complex system of linear equations A * X = B,
!> where A is an N-by-N symmetric matrix and X and B are N-by-NRHS
!> matrices.
!>
!> Error bounds on the solution and a condition estimate are also
!> provided.
!>
Description:
!>
!> The following steps are performed:
!>
!> 1. If FACT = 'N', the diagonal pivoting method is used to factor A.
!>    The form of the factorization is
!>       A = U * D * U**T,  if UPLO = 'U', or
!>       A = L * D * L**T,  if UPLO = 'L',
!>    where U (or L) is a product of permutation and unit upper (lower)
!>    triangular matrices, and D is symmetric and block diagonal with
!>    1-by-1 and 2-by-2 diagonal blocks.
!>
!> 2. If some D(i,i)=0, so that D is exactly singular, then the routine
!>    returns with INFO = i. Otherwise, the factored form of A is used
!>    to estimate the condition number of the matrix A.  If the
!>    reciprocal of the condition number is less than machine precision,
!>    INFO = N+1 is returned as a warning, but the routine still goes on
!>    to solve for X and compute error bounds as described below.
!>
!> 3. The system of equations is solved for X using the factored form
!>    of A.
!>
!> 4. Iterative refinement is applied to improve the computed solution
!>    matrix and calculate error bounds and backward error estimates
!>    for it.
!>
Parameters
[in]FACT
!>          FACT is CHARACTER*1
!>          Specifies whether or not the factored form of A has been
!>          supplied on entry.
!>          = 'F':  On entry, AF and IPIV contain the factored form
!>                  of A.  A, AF and IPIV will not be modified.
!>          = 'N':  The matrix A will be copied to AF and factored.
!>
[in]UPLO
!>          UPLO is CHARACTER*1
!>          = 'U':  Upper triangle of A is stored;
!>          = 'L':  Lower triangle of A is stored.
!>
[in]N
!>          N is INTEGER
!>          The number of linear equations, i.e., the order of the
!>          matrix A.  N >= 0.
!>
[in]NRHS
!>          NRHS is INTEGER
!>          The number of right hand sides, i.e., the number of columns
!>          of the matrices B and X.  NRHS >= 0.
!>
[in]A
!>          A is COMPLEX array, dimension (LDA,N)
!>          The symmetric matrix A.  If UPLO = 'U', the leading N-by-N
!>          upper triangular part of A contains the upper triangular part
!>          of the matrix A, and the strictly lower triangular part of A
!>          is not referenced.  If UPLO = 'L', the leading N-by-N lower
!>          triangular part of A contains the lower triangular part of
!>          the matrix A, and the strictly upper triangular part of A is
!>          not referenced.
!>
[in]LDA
!>          LDA is INTEGER
!>          The leading dimension of the array A.  LDA >= max(1,N).
!>
[in,out]AF
!>          AF is COMPLEX array, dimension (LDAF,N)
!>          If FACT = 'F', then AF is an input argument and on entry
!>          contains the block diagonal matrix D and the multipliers used
!>          to obtain the factor U or L from the factorization
!>          A = U*D*U**T or A = L*D*L**T as computed by CSYTRF.
!>
!>          If FACT = 'N', then AF is an output argument and on exit
!>          returns the block diagonal matrix D and the multipliers used
!>          to obtain the factor U or L from the factorization
!>          A = U*D*U**T or A = L*D*L**T.
!>
[in]LDAF
!>          LDAF is INTEGER
!>          The leading dimension of the array AF.  LDAF >= max(1,N).
!>
[in,out]IPIV
!>          IPIV is INTEGER array, dimension (N)
!>          If FACT = 'F', then IPIV is an input argument and on entry
!>          contains details of the interchanges and the block structure
!>          of D, as determined by CSYTRF.
!>          If IPIV(k) > 0, then rows and columns k and IPIV(k) were
!>          interchanged and D(k,k) is a 1-by-1 diagonal block.
!>          If UPLO = 'U' and IPIV(k) = IPIV(k-1) < 0, then rows and
!>          columns k-1 and -IPIV(k) were interchanged and D(k-1:k,k-1:k)
!>          is a 2-by-2 diagonal block.  If UPLO = 'L' and IPIV(k) =
!>          IPIV(k+1) < 0, then rows and columns k+1 and -IPIV(k) were
!>          interchanged and D(k:k+1,k:k+1) is a 2-by-2 diagonal block.
!>
!>          If FACT = 'N', then IPIV is an output argument and on exit
!>          contains details of the interchanges and the block structure
!>          of D, as determined by CSYTRF.
!>
[in]B
!>          B is COMPLEX array, dimension (LDB,NRHS)
!>          The N-by-NRHS right hand side matrix B.
!>
[in]LDB
!>          LDB is INTEGER
!>          The leading dimension of the array B.  LDB >= max(1,N).
!>
[out]X
!>          X is COMPLEX array, dimension (LDX,NRHS)
!>          If INFO = 0 or INFO = N+1, the N-by-NRHS solution matrix X.
!>
[in]LDX
!>          LDX is INTEGER
!>          The leading dimension of the array X.  LDX >= max(1,N).
!>
[out]RCOND
!>          RCOND is REAL
!>          The estimate of the reciprocal condition number of the matrix
!>          A.  If RCOND is less than the machine precision (in
!>          particular, if RCOND = 0), the matrix is singular to working
!>          precision.  This condition is indicated by a return code of
!>          INFO > 0.
!>
[out]FERR
!>          FERR is REAL array, dimension (NRHS)
!>          The estimated forward error bound for each solution vector
!>          X(j) (the j-th column of the solution matrix X).
!>          If XTRUE is the true solution corresponding to X(j), FERR(j)
!>          is an estimated upper bound for the magnitude of the largest
!>          element in (X(j) - XTRUE) divided by the magnitude of the
!>          largest element in X(j).  The estimate is as reliable as
!>          the estimate for RCOND, and is almost always a slight
!>          overestimate of the true error.
!>
[out]BERR
!>          BERR is REAL array, dimension (NRHS)
!>          The componentwise relative backward error of each solution
!>          vector X(j) (i.e., the smallest relative change in
!>          any element of A or B that makes X(j) an exact solution).
!>
[out]WORK
!>          WORK is COMPLEX array, dimension (MAX(1,LWORK))
!>          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
!>
[in]LWORK
!>          LWORK is INTEGER
!>          The length of WORK.  LWORK >= max(1,2*N), and for best
!>          performance, when FACT = 'N', LWORK >= max(1,2*N,N*NB), where
!>          NB is the optimal blocksize for CSYTRF.
!>
!>          If LWORK = -1, then a workspace query is assumed; the routine
!>          only calculates the optimal size of the WORK array, returns
!>          this value as the first entry of the WORK array, and no error
!>          message related to LWORK is issued by XERBLA.
!>
[out]RWORK
!>          RWORK is REAL array, dimension (N)
!>
[out]INFO
!>          INFO is INTEGER
!>          = 0: successful exit
!>          < 0: if INFO = -i, the i-th argument had an illegal value
!>          > 0: if INFO = i, and i is
!>                <= N:  D(i,i) is exactly zero.  The factorization
!>                       has been completed but the factor D is exactly
!>                       singular, so the solution and error bounds could
!>                       not be computed. RCOND = 0 is returned.
!>                = N+1: D is nonsingular, but RCOND is less than machine
!>                       precision, meaning that the matrix is singular
!>                       to working precision.  Nevertheless, the
!>                       solution and error bounds are computed because
!>                       there are a number of situations where the
!>                       computed solution can be more accurate than the
!>                       value of RCOND would suggest.
!>
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.

Definition at line 280 of file csysvx.f.

284*
285* -- LAPACK driver routine --
286* -- LAPACK is a software package provided by Univ. of Tennessee, --
287* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
288*
289* .. Scalar Arguments ..
290 CHARACTER FACT, UPLO
291 INTEGER INFO, LDA, LDAF, LDB, LDX, LWORK, N, NRHS
292 REAL RCOND
293* ..
294* .. Array Arguments ..
295 INTEGER IPIV( * )
296 REAL BERR( * ), FERR( * ), RWORK( * )
297 COMPLEX A( LDA, * ), AF( LDAF, * ), B( LDB, * ),
298 $ WORK( * ), X( LDX, * )
299* ..
300*
301* =====================================================================
302*
303* .. Parameters ..
304 REAL ZERO
305 parameter( zero = 0.0e+0 )
306* ..
307* .. Local Scalars ..
308 LOGICAL LQUERY, NOFACT
309 INTEGER LWKOPT, NB
310 REAL ANORM
311* ..
312* .. External Functions ..
313 LOGICAL LSAME
314 INTEGER ILAENV
315 REAL CLANSY, SLAMCH, SROUNDUP_LWORK
316 EXTERNAL ilaenv, lsame, clansy, slamch,
317 $ sroundup_lwork
318* ..
319* .. External Subroutines ..
320 EXTERNAL clacpy, csycon, csyrfs, csytrf, csytrs,
321 $ xerbla
322* ..
323* .. Intrinsic Functions ..
324 INTRINSIC max
325* ..
326* .. Executable Statements ..
327*
328* Test the input parameters.
329*
330 info = 0
331 nofact = lsame( fact, 'N' )
332 lquery = ( lwork.EQ.-1 )
333 IF( .NOT.nofact .AND. .NOT.lsame( fact, 'F' ) ) THEN
334 info = -1
335 ELSE IF( .NOT.lsame( uplo, 'U' ) .AND.
336 $ .NOT.lsame( uplo, 'L' ) )
337 $ THEN
338 info = -2
339 ELSE IF( n.LT.0 ) THEN
340 info = -3
341 ELSE IF( nrhs.LT.0 ) THEN
342 info = -4
343 ELSE IF( lda.LT.max( 1, n ) ) THEN
344 info = -6
345 ELSE IF( ldaf.LT.max( 1, n ) ) THEN
346 info = -8
347 ELSE IF( ldb.LT.max( 1, n ) ) THEN
348 info = -11
349 ELSE IF( ldx.LT.max( 1, n ) ) THEN
350 info = -13
351 ELSE IF( lwork.LT.max( 1, 2*n ) .AND. .NOT.lquery ) THEN
352 info = -18
353 END IF
354*
355 IF( info.EQ.0 ) THEN
356 lwkopt = max( 1, 2*n )
357 IF( nofact ) THEN
358 nb = ilaenv( 1, 'CSYTRF', uplo, n, -1, -1, -1 )
359 lwkopt = max( lwkopt, n*nb )
360 END IF
361 work( 1 ) = sroundup_lwork(lwkopt)
362 END IF
363*
364 IF( info.NE.0 ) THEN
365 CALL xerbla( 'CSYSVX', -info )
366 RETURN
367 ELSE IF( lquery ) THEN
368 RETURN
369 END IF
370*
371 IF( nofact ) THEN
372*
373* Compute the factorization A = U*D*U**T or A = L*D*L**T.
374*
375 CALL clacpy( uplo, n, n, a, lda, af, ldaf )
376 CALL csytrf( uplo, n, af, ldaf, ipiv, work, lwork, info )
377*
378* Return if INFO is non-zero.
379*
380 IF( info.GT.0 )THEN
381 rcond = zero
382 RETURN
383 END IF
384 END IF
385*
386* Compute the norm of the matrix A.
387*
388 anorm = clansy( 'I', uplo, n, a, lda, rwork )
389*
390* Compute the reciprocal of the condition number of A.
391*
392 CALL csycon( uplo, n, af, ldaf, ipiv, anorm, rcond, work,
393 $ info )
394*
395* Compute the solution vectors X.
396*
397 CALL clacpy( 'Full', n, nrhs, b, ldb, x, ldx )
398 CALL csytrs( uplo, n, nrhs, af, ldaf, ipiv, x, ldx, info )
399*
400* Use iterative refinement to improve the computed solutions and
401* compute error bounds and backward error estimates for them.
402*
403 CALL csyrfs( uplo, n, nrhs, a, lda, af, ldaf, ipiv, b, ldb, x,
404 $ ldx, ferr, berr, work, rwork, info )
405*
406* Set INFO = N+1 if the matrix is singular to working precision.
407*
408 IF( rcond.LT.slamch( 'Epsilon' ) )
409 $ info = n + 1
410*
411 work( 1 ) = sroundup_lwork(lwkopt)
412*
413 RETURN
414*
415* End of CSYSVX
416*
xerbla
subroutine xerbla(srname, info)
Definition cblat2.f:3285
csycon
subroutine csycon(uplo, n, a, lda, ipiv, anorm, rcond, work, info)
CSYCON
Definition csycon.f:123
csyrfs
subroutine csyrfs(uplo, n, nrhs, a, lda, af, ldaf, ipiv, b, ldb, x, ldx, ferr, berr, work, rwork, info)
CSYRFS
Definition csyrfs.f:191
csytrf
subroutine csytrf(uplo, n, a, lda, ipiv, work, lwork, info)
CSYTRF
Definition csytrf.f:180
csytrs
subroutine csytrs(uplo, n, nrhs, a, lda, ipiv, b, ldb, info)
CSYTRS
Definition csytrs.f:118
ilaenv
integer function ilaenv(ispec, name, opts, n1, n2, n3, n4)
ILAENV
Definition ilaenv.f:160
clacpy
subroutine clacpy(uplo, m, n, a, lda, b, ldb)
CLACPY copies all or part of one two-dimensional array to another.
Definition clacpy.f:101
slamch
real function slamch(cmach)
SLAMCH
Definition slamch.f:68
clansy
real function clansy(norm, uplo, n, a, lda, work)
CLANSY returns the value of the 1-norm, or the Frobenius norm, or the infinity norm,...
Definition clansy.f:121
lsame
logical function lsame(ca, cb)
LSAME
Definition lsame.f:48
sroundup_lwork
real function sroundup_lwork(lwork)
SROUNDUP_LWORK
Definition sroundup_lwork.f:59
Here is the call graph for this function:
Here is the caller graph for this function: