zgelqs()

subroutine zgelqs	(	integer	m,
		integer	n,
		integer	nrhs,
		complex*16, dimension( lda, * )	a,
		integer	lda,
		complex*16, dimension( * )	tau,
		complex*16, dimension( ldb, * )	b,
		integer	ldb,
		complex*16, dimension( lwork )	work,
		integer	lwork,
		integer	info )

ZGELQS

Purpose:

!>
!> Compute a minimum-norm solution
!>     min || A*X - B ||
!> using the LQ factorization
!>     A = L*Q
!> computed by ZGELQF.
!> 

Parameters

[in]	M	!> M is INTEGER !> The number of rows of the matrix A. M >= 0. !>
[in]	N	!> N is INTEGER !> The number of columns of the matrix A. N >= M >= 0. !>
[in]	NRHS	!> NRHS is INTEGER !> The number of columns of B. NRHS >= 0. !>
[in]	A	!> A is COMPLEX*16 array, dimension (LDA,N) !> Details of the LQ factorization of the original matrix A as !> returned by ZGELQF. !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the array A. LDA >= M. !>
[in]	TAU	!> TAU is COMPLEX*16 array, dimension (M) !> Details of the orthogonal matrix Q. !>
[in,out]	B	!> B is COMPLEX*16 array, dimension (LDB,NRHS) !> On entry, the m-by-nrhs right hand side matrix B. !> On exit, the n-by-nrhs solution matrix X. !>
[in]	LDB	!> LDB is INTEGER !> The leading dimension of the array B. LDB >= N. !>
[out]	WORK	!> WORK is COMPLEX*16 array, dimension (LWORK) !>
[in]	LWORK	!> LWORK is INTEGER !> The length of the array WORK. LWORK must be at least NRHS, !> and should be at least NRHS*NB, where NB is the block size !> for this environment. !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit !> < 0: if INFO = -i, the i-th argument had an illegal value !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 119 of file zgelqs.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            INFO, LDA, LDB, LWORK, M, N, NRHS
*     ..
*     .. Array Arguments ..
      COMPLEX*16         A( LDA, * ), B( LDB, * ), TAU( * ),
     $                   WORK( LWORK )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      COMPLEX*16         CZERO, CONE
      parameter( czero = ( 0.0d+0, 0.0d+0 ),
     $                   cone = ( 1.0d+0, 0.0d+0 ) )
*     ..
*     .. External Subroutines ..
      EXTERNAL           xerbla, zlaset, ztrsm, zunmlq
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
      IF( m.LT.0 ) THEN
         info = -1
      ELSE IF( n.LT.0 .OR. m.GT.n ) THEN
         info = -2
      ELSE IF( nrhs.LT.0 ) THEN
         info = -3
      ELSE IF( lda.LT.max( 1, m ) ) THEN
         info = -5
      ELSE IF( ldb.LT.max( 1, n ) ) THEN
         info = -8
      ELSE IF( lwork.LT.1 .OR. lwork.LT.nrhs .AND. m.GT.0 .AND. n.GT.0 )
     $          THEN
         info = -10
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'ZGELQS', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 .OR. nrhs.EQ.0 .OR. m.EQ.0 )
     $   RETURN
*
*     Solve L*X = B(1:m,:)
*
      CALL ztrsm( 'Left', 'Lower', 'No transpose', 'Non-unit', m, nrhs,
     $            cone, a, lda, b, ldb )
*
*     Set B(m+1:n,:) to zero
*
      IF( m.LT.n )
     $   CALL zlaset( 'Full', n-m, nrhs, czero, czero, b( m+1, 1 ),
     $                ldb )
*
*     B := Q' * B
*
      CALL zunmlq( 'Left', 'Conjugate transpose', n, nrhs, m, a, lda,
     $             tau, b, ldb, work, lwork, info )
*
      RETURN
*
*     End of ZGELQS
*

Here is the call graph for this function: