zchkgl()

subroutine zchkgl	(	integer	nin,
		integer	nout
	)

ZCHKGL

Purpose:

 ZCHKGL tests ZGGBAL, a routine for balancing a matrix pair (A, B).

Parameters

[in]	NIN	NIN is INTEGER The logical unit number for input. NIN > 0.
[in]	NOUT	NOUT is INTEGER The logical unit number for output. NOUT > 0.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 52 of file zchkgl.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            NIN, NOUT
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            LDA, LDB, LWORK
      parameter( lda = 20, ldb = 20, lwork = 6*lda )
      DOUBLE PRECISION   ZERO
      parameter( zero = 0.0d+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, IHI, IHIIN, ILO, ILOIN, INFO, J, KNT, N,
     $                   NINFO
      DOUBLE PRECISION   ANORM, BNORM, EPS, RMAX, VMAX
*     ..
*     .. Local Arrays ..
      INTEGER            LMAX( 3 )
      DOUBLE PRECISION   LSCALE( LDA ), LSCLIN( LDA ), RSCALE( LDA ),
     $                   RSCLIN( LDA ), WORK( LWORK )
      COMPLEX*16         A( LDA, LDA ), AIN( LDA, LDA ), B( LDB, LDB ),
     $                   BIN( LDB, LDB )
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   DLAMCH, ZLANGE
      EXTERNAL           dlamch, zlange
*     ..
*     .. External Subroutines ..
      EXTERNAL           zggbal
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, max
*     ..
*     .. Executable Statements ..
*
      lmax( 1 ) = 0
      lmax( 2 ) = 0
      lmax( 3 ) = 0
      ninfo = 0
      knt = 0
      rmax = zero
*
      eps = dlamch( 'Precision' )
*
   10 CONTINUE
*
      READ( nin, fmt = * )n
      IF( n.EQ.0 )
     $   GO TO 90
      DO 20 i = 1, n
         READ( nin, fmt = * )( a( i, j ), j = 1, n )
   20 CONTINUE
*
      DO 30 i = 1, n
         READ( nin, fmt = * )( b( i, j ), j = 1, n )
   30 CONTINUE
*
      READ( nin, fmt = * )iloin, ihiin
      DO 40 i = 1, n
         READ( nin, fmt = * )( ain( i, j ), j = 1, n )
   40 CONTINUE
      DO 50 i = 1, n
         READ( nin, fmt = * )( bin( i, j ), j = 1, n )
   50 CONTINUE
*
      READ( nin, fmt = * )( lsclin( i ), i = 1, n )
      READ( nin, fmt = * )( rsclin( i ), i = 1, n )
*
      anorm = zlange( 'M', n, n, a, lda, work )
      bnorm = zlange( 'M', n, n, b, ldb, work )
*
      knt = knt + 1
*
      CALL zggbal( 'B', n, a, lda, b, ldb, ilo, ihi, lscale, rscale,
     $             work, info )
*
      IF( info.NE.0 ) THEN
         ninfo = ninfo + 1
         lmax( 1 ) = knt
      END IF
*
      IF( ilo.NE.iloin .OR. ihi.NE.ihiin ) THEN
         ninfo = ninfo + 1
         lmax( 2 ) = knt
      END IF
*
      vmax = zero
      DO 70 i = 1, n
         DO 60 j = 1, n
            vmax = max( vmax, abs( a( i, j )-ain( i, j ) ) )
            vmax = max( vmax, abs( b( i, j )-bin( i, j ) ) )
   60    CONTINUE
   70 CONTINUE
*
      DO 80 i = 1, n
         vmax = max( vmax, abs( lscale( i )-lsclin( i ) ) )
         vmax = max( vmax, abs( rscale( i )-rsclin( i ) ) )
   80 CONTINUE
*
      vmax = vmax / ( eps*max( anorm, bnorm ) )
*
      IF( vmax.GT.rmax ) THEN
         lmax( 3 ) = knt
         rmax = vmax
      END IF
*
      GO TO 10
*
   90 CONTINUE
*
      WRITE( nout, fmt = 9999 )
 9999 FORMAT( ' .. test output of ZGGBAL .. ' )
*
      WRITE( nout, fmt = 9998 )rmax
 9998 FORMAT( ' ratio of largest test error              = ', d12.3 )
      WRITE( nout, fmt = 9997 )lmax( 1 )
 9997 FORMAT( ' example number where info is not zero    = ', i4 )
      WRITE( nout, fmt = 9996 )lmax( 2 )
 9996 FORMAT( ' example number where ILO or IHI is wrong = ', i4 )
      WRITE( nout, fmt = 9995 )lmax( 3 )
 9995 FORMAT( ' example number having largest error      = ', i4 )
      WRITE( nout, fmt = 9994 )ninfo
 9994 FORMAT( ' number of examples where info is not 0   = ', i4 )
      WRITE( nout, fmt = 9993 )knt
 9993 FORMAT( ' total number of examples tested          = ', i4 )
*
      RETURN
*
*     End of ZCHKGL
*

Here is the call graph for this function:

Here is the caller graph for this function: