zchkgg.f

Go to the documentation of this file.

*> \brief \b ZCHKGG
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*  Definition:
*  ===========
*
*       SUBROUTINE ZCHKGG( NSIZES, NN, NTYPES, DOTYPE, ISEED, THRESH,
*                          TSTDIF, THRSHN, NOUNIT, A, LDA, B, H, T, S1,
*                          S2, P1, P2, U, LDU, V, Q, Z, ALPHA1, BETA1,
*                          ALPHA3, BETA3, EVECTL, EVECTR, WORK, LWORK,
*                          RWORK, LLWORK, RESULT, INFO )
*
*       .. Scalar Arguments ..
*       LOGICAL            TSTDIF
*       INTEGER            INFO, LDA, LDU, LWORK, NOUNIT, NSIZES, NTYPES
*       DOUBLE PRECISION   THRESH, THRSHN
*       ..
*       .. Array Arguments ..
*       LOGICAL            DOTYPE( * ), LLWORK( * )
*       INTEGER            ISEED( 4 ), NN( * )
*       DOUBLE PRECISION   RESULT( 15 ), RWORK( * )
*       COMPLEX*16         A( LDA, * ), ALPHA1( * ), ALPHA3( * ),
*      $                   B( LDA, * ), BETA1( * ), BETA3( * ),
*      $                   EVECTL( LDU, * ), EVECTR( LDU, * ),
*      $                   H( LDA, * ), P1( LDA, * ), P2( LDA, * ),
*      $                   Q( LDU, * ), S1( LDA, * ), S2( LDA, * ),
*      $                   T( LDA, * ), U( LDU, * ), V( LDU, * ),
*      $                   WORK( * ), Z( LDU, * )
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> ZCHKGG  checks the nonsymmetric generalized eigenvalue problem
*> routines.
*>                                H          H        H
*> ZGGHRD factors A and B as U H V  and U T V , where   means conjugate
*> transpose, H is hessenberg, T is triangular and U and V are unitary.
*>
*>                                 H          H
*> ZHGEQZ factors H and T as  Q S Z  and Q P Z , where P and S are upper
*> triangular and Q and Z are unitary.  It also computes the generalized
*> eigenvalues (alpha(1),beta(1)),...,(alpha(n),beta(n)), where
*> alpha(j)=S(j,j) and beta(j)=P(j,j) -- thus, w(j) = alpha(j)/beta(j)
*> is a root of the generalized eigenvalue problem
*>
*>     det( A - w(j) B ) = 0
*>
*> and m(j) = beta(j)/alpha(j) is a root of the essentially equivalent
*> problem
*>
*>     det( m(j) A - B ) = 0
*>
*> ZTGEVC computes the matrix L of left eigenvectors and the matrix R
*> of right eigenvectors for the matrix pair ( S, P ).  In the
*> description below,  l and r are left and right eigenvectors
*> corresponding to the generalized eigenvalues (alpha,beta).
*>
*> When ZCHKGG is called, a number of matrix "sizes" ("n's") and a
*> number of matrix "types" are specified.  For each size ("n")
*> and each type of matrix, one matrix will be generated and used
*> to test the nonsymmetric eigenroutines.  For each matrix, 13
*> tests will be performed.  The first twelve "test ratios" should be
*> small -- O(1).  They will be compared with the threshold THRESH:
*>
*>                  H
*> (1)   | A - U H V  | / ( |A| n ulp )
*>
*>                  H
*> (2)   | B - U T V  | / ( |B| n ulp )
*>
*>               H
*> (3)   | I - UU  | / ( n ulp )
*>
*>               H
*> (4)   | I - VV  | / ( n ulp )
*>
*>                  H
*> (5)   | H - Q S Z  | / ( |H| n ulp )
*>
*>                  H
*> (6)   | T - Q P Z  | / ( |T| n ulp )
*>
*>               H
*> (7)   | I - QQ  | / ( n ulp )
*>
*>               H
*> (8)   | I - ZZ  | / ( n ulp )
*>
*> (9)   max over all left eigenvalue/-vector pairs (beta/alpha,l) of
*>                           H
*>       | (beta A - alpha B) l | / ( ulp max( |beta A|, |alpha B| ) )
*>
*> (10)  max over all left eigenvalue/-vector pairs (beta/alpha,l') of
*>                           H
*>       | (beta H - alpha T) l' | / ( ulp max( |beta H|, |alpha T| ) )
*>
*>       where the eigenvectors l' are the result of passing Q to
*>       DTGEVC and back transforming (JOB='B').
*>
*> (11)  max over all right eigenvalue/-vector pairs (beta/alpha,r) of
*>
*>       | (beta A - alpha B) r | / ( ulp max( |beta A|, |alpha B| ) )
*>
*> (12)  max over all right eigenvalue/-vector pairs (beta/alpha,r') of
*>
*>       | (beta H - alpha T) r' | / ( ulp max( |beta H|, |alpha T| ) )
*>
*>       where the eigenvectors r' are the result of passing Z to
*>       DTGEVC and back transforming (JOB='B').
*>
*> The last three test ratios will usually be small, but there is no
*> mathematical requirement that they be so.  They are therefore
*> compared with THRESH only if TSTDIF is .TRUE.
*>
*> (13)  | S(Q,Z computed) - S(Q,Z not computed) | / ( |S| ulp )
*>
*> (14)  | P(Q,Z computed) - P(Q,Z not computed) | / ( |P| ulp )
*>
*> (15)  max( |alpha(Q,Z computed) - alpha(Q,Z not computed)|/|S| ,
*>            |beta(Q,Z computed) - beta(Q,Z not computed)|/|P| ) / ulp
*>
*> In addition, the normalization of L and R are checked, and compared
*> with the threshold THRSHN.
*>
*> Test Matrices
*> ---- --------
*>
*> The sizes of the test matrices are specified by an array
*> NN(1:NSIZES); the value of each element NN(j) specifies one size.
*> The "types" are specified by a logical array DOTYPE( 1:NTYPES ); if
*> DOTYPE(j) is .TRUE., then matrix type "j" will be generated.
*> Currently, the list of possible types is:
*>
*> (1)  ( 0, 0 )         (a pair of zero matrices)
*>
*> (2)  ( I, 0 )         (an identity and a zero matrix)
*>
*> (3)  ( 0, I )         (an identity and a zero matrix)
*>
*> (4)  ( I, I )         (a pair of identity matrices)
*>
*>         t   t
*> (5)  ( J , J  )       (a pair of transposed Jordan blocks)
*>
*>                                     t                ( I   0  )
*> (6)  ( X, Y )         where  X = ( J   0  )  and Y = (      t )
*>                                  ( 0   I  )          ( 0   J  )
*>                       and I is a k x k identity and J a (k+1)x(k+1)
*>                       Jordan block; k=(N-1)/2
*>
*> (7)  ( D, I )         where D is P*D1, P is a random unitary diagonal
*>                       matrix (i.e., with random magnitude 1 entries
*>                       on the diagonal), and D1=diag( 0, 1,..., N-1 )
*>                       (i.e., a diagonal matrix with D1(1,1)=0,
*>                       D1(2,2)=1, ..., D1(N,N)=N-1.)
*> (8)  ( I, D )
*>
*> (9)  ( big*D, small*I ) where "big" is near overflow and small=1/big
*>
*> (10) ( small*D, big*I )
*>
*> (11) ( big*I, small*D )
*>
*> (12) ( small*I, big*D )
*>
*> (13) ( big*D, big*I )
*>
*> (14) ( small*D, small*I )
*>
*> (15) ( D1, D2 )        where D1=P*diag( 0, 0, 1, ..., N-3, 0 ) and
*>                        D2=Q*diag( 0, N-3, N-4,..., 1, 0, 0 ), and
*>                        P and Q are random unitary diagonal matrices.
*>           t   t
*> (16) U ( J , J ) V     where U and V are random unitary matrices.
*>
*> (17) U ( T1, T2 ) V    where T1 and T2 are upper triangular matrices
*>                        with random O(1) entries above the diagonal
*>                        and diagonal entries diag(T1) =
*>                        P*( 0, 0, 1, ..., N-3, 0 ) and diag(T2) =
*>                        Q*( 0, N-3, N-4,..., 1, 0, 0 )
*>
*> (18) U ( T1, T2 ) V    diag(T1) = ( 0, 0, 1, 1, s, ..., s, 0 )
*>                        diag(T2) = ( 0, 1, 0, 1,..., 1, 0 )
*>                        s = machine precision.
*>
*> (19) U ( T1, T2 ) V    diag(T1)=( 0,0,1,1, 1-d, ..., 1-(N-5)*d=s, 0 )
*>                        diag(T2) = ( 0, 1, 0, 1, ..., 1, 0 )
*>
*>                                                        N-5
*> (20) U ( T1, T2 ) V    diag(T1)=( 0, 0, 1, 1, a, ..., a   =s, 0 )
*>                        diag(T2) = ( 0, 1, 0, 1, ..., 1, 0, 0 )
*>
*> (21) U ( T1, T2 ) V    diag(T1)=( 0, 0, 1, r1, r2, ..., r(N-4), 0 )
*>                        diag(T2) = ( 0, 1, 0, 1, ..., 1, 0, 0 )
*>                        where r1,..., r(N-4) are random.
*>
*> (22) U ( big*T1, small*T2 ) V   diag(T1) = P*( 0, 0, 1, ..., N-3, 0 )
*>                                 diag(T2) = ( 0, 1, ..., 1, 0, 0 )
*>
*> (23) U ( small*T1, big*T2 ) V   diag(T1) = P*( 0, 0, 1, ..., N-3, 0 )
*>                                 diag(T2) = ( 0, 1, ..., 1, 0, 0 )
*>
*> (24) U ( small*T1, small*T2 ) V diag(T1) = P*( 0, 0, 1, ..., N-3, 0 )
*>                                 diag(T2) = ( 0, 1, ..., 1, 0, 0 )
*>
*> (25) U ( big*T1, big*T2 ) V     diag(T1) = P*( 0, 0, 1, ..., N-3, 0 )
*>                                 diag(T2) = ( 0, 1, ..., 1, 0, 0 )
*>
*> (26) U ( T1, T2 ) V     where T1 and T2 are random upper-triangular
*>                         matrices.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] NSIZES
*> \verbatim
*>          NSIZES is INTEGER
*>          The number of sizes of matrices to use.  If it is zero,
*>          ZCHKGG does nothing.  It must be at least zero.
*> \endverbatim
*>
*> \param[in] NN
*> \verbatim
*>          NN is INTEGER array, dimension (NSIZES)
*>          An array containing the sizes to be used for the matrices.
*>          Zero values will be skipped.  The values must be at least
*>          zero.
*> \endverbatim
*>
*> \param[in] NTYPES
*> \verbatim
*>          NTYPES is INTEGER
*>          The number of elements in DOTYPE.   If it is zero, ZCHKGG
*>          does nothing.  It must be at least zero.  If it is MAXTYP+1
*>          and NSIZES is 1, then an additional type, MAXTYP+1 is
*>          defined, which is to use whatever matrix is in A.  This
*>          is only useful if DOTYPE(1:MAXTYP) is .FALSE. and
*>          DOTYPE(MAXTYP+1) is .TRUE. .
*> \endverbatim
*>
*> \param[in] DOTYPE
*> \verbatim
*>          DOTYPE is LOGICAL array, dimension (NTYPES)
*>          If DOTYPE(j) is .TRUE., then for each size in NN a
*>          matrix of that size and of type j will be generated.
*>          If NTYPES is smaller than the maximum number of types
*>          defined (PARAMETER MAXTYP), then types NTYPES+1 through
*>          MAXTYP will not be generated.  If NTYPES is larger
*>          than MAXTYP, DOTYPE(MAXTYP+1) through DOTYPE(NTYPES)
*>          will be ignored.
*> \endverbatim
*>
*> \param[in,out] ISEED
*> \verbatim
*>          ISEED is INTEGER array, dimension (4)
*>          On entry ISEED specifies the seed of the random number
*>          generator. The array elements should be between 0 and 4095;
*>          if not they will be reduced mod 4096.  Also, ISEED(4) must
*>          be odd.  The random number generator uses a linear
*>          congruential sequence limited to small integers, and so
*>          should produce machine independent random numbers. The
*>          values of ISEED are changed on exit, and can be used in the
*>          next call to ZCHKGG to continue the same random number
*>          sequence.
*> \endverbatim
*>
*> \param[in] THRESH
*> \verbatim
*>          THRESH is DOUBLE PRECISION
*>          A test will count as "failed" if the "error", computed as
*>          described above, exceeds THRESH.  Note that the error
*>          is scaled to be O(1), so THRESH should be a reasonably
*>          small multiple of 1, e.g., 10 or 100.  In particular,
*>          it should not depend on the precision (single vs. double)
*>          or the size of the matrix.  It must be at least zero.
*> \endverbatim
*>
*> \param[in] TSTDIF
*> \verbatim
*>          TSTDIF is LOGICAL
*>          Specifies whether test ratios 13-15 will be computed and
*>          compared with THRESH.
*>          = .FALSE.: Only test ratios 1-12 will be computed and tested.
*>                     Ratios 13-15 will be set to zero.
*>          = .TRUE.:  All the test ratios 1-15 will be computed and
*>                     tested.
*> \endverbatim
*>
*> \param[in] THRSHN
*> \verbatim
*>          THRSHN is DOUBLE PRECISION
*>          Threshold for reporting eigenvector normalization error.
*>          If the normalization of any eigenvector differs from 1 by
*>          more than THRSHN*ulp, then a special error message will be
*>          printed.  (This is handled separately from the other tests,
*>          since only a compiler or programming error should cause an
*>          error message, at least if THRSHN is at least 5--10.)
*> \endverbatim
*>
*> \param[in] NOUNIT
*> \verbatim
*>          NOUNIT is INTEGER
*>          The FORTRAN unit number for printing out error messages
*>          (e.g., if a routine returns IINFO not equal to 0.)
*> \endverbatim
*>
*> \param[in,out] A
*> \verbatim
*>          A is COMPLEX*16 array, dimension (LDA, max(NN))
*>          Used to hold the original A matrix.  Used as input only
*>          if NTYPES=MAXTYP+1, DOTYPE(1:MAXTYP)=.FALSE., and
*>          DOTYPE(MAXTYP+1)=.TRUE.
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>          The leading dimension of A, B, H, T, S1, P1, S2, and P2.
*>          It must be at least 1 and at least max( NN ).
*> \endverbatim
*>
*> \param[in,out] B
*> \verbatim
*>          B is COMPLEX*16 array, dimension (LDA, max(NN))
*>          Used to hold the original B matrix.  Used as input only
*>          if NTYPES=MAXTYP+1, DOTYPE(1:MAXTYP)=.FALSE., and
*>          DOTYPE(MAXTYP+1)=.TRUE.
*> \endverbatim
*>
*> \param[out] H
*> \verbatim
*>          H is COMPLEX*16 array, dimension (LDA, max(NN))
*>          The upper Hessenberg matrix computed from A by ZGGHRD.
*> \endverbatim
*>
*> \param[out] T
*> \verbatim
*>          T is COMPLEX*16 array, dimension (LDA, max(NN))
*>          The upper triangular matrix computed from B by ZGGHRD.
*> \endverbatim
*>
*> \param[out] S1
*> \verbatim
*>          S1 is COMPLEX*16 array, dimension (LDA, max(NN))
*>          The Schur (upper triangular) matrix computed from H by ZHGEQZ
*>          when Q and Z are also computed.
*> \endverbatim
*>
*> \param[out] S2
*> \verbatim
*>          S2 is COMPLEX*16 array, dimension (LDA, max(NN))
*>          The Schur (upper triangular) matrix computed from H by ZHGEQZ
*>          when Q and Z are not computed.
*> \endverbatim
*>
*> \param[out] P1
*> \verbatim
*>          P1 is COMPLEX*16 array, dimension (LDA, max(NN))
*>          The upper triangular matrix computed from T by ZHGEQZ
*>          when Q and Z are also computed.
*> \endverbatim
*>
*> \param[out] P2
*> \verbatim
*>          P2 is COMPLEX*16 array, dimension (LDA, max(NN))
*>          The upper triangular matrix computed from T by ZHGEQZ
*>          when Q and Z are not computed.
*> \endverbatim
*>
*> \param[out] U
*> \verbatim
*>          U is COMPLEX*16 array, dimension (LDU, max(NN))
*>          The (left) unitary matrix computed by ZGGHRD.
*> \endverbatim
*>
*> \param[in] LDU
*> \verbatim
*>          LDU is INTEGER
*>          The leading dimension of U, V, Q, Z, EVECTL, and EVEZTR.  It
*>          must be at least 1 and at least max( NN ).
*> \endverbatim
*>
*> \param[out] V
*> \verbatim
*>          V is COMPLEX*16 array, dimension (LDU, max(NN))
*>          The (right) unitary matrix computed by ZGGHRD.
*> \endverbatim
*>
*> \param[out] Q
*> \verbatim
*>          Q is COMPLEX*16 array, dimension (LDU, max(NN))
*>          The (left) unitary matrix computed by ZHGEQZ.
*> \endverbatim
*>
*> \param[out] Z
*> \verbatim
*>          Z is COMPLEX*16 array, dimension (LDU, max(NN))
*>          The (left) unitary matrix computed by ZHGEQZ.
*> \endverbatim
*>
*> \param[out] ALPHA1
*> \verbatim
*>          ALPHA1 is COMPLEX*16 array, dimension (max(NN))
*> \endverbatim
*>
*> \param[out] BETA1
*> \verbatim
*>          BETA1 is COMPLEX*16 array, dimension (max(NN))
*>          The generalized eigenvalues of (A,B) computed by ZHGEQZ
*>          when Q, Z, and the full Schur matrices are computed.
*> \endverbatim
*>
*> \param[out] ALPHA3
*> \verbatim
*>          ALPHA3 is COMPLEX*16 array, dimension (max(NN))
*> \endverbatim
*>
*> \param[out] BETA3
*> \verbatim
*>          BETA3 is COMPLEX*16 array, dimension (max(NN))
*>          The generalized eigenvalues of (A,B) computed by ZHGEQZ
*>          when neither Q, Z, nor the Schur matrices are computed.
*> \endverbatim
*>
*> \param[out] EVECTL
*> \verbatim
*>          EVECTL is COMPLEX*16 array, dimension (LDU, max(NN))
*>          The (lower triangular) left eigenvector matrix for the
*>          matrices in S1 and P1.
*> \endverbatim
*>
*> \param[out] EVECTR
*> \verbatim
*>          EVECTR is COMPLEX*16 array, dimension (LDU, max(NN))
*>          The (upper triangular) right eigenvector matrix for the
*>          matrices in S1 and P1.
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is COMPLEX*16 array, dimension (LWORK)
*> \endverbatim
*>
*> \param[in] LWORK
*> \verbatim
*>          LWORK is INTEGER
*>          The number of entries in WORK.  This must be at least
*>          max( 4*N, 2 * N**2, 1 ), for all N=NN(j).
*> \endverbatim
*>
*> \param[out] RWORK
*> \verbatim
*>          RWORK is DOUBLE PRECISION array, dimension (2*max(NN))
*> \endverbatim
*>
*> \param[out] LLWORK
*> \verbatim
*>          LLWORK is LOGICAL array, dimension (max(NN))
*> \endverbatim
*>
*> \param[out] RESULT
*> \verbatim
*>          RESULT is DOUBLE PRECISION array, dimension (15)
*>          The values computed by the tests described above.
*>          The values are currently limited to 1/ulp, to avoid
*>          overflow.
*> \endverbatim
*>
*> \param[out] INFO
*> \verbatim
*>          INFO is INTEGER
*>          = 0:  successful exit.
*>          < 0:  if INFO = -i, the i-th argument had an illegal value.
*>          > 0:  A routine returned an error code.  INFO is the
*>                absolute value of the INFO value returned.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \ingroup complex16_eig
*
*  =====================================================================
      SUBROUTINE zchkgg( NSIZES, NN, NTYPES, DOTYPE, ISEED, THRESH,
     $                   TSTDIF, THRSHN, NOUNIT, A, LDA, B, H, T, S1,
     $                   S2, P1, P2, U, LDU, V, Q, Z, ALPHA1, BETA1,
     $                   ALPHA3, BETA3, EVECTL, EVECTR, WORK, LWORK,
     $                   RWORK, LLWORK, RESULT, INFO )
*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      LOGICAL            TSTDIF
      INTEGER            INFO, LDA, LDU, LWORK, NOUNIT, NSIZES, NTYPES
      DOUBLE PRECISION   THRESH, THRSHN
*     ..
*     .. Array Arguments ..
      LOGICAL            DOTYPE( * ), LLWORK( * )
      INTEGER            ISEED( 4 ), NN( * )
      DOUBLE PRECISION   RESULT( 15 ), RWORK( * )
      COMPLEX*16         A( LDA, * ), ALPHA1( * ), ALPHA3( * ),
     $                   b( lda, * ), beta1( * ), beta3( * ),
     $                   evectl( ldu, * ), evectr( ldu, * ),
     $                   h( lda, * ), p1( lda, * ), p2( lda, * ),
     $                   q( ldu, * ), s1( lda, * ), s2( lda, * ),
     $                   t( lda, * ), u( ldu, * ), v( ldu, * ),
     $                   work( * ), z( ldu, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO, ONE
      PARAMETER          ( ZERO = 0.0d+0, one = 1.0d+0 )
      COMPLEX*16         CZERO, CONE
      PARAMETER          ( CZERO = ( 0.0d+0, 0.0d+0 ),
     $                   cone = ( 1.0d+0, 0.0d+0 ) )
      INTEGER            MAXTYP
      parameter( maxtyp = 26 )
*     ..
*     .. Local Scalars ..
      LOGICAL            BADNN
      INTEGER            I1, IADD, IINFO, IN, J, JC, JR, JSIZE, JTYPE,
     $                   LWKOPT, MTYPES, N, N1, NERRS, NMATS, NMAX,
     $                   NTEST, NTESTT
      DOUBLE PRECISION   ANORM, BNORM, SAFMAX, SAFMIN, TEMP1, TEMP2,
     $                   ulp, ulpinv
      COMPLEX*16         CTEMP
*     ..
*     .. Local Arrays ..
      LOGICAL            LASIGN( MAXTYP ), LBSIGN( MAXTYP )
      INTEGER            IOLDSD( 4 ), KADD( 6 ), KAMAGN( MAXTYP ),
     $                   KATYPE( MAXTYP ), KAZERO( MAXTYP ),
     $                   KBMAGN( MAXTYP ), KBTYPE( MAXTYP ),
     $                   kbzero( maxtyp ), kclass( maxtyp ),
     $                   ktrian( maxtyp ), kz1( 6 ), kz2( 6 )
      DOUBLE PRECISION   DUMMA( 4 ), RMAGN( 0: 3 )
      COMPLEX*16         CDUMMA( 4 )
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   DLAMCH, ZLANGE
      COMPLEX*16         ZLARND
      EXTERNAL           DLAMCH, ZLANGE, ZLARND
*     ..
*     .. External Subroutines ..
      EXTERNAL           dlasum, xerbla, zgeqr2, zget51, zget52, zgghrd,
     $                   zhgeqz, zlacpy, zlarfg, zlaset, zlatm4, ztgevc,
     $                   zunm2r
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, dble, dconjg, max, min, sign
*     ..
*     .. Data statements ..
      DATA               kclass / 15*1, 10*2, 1*3 /
      DATA               kz1 / 0, 1, 2, 1, 3, 3 /
      DATA               kz2 / 0, 0, 1, 2, 1, 1 /
      DATA               kadd / 0, 0, 0, 0, 3, 2 /
      DATA               katype / 0, 1, 0, 1, 2, 3, 4, 1, 4, 4, 1, 1, 4,
     $                   4, 4, 2, 4, 5, 8, 7, 9, 4*4, 0 /
      DATA               kbtype / 0, 0, 1, 1, 2, -3, 1, 4, 1, 1, 4, 4,
     $                   1, 1, -4, 2, -4, 8*8, 0 /
      DATA               kazero / 6*1, 2, 1, 2*2, 2*1, 2*2, 3, 1, 3,
     $                   4*5, 4*3, 1 /
      DATA               kbzero / 6*1, 1, 2, 2*1, 2*2, 2*1, 4, 1, 4,
     $                   4*6, 4*4, 1 /
      DATA               kamagn / 8*1, 2, 3, 2, 3, 2, 3, 7*1, 2, 3, 3,
     $                   2, 1 /
      DATA               kbmagn / 8*1, 3, 2, 3, 2, 2, 3, 7*1, 3, 2, 3,
     $                   2, 1 /
      DATA               ktrian / 16*0, 10*1 /
      DATA               lasign / 6*.false., .true., .false., 2*.true.,
     $                   2*.false., 3*.true., .false., .true.,
     $                   3*.false., 5*.true., .false. /
      DATA               lbsign / 7*.false., .true., 2*.false.,
     $                   2*.true., 2*.false., .true., .false., .true.,
     $                   9*.false. /
*     ..
*     .. Executable Statements ..
*
*     Check for errors
*
      info = 0
*
      badnn = .false.
      nmax = 1
      DO 10 j = 1, nsizes
         nmax = max( nmax, nn( j ) )
         IF( nn( j ).LT.0 )
     $      badnn = .true.
   10 CONTINUE
*
      lwkopt = max( 2*nmax*nmax, 4*nmax, 1 )
*
*     Check for errors
*
      IF( nsizes.LT.0 ) THEN
         info = -1
      ELSE IF( badnn ) THEN
         info = -2
      ELSE IF( ntypes.LT.0 ) THEN
         info = -3
      ELSE IF( thresh.LT.zero ) THEN
         info = -6
      ELSE IF( lda.LE.1 .OR. lda.LT.nmax ) THEN
         info = -10
      ELSE IF( ldu.LE.1 .OR. ldu.LT.nmax ) THEN
         info = -19
      ELSE IF( lwkopt.GT.lwork ) THEN
         info = -30
      END IF
*
      IF( info.NE.0 ) THEN
         CALL xerbla( 'ZCHKGG', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( nsizes.EQ.0 .OR. ntypes.EQ.0 )
     $   RETURN
*
      safmin = dlamch( 'Safe minimum' )
      ulp = dlamch( 'Epsilon' )*dlamch( 'Base' )
      safmin = safmin / ulp
      safmax = one / safmin
      ulpinv = one / ulp
*
*     The values RMAGN(2:3) depend on N, see below.
*
      rmagn( 0 ) = zero
      rmagn( 1 ) = one
*
*     Loop over sizes, types
*
      ntestt = 0
      nerrs = 0
      nmats = 0
*
      DO 240 jsize = 1, nsizes
         n = nn( jsize )
         n1 = max( 1, n )
         rmagn( 2 ) = safmax*ulp / dble( n1 )
         rmagn( 3 ) = safmin*ulpinv*n1
*
         IF( nsizes.NE.1 ) THEN
            mtypes = min( maxtyp, ntypes )
         ELSE
            mtypes = min( maxtyp+1, ntypes )
         END IF
*
         DO 230 jtype = 1, mtypes
            IF( .NOT.dotype( jtype ) )
     $         GO TO 230
            nmats = nmats + 1
            ntest = 0
*
*           Save ISEED in case of an error.
*
            DO 20 j = 1, 4
               ioldsd( j ) = iseed( j )
   20       CONTINUE
*
*           Initialize RESULT
*
            DO 30 j = 1, 15
               result( j ) = zero
   30       CONTINUE
*
*           Compute A and B
*
*           Description of control parameters:
*
*           KZLASS: =1 means w/o rotation, =2 means w/ rotation,
*                   =3 means random.
*           KATYPE: the "type" to be passed to ZLATM4 for computing A.
*           KAZERO: the pattern of zeros on the diagonal for A:
*                   =1: ( xxx ), =2: (0, xxx ) =3: ( 0, 0, xxx, 0 ),
*                   =4: ( 0, xxx, 0, 0 ), =5: ( 0, 0, 1, xxx, 0 ),
*                   =6: ( 0, 1, 0, xxx, 0 ).  (xxx means a string of
*                   non-zero entries.)
*           KAMAGN: the magnitude of the matrix: =0: zero, =1: O(1),
*                   =2: large, =3: small.
*           LASIGN: .TRUE. if the diagonal elements of A are to be
*                   multiplied by a random magnitude 1 number.
*           KBTYPE, KBZERO, KBMAGN, LBSIGN: the same, but for B.
*           KTRIAN: =0: don't fill in the upper triangle, =1: do.
*           KZ1, KZ2, KADD: used to implement KAZERO and KBZERO.
*           RMAGN:  used to implement KAMAGN and KBMAGN.
*
            IF( mtypes.GT.maxtyp )
     $         GO TO 110
            iinfo = 0
            IF( kclass( jtype ).LT.3 ) THEN
*
*              Generate A (w/o rotation)
*
               IF( abs( katype( jtype ) ).EQ.3 ) THEN
                  in = 2*( ( n-1 ) / 2 ) + 1
                  IF( in.NE.n )
     $               CALL zlaset( 'Full', n, n, czero, czero, a, lda )
               ELSE
                  in = n
               END IF
               CALL zlatm4( katype( jtype ), in, kz1( kazero( jtype ) ),
     $                      kz2( kazero( jtype ) ), lasign( jtype ),
     $                      rmagn( kamagn( jtype ) ), ulp,
     $                      rmagn( ktrian( jtype )*kamagn( jtype ) ), 4,
     $                      iseed, a, lda )
               iadd = kadd( kazero( jtype ) )
               IF( iadd.GT.0 .AND. iadd.LE.n )
     $            a( iadd, iadd ) = rmagn( kamagn( jtype ) )
*
*              Generate B (w/o rotation)
*
               IF( abs( kbtype( jtype ) ).EQ.3 ) THEN
                  in = 2*( ( n-1 ) / 2 ) + 1
                  IF( in.NE.n )
     $               CALL zlaset( 'Full', n, n, czero, czero, b, lda )
               ELSE
                  in = n
               END IF
               CALL zlatm4( kbtype( jtype ), in, kz1( kbzero( jtype ) ),
     $                      kz2( kbzero( jtype ) ), lbsign( jtype ),
     $                      rmagn( kbmagn( jtype ) ), one,
     $                      rmagn( ktrian( jtype )*kbmagn( jtype ) ), 4,
     $                      iseed, b, lda )
               iadd = kadd( kbzero( jtype ) )
               IF( iadd.NE.0 )
     $            b( iadd, iadd ) = rmagn( kbmagn( jtype ) )
*
               IF( kclass( jtype ).EQ.2 .AND. n.GT.0 ) THEN
*
*                 Include rotations
*
*                 Generate U, V as Householder transformations times a
*                 diagonal matrix.  (Note that ZLARFG makes U(j,j) and
*                 V(j,j) real.)
*
                  DO 50 jc = 1, n - 1
                     DO 40 jr = jc, n
                        u( jr, jc ) = zlarnd( 3, iseed )
                        v( jr, jc ) = zlarnd( 3, iseed )
   40                CONTINUE
                     CALL zlarfg( n+1-jc, u( jc, jc ), u( jc+1, jc ), 1,
     $                            work( jc ) )
                     work( 2*n+jc ) = sign( one, dble( u( jc, jc ) ) )
                     u( jc, jc ) = cone
                     CALL zlarfg( n+1-jc, v( jc, jc ), v( jc+1, jc ), 1,
     $                            work( n+jc ) )
                     work( 3*n+jc ) = sign( one, dble( v( jc, jc ) ) )
                     v( jc, jc ) = cone
   50             CONTINUE
                  ctemp = zlarnd( 3, iseed )
                  u( n, n ) = cone
                  work( n ) = czero
                  work( 3*n ) = ctemp / abs( ctemp )
                  ctemp = zlarnd( 3, iseed )
                  v( n, n ) = cone
                  work( 2*n ) = czero
                  work( 4*n ) = ctemp / abs( ctemp )
*
*                 Apply the diagonal matrices
*
                  DO 70 jc = 1, n
                     DO 60 jr = 1, n
                        a( jr, jc ) = work( 2*n+jr )*
     $                                dconjg( work( 3*n+jc ) )*
     $                                a( jr, jc )
                        b( jr, jc ) = work( 2*n+jr )*
     $                                dconjg( work( 3*n+jc ) )*
     $                                b( jr, jc )
   60                CONTINUE
   70             CONTINUE
                  CALL zunm2r( 'L', 'N', n, n, n-1, u, ldu, work, a,
     $                         lda, work( 2*n+1 ), iinfo )
                  IF( iinfo.NE.0 )
     $               GO TO 100
                  CALL zunm2r( 'R', 'C', n, n, n-1, v, ldu, work( n+1 ),
     $                         a, lda, work( 2*n+1 ), iinfo )
                  IF( iinfo.NE.0 )
     $               GO TO 100
                  CALL zunm2r( 'L', 'N', n, n, n-1, u, ldu, work, b,
     $                         lda, work( 2*n+1 ), iinfo )
                  IF( iinfo.NE.0 )
     $               GO TO 100
                  CALL zunm2r( 'R', 'C', n, n, n-1, v, ldu, work( n+1 ),
     $                         b, lda, work( 2*n+1 ), iinfo )
                  IF( iinfo.NE.0 )
     $               GO TO 100
               END IF
            ELSE
*
*              Random matrices
*
               DO 90 jc = 1, n
                  DO 80 jr = 1, n
                     a( jr, jc ) = rmagn( kamagn( jtype ) )*
     $                             zlarnd( 4, iseed )
                     b( jr, jc ) = rmagn( kbmagn( jtype ) )*
     $                             zlarnd( 4, iseed )
   80             CONTINUE
   90          CONTINUE
            END IF
*
            anorm = zlange( '1', n, n, a, lda, rwork )
            bnorm = zlange( '1', n, n, b, lda, rwork )
*
  100       CONTINUE
*
            IF( iinfo.NE.0 ) THEN
               WRITE( nounit, fmt = 9999 )'Generator', iinfo, n, jtype,
     $            ioldsd
               info = abs( iinfo )
               RETURN
            END IF
*
  110       CONTINUE
*
*           Call ZGEQR2, ZUNM2R, and ZGGHRD to compute H, T, U, and V
*
            CALL zlacpy( ' ', n, n, a, lda, h, lda )
            CALL zlacpy( ' ', n, n, b, lda, t, lda )
            ntest = 1
            result( 1 ) = ulpinv
*
            CALL zgeqr2( n, n, t, lda, work, work( n+1 ), iinfo )
            IF( iinfo.NE.0 ) THEN
               WRITE( nounit, fmt = 9999 )'ZGEQR2', iinfo, n, jtype,
     $            ioldsd
               info = abs( iinfo )
               GO TO 210
            END IF
*
            CALL zunm2r( 'L', 'C', n, n, n, t, lda, work, h, lda,
     $                   work( n+1 ), iinfo )
            IF( iinfo.NE.0 ) THEN
               WRITE( nounit, fmt = 9999 )'ZUNM2R', iinfo, n, jtype,
     $            ioldsd
               info = abs( iinfo )
               GO TO 210
            END IF
*
            CALL zlaset( 'Full', n, n, czero, cone, u, ldu )
            CALL zunm2r( 'R', 'N', n, n, n, t, lda, work, u, ldu,
     $                   work( n+1 ), iinfo )
            IF( iinfo.NE.0 ) THEN
               WRITE( nounit, fmt = 9999 )'ZUNM2R', iinfo, n, jtype,
     $            ioldsd
               info = abs( iinfo )
               GO TO 210
            END IF
*
            CALL zgghrd( 'V', 'I', n, 1, n, h, lda, t, lda, u, ldu, v,
     $                   ldu, iinfo )
            IF( iinfo.NE.0 ) THEN
               WRITE( nounit, fmt = 9999 )'ZGGHRD', iinfo, n, jtype,
     $            ioldsd
               info = abs( iinfo )
               GO TO 210
            END IF
            ntest = 4
*
*           Do tests 1--4
*
            CALL zget51( 1, n, a, lda, h, lda, u, ldu, v, ldu, work,
     $                   rwork, result( 1 ) )
            CALL zget51( 1, n, b, lda, t, lda, u, ldu, v, ldu, work,
     $                   rwork, result( 2 ) )
            CALL zget51( 3, n, b, lda, t, lda, u, ldu, u, ldu, work,
     $                   rwork, result( 3 ) )
            CALL zget51( 3, n, b, lda, t, lda, v, ldu, v, ldu, work,
     $                   rwork, result( 4 ) )
*
*           Call ZHGEQZ to compute S1, P1, S2, P2, Q, and Z, do tests.
*
*           Compute T1 and UZ
*
*           Eigenvalues only
*
            CALL zlacpy( ' ', n, n, h, lda, s2, lda )
            CALL zlacpy( ' ', n, n, t, lda, p2, lda )
            ntest = 5
            result( 5 ) = ulpinv
*
            CALL zhgeqz( 'E', 'N', 'N', n, 1, n, s2, lda, p2, lda,
     $                   alpha3, beta3, q, ldu, z, ldu, work, lwork,
     $                   rwork, iinfo )
            IF( iinfo.NE.0 ) THEN
               WRITE( nounit, fmt = 9999 )'ZHGEQZ(E)', iinfo, n, jtype,
     $            ioldsd
               info = abs( iinfo )
               GO TO 210
            END IF
*
*           Eigenvalues and Full Schur Form
*
            CALL zlacpy( ' ', n, n, h, lda, s2, lda )
            CALL zlacpy( ' ', n, n, t, lda, p2, lda )
*
            CALL zhgeqz( 'S', 'N', 'N', n, 1, n, s2, lda, p2, lda,
     $                   alpha1, beta1, q, ldu, z, ldu, work, lwork,
     $                   rwork, iinfo )
            IF( iinfo.NE.0 ) THEN
               WRITE( nounit, fmt = 9999 )'ZHGEQZ(S)', iinfo, n, jtype,
     $            ioldsd
               info = abs( iinfo )
               GO TO 210
            END IF
*
*           Eigenvalues, Schur Form, and Schur Vectors
*
            CALL zlacpy( ' ', n, n, h, lda, s1, lda )
            CALL zlacpy( ' ', n, n, t, lda, p1, lda )
*
            CALL zhgeqz( 'S', 'I', 'I', n, 1, n, s1, lda, p1, lda,
     $                   alpha1, beta1, q, ldu, z, ldu, work, lwork,
     $                   rwork, iinfo )
            IF( iinfo.NE.0 ) THEN
               WRITE( nounit, fmt = 9999 )'ZHGEQZ(V)', iinfo, n, jtype,
     $            ioldsd
               info = abs( iinfo )
               GO TO 210
            END IF
*
            ntest = 8
*
*           Do Tests 5--8
*
            CALL zget51( 1, n, h, lda, s1, lda, q, ldu, z, ldu, work,
     $                   rwork, result( 5 ) )
            CALL zget51( 1, n, t, lda, p1, lda, q, ldu, z, ldu, work,
     $                   rwork, result( 6 ) )
            CALL zget51( 3, n, t, lda, p1, lda, q, ldu, q, ldu, work,
     $                   rwork, result( 7 ) )
            CALL zget51( 3, n, t, lda, p1, lda, z, ldu, z, ldu, work,
     $                   rwork, result( 8 ) )
*
*           Compute the Left and Right Eigenvectors of (S1,P1)
*
*           9: Compute the left eigenvector Matrix without
*              back transforming:
*
            ntest = 9
            result( 9 ) = ulpinv
*
*           To test "SELECT" option, compute half of the eigenvectors
*           in one call, and half in another
*
            i1 = n / 2
            DO 120 j = 1, i1
               llwork( j ) = .true.
  120       CONTINUE
            DO 130 j = i1 + 1, n
               llwork( j ) = .false.
  130       CONTINUE
*
            CALL ztgevc( 'L', 'S', llwork, n, s1, lda, p1, lda, evectl,
     $                   ldu, cdumma, ldu, n, in, work, rwork, iinfo )
            IF( iinfo.NE.0 ) THEN
               WRITE( nounit, fmt = 9999 )'ZTGEVC(L,S1)', iinfo, n,
     $            jtype, ioldsd
               info = abs( iinfo )
               GO TO 210
            END IF
*
            i1 = in
            DO 140 j = 1, i1
               llwork( j ) = .false.
  140       CONTINUE
            DO 150 j = i1 + 1, n
               llwork( j ) = .true.
  150       CONTINUE
*
            CALL ztgevc( 'L', 'S', llwork, n, s1, lda, p1, lda,
     $                   evectl( 1, i1+1 ), ldu, cdumma, ldu, n, in,
     $                   work, rwork, iinfo )
            IF( iinfo.NE.0 ) THEN
               WRITE( nounit, fmt = 9999 )'ZTGEVC(L,S2)', iinfo, n,
     $            jtype, ioldsd
               info = abs( iinfo )
               GO TO 210
            END IF
*
            CALL zget52( .true., n, s1, lda, p1, lda, evectl, ldu,
     $                   alpha1, beta1, work, rwork, dumma( 1 ) )
            result( 9 ) = dumma( 1 )
            IF( dumma( 2 ).GT.thrshn ) THEN
               WRITE( nounit, fmt = 9998 )'Left', 'ZTGEVC(HOWMNY=S)',
     $            dumma( 2 ), n, jtype, ioldsd
            END IF
*
*           10: Compute the left eigenvector Matrix with
*               back transforming:
*
            ntest = 10
            result( 10 ) = ulpinv
            CALL zlacpy( 'F', n, n, q, ldu, evectl, ldu )
            CALL ztgevc( 'L', 'B', llwork, n, s1, lda, p1, lda, evectl,
     $                   ldu, cdumma, ldu, n, in, work, rwork, iinfo )
            IF( iinfo.NE.0 ) THEN
               WRITE( nounit, fmt = 9999 )'ZTGEVC(L,B)', iinfo, n,
     $            jtype, ioldsd
               info = abs( iinfo )
               GO TO 210
            END IF
*
            CALL zget52( .true., n, h, lda, t, lda, evectl, ldu, alpha1,
     $                   beta1, work, rwork, dumma( 1 ) )
            result( 10 ) = dumma( 1 )
            IF( dumma( 2 ).GT.thrshn ) THEN
               WRITE( nounit, fmt = 9998 )'Left', 'ZTGEVC(HOWMNY=B)',
     $            dumma( 2 ), n, jtype, ioldsd
            END IF
*
*           11: Compute the right eigenvector Matrix without
*               back transforming:
*
            ntest = 11
            result( 11 ) = ulpinv
*
*           To test "SELECT" option, compute half of the eigenvectors
*           in one call, and half in another
*
            i1 = n / 2
            DO 160 j = 1, i1
               llwork( j ) = .true.
  160       CONTINUE
            DO 170 j = i1 + 1, n
               llwork( j ) = .false.
  170       CONTINUE
*
            CALL ztgevc( 'R', 'S', llwork, n, s1, lda, p1, lda, cdumma,
     $                   ldu, evectr, ldu, n, in, work, rwork, iinfo )
            IF( iinfo.NE.0 ) THEN
               WRITE( nounit, fmt = 9999 )'ZTGEVC(R,S1)', iinfo, n,
     $            jtype, ioldsd
               info = abs( iinfo )
               GO TO 210
            END IF
*
            i1 = in
            DO 180 j = 1, i1
               llwork( j ) = .false.
  180       CONTINUE
            DO 190 j = i1 + 1, n
               llwork( j ) = .true.
  190       CONTINUE
*
            CALL ztgevc( 'R', 'S', llwork, n, s1, lda, p1, lda, cdumma,
     $                   ldu, evectr( 1, i1+1 ), ldu, n, in, work,
     $                   rwork, iinfo )
            IF( iinfo.NE.0 ) THEN
               WRITE( nounit, fmt = 9999 )'ZTGEVC(R,S2)', iinfo, n,
     $            jtype, ioldsd
               info = abs( iinfo )
               GO TO 210
            END IF
*
            CALL zget52( .false., n, s1, lda, p1, lda, evectr, ldu,
     $                   alpha1, beta1, work, rwork, dumma( 1 ) )
            result( 11 ) = dumma( 1 )
            IF( dumma( 2 ).GT.thresh ) THEN
               WRITE( nounit, fmt = 9998 )'Right', 'ZTGEVC(HOWMNY=S)',
     $            dumma( 2 ), n, jtype, ioldsd
            END IF
*
*           12: Compute the right eigenvector Matrix with
*               back transforming:
*
            ntest = 12
            result( 12 ) = ulpinv
            CALL zlacpy( 'F', n, n, z, ldu, evectr, ldu )
            CALL ztgevc( 'R', 'B', llwork, n, s1, lda, p1, lda, cdumma,
     $                   ldu, evectr, ldu, n, in, work, rwork, iinfo )
            IF( iinfo.NE.0 ) THEN
               WRITE( nounit, fmt = 9999 )'ZTGEVC(R,B)', iinfo, n,
     $            jtype, ioldsd
               info = abs( iinfo )
               GO TO 210
            END IF
*
            CALL zget52( .false., n, h, lda, t, lda, evectr, ldu,
     $                   alpha1, beta1, work, rwork, dumma( 1 ) )
            result( 12 ) = dumma( 1 )
            IF( dumma( 2 ).GT.thresh ) THEN
               WRITE( nounit, fmt = 9998 )'Right', 'ZTGEVC(HOWMNY=B)',
     $            dumma( 2 ), n, jtype, ioldsd
            END IF
*
*           Tests 13--15 are done only on request
*
            IF( tstdif ) THEN
*
*              Do Tests 13--14
*
               CALL zget51( 2, n, s1, lda, s2, lda, q, ldu, z, ldu,
     $                      work, rwork, result( 13 ) )
               CALL zget51( 2, n, p1, lda, p2, lda, q, ldu, z, ldu,
     $                      work, rwork, result( 14 ) )
*
*              Do Test 15
*
               temp1 = zero
               temp2 = zero
               DO 200 j = 1, n
                  temp1 = max( temp1, abs( alpha1( j )-alpha3( j ) ) )
                  temp2 = max( temp2, abs( beta1( j )-beta3( j ) ) )
  200          CONTINUE
*
               temp1 = temp1 / max( safmin, ulp*max( temp1, anorm ) )
               temp2 = temp2 / max( safmin, ulp*max( temp2, bnorm ) )
               result( 15 ) = max( temp1, temp2 )
               ntest = 15
            ELSE
               result( 13 ) = zero
               result( 14 ) = zero
               result( 15 ) = zero
               ntest = 12
            END IF
*
*           End of Loop -- Check for RESULT(j) > THRESH
*
  210       CONTINUE
*
            ntestt = ntestt + ntest
*
*           Print out tests which fail.
*
            DO 220 jr = 1, ntest
               IF( result( jr ).GE.thresh ) THEN
*
*                 If this is the first test to fail,
*                 print a header to the data file.
*
                  IF( nerrs.EQ.0 ) THEN
                     WRITE( nounit, fmt = 9997 )'ZGG'
*
*                    Matrix types
*
                     WRITE( nounit, fmt = 9996 )
                     WRITE( nounit, fmt = 9995 )
                     WRITE( nounit, fmt = 9994 )'Unitary'
*
*                    Tests performed
*
                     WRITE( nounit, fmt = 9993 )'unitary', '*',
     $                  'conjugate transpose', ( '*', j = 1, 10 )
*
                  END IF
                  nerrs = nerrs + 1
                  IF( result( jr ).LT.10000.0d0 ) THEN
                     WRITE( nounit, fmt = 9992 )n, jtype, ioldsd, jr,
     $                  result( jr )
                  ELSE
                     WRITE( nounit, fmt = 9991 )n, jtype, ioldsd, jr,
     $                  result( jr )
                  END IF
               END IF
  220       CONTINUE
*
  230    CONTINUE
  240 CONTINUE
*
*     Summary
*
      CALL dlasum( 'ZGG', nounit, nerrs, ntestt )
      RETURN
*
 9999 FORMAT( ' ZCHKGG: ', a, ' returned INFO=', i6, '.', / 9x, 'N=',
     $      i6, ', JTYPE=', i6, ', ISEED=(', 3( i5, ',' ), i5, ')' )
*
 9998 FORMAT( ' ZCHKGG: ', a, ' Eigenvectors from ', a, ' incorrectly ',
     $      'normalized.', / ' Bits of error=', 0p, g10.3, ',', 9x,
     $      'N=', i6, ', JTYPE=', i6, ', ISEED=(', 3( i5, ',' ), i5,
     $      ')' )
*
 9997 FORMAT( 1x, a3, ' -- Complex Generalized eigenvalue problem' )
*
 9996 FORMAT( ' Matrix types (see ZCHKGG for details): ' )
*
 9995 FORMAT( ' Special Matrices:', 23x,
     $      '(J''=transposed Jordan block)',
     $      / '   1=(0,0)  2=(I,0)  3=(0,I)  4=(I,I)  5=(J'',J'')  ',
     $      '6=(diag(J'',I), diag(I,J''))', / ' Diagonal Matrices:  ( ',
     $      'D=diag(0,1,2,...) )', / '   7=(D,I)   9=(large*D, small*I',
     $      ')  11=(large*I, small*D)  13=(large*D, large*I)', /
     $      '   8=(I,D)  10=(small*D, large*I)  12=(small*I, large*D) ',
     $      ' 14=(small*D, small*I)', / '  15=(D, reversed D)' )
 9994 FORMAT( ' Matrices Rotated by Random ', a, ' Matrices U, V:',
     $      / '  16=Transposed Jordan Blocks             19=geometric ',
     $      'alpha, beta=0,1', / '  17=arithm. alpha&beta             ',
     $      '      20=arithmetic alpha, beta=0,1', / '  18=clustered ',
     $      'alpha, beta=0,1            21=random alpha, beta=0,1',
     $      / ' Large & Small Matrices:', / '  22=(large, small)   ',
     $      '23=(small,large)    24=(small,small)    25=(large,large)',
     $      / '  26=random O(1) matrices.' )
*
 9993 FORMAT( / ' Tests performed:   (H is Hessenberg, S is Schur, B, ',
     $      'T, P are triangular,', / 20x, 'U, V, Q, and Z are ', a,
     $      ', l and r are the', / 20x,
     $      'appropriate left and right eigenvectors, resp., a is',
     $      / 20x, 'alpha, b is beta, and ', a, ' means ', a, '.)',
     $      / ' 1 = | A - U H V', a,
     $      ' | / ( |A| n ulp )      2 = | B - U T V', a,
     $      ' | / ( |B| n ulp )', / ' 3 = | I - UU', a,
     $      ' | / ( n ulp )             4 = | I - VV', a,
     $      ' | / ( n ulp )', / ' 5 = | H - Q S Z', a,
     $      ' | / ( |H| n ulp )', 6x, '6 = | T - Q P Z', a,
     $      ' | / ( |T| n ulp )', / ' 7 = | I - QQ', a,
     $      ' | / ( n ulp )             8 = | I - ZZ', a,
     $      ' | / ( n ulp )', / ' 9 = max | ( b S - a P )', a,
     $      ' l | / const.  10 = max | ( b H - a T )', a,
     $      ' l | / const.', /
     $      ' 11= max | ( b S - a P ) r | / const.   12 = max | ( b H',
     $      ' - a T ) r | / const.', / 1x )
*
 9992 FORMAT( ' Matrix order=', i5, ', type=', i2, ', seed=',
     $      4( i4, ',' ), ' result ', i2, ' is', 0p, f8.2 )
 9991 FORMAT( ' Matrix order=', i5, ', type=', i2, ', seed=',
     $      4( i4, ',' ), ' result ', i2, ' is', 1p, d10.3 )
*
*     End of ZCHKGG
*
      END