dorg2r()

subroutine dorg2r	(	integer	m,
		integer	n,
		integer	k,
		double precision, dimension( lda, * )	a,
		integer	lda,
		double precision, dimension( * )	tau,
		double precision, dimension( * )	work,
		integer	info )

DORG2R generates all or part of the orthogonal matrix Q from a QR factorization determined by sgeqrf (unblocked algorithm).

Download DORG2R + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> DORG2R generates an m by n real matrix Q with orthonormal columns,
!> which is defined as the first n columns of a product of k elementary
!> reflectors of order m
!>
!>       Q  =  H(1) H(2) . . . H(k)
!>
!> as returned by DGEQRF.
!> 

Parameters

[in]	M	!> M is INTEGER !> The number of rows of the matrix Q. M >= 0. !>
[in]	N	!> N is INTEGER !> The number of columns of the matrix Q. M >= N >= 0. !>
[in]	K	!> K is INTEGER !> The number of elementary reflectors whose product defines the !> matrix Q. N >= K >= 0. !>
[in,out]	A	!> A is DOUBLE PRECISION array, dimension (LDA,N) !> On entry, the i-th column must contain the vector which !> defines the elementary reflector H(i), for i = 1,2,...,k, as !> returned by DGEQRF in the first k columns of its array !> argument A. !> On exit, the m-by-n matrix Q. !>
[in]	LDA	!> LDA is INTEGER !> The first dimension of the array A. LDA >= max(1,M). !>
[in]	TAU	!> TAU is DOUBLE PRECISION array, dimension (K) !> TAU(i) must contain the scalar factor of the elementary !> reflector H(i), as returned by DGEQRF. !>
[out]	WORK	!> WORK is DOUBLE PRECISION array, dimension (N) !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit !> < 0: if INFO = -i, the i-th argument has an illegal value !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 111 of file dorg2r.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            INFO, K, LDA, M, N
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   A( LDA, * ), TAU( * ), WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ONE, ZERO
      parameter( one = 1.0d+0, zero = 0.0d+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, J, L
*     ..
*     .. External Subroutines ..
      EXTERNAL           dlarf1f, dscal, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max
*     ..
*     .. Executable Statements ..
*
*     Test the input arguments
*
      info = 0
      IF( m.LT.0 ) THEN
         info = -1
      ELSE IF( n.LT.0 .OR. n.GT.m ) THEN
         info = -2
      ELSE IF( k.LT.0 .OR. k.GT.n ) THEN
         info = -3
      ELSE IF( lda.LT.max( 1, m ) ) THEN
         info = -5
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'DORG2R', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.LE.0 )
     $   RETURN
*
*     Initialise columns k+1:n to columns of the unit matrix
*
      DO 20 j = k + 1, n
         DO 10 l = 1, m
            a( l, j ) = zero
   10    CONTINUE
         a( j, j ) = one
   20 CONTINUE
*
      DO 40 i = k, 1, -1
*
*        Apply H(i) to A(i:m,i:n) from the left
*
         IF( i.LT.n ) THEN
            CALL dlarf1f( 'Left', m-i+1, n-i, a( i, i ), 1, tau( i ),
     $                  a( i, i+1 ), lda, work )
         END IF
         IF( i.LT.m )
     $      CALL dscal( m-i, -tau( i ), a( i+1, i ), 1 )
         a( i, i ) = one - tau( i )
*
*        Set A(1:i-1,i) to zero
*
         DO 30 l = 1, i - 1
            a( l, i ) = zero
   30    CONTINUE
   40 CONTINUE
      RETURN
*
*     End of DORG2R
*

Here is the call graph for this function:

Here is the caller graph for this function: