slatzm()

subroutine slatzm	(	character	side,
		integer	m,
		integer	n,
		real, dimension( * )	v,
		integer	incv,
		real	tau,
		real, dimension( ldc, * )	c1,
		real, dimension( ldc, * )	c2,
		integer	ldc,
		real, dimension( * )	work
	)

SLATZM

Download SLATZM + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 This routine is deprecated and has been replaced by routine SORMRZ.

 SLATZM applies a Householder matrix generated by STZRQF to a matrix.

 Let P = I - tau*u*u**T,   u = ( 1 ),
                               ( v )
 where v is an (m-1) vector if SIDE = 'L', or a (n-1) vector if
 SIDE = 'R'.

 If SIDE equals 'L', let
        C = [ C1 ] 1
            [ C2 ] m-1
              n
 Then C is overwritten by P*C.

 If SIDE equals 'R', let
        C = [ C1, C2 ] m
               1  n-1
 Then C is overwritten by C*P.

Parameters

[in]	SIDE	SIDE is CHARACTER*1 = 'L': form P * C = 'R': form C * P
[in]	M	M is INTEGER The number of rows of the matrix C.
[in]	N	N is INTEGER The number of columns of the matrix C.
[in]	V	V is REAL array, dimension (1 + (M-1)*abs(INCV)) if SIDE = 'L' (1 + (N-1)*abs(INCV)) if SIDE = 'R' The vector v in the representation of P. V is not used if TAU = 0.
[in]	INCV	INCV is INTEGER The increment between elements of v. INCV <> 0
[in]	TAU	TAU is REAL The value tau in the representation of P.
[in,out]	C1	C1 is REAL array, dimension (LDC,N) if SIDE = 'L' (M,1) if SIDE = 'R' On entry, the n-vector C1 if SIDE = 'L', or the m-vector C1 if SIDE = 'R'. On exit, the first row of P*C if SIDE = 'L', or the first column of C*P if SIDE = 'R'.
[in,out]	C2	C2 is REAL array, dimension (LDC, N) if SIDE = 'L' (LDC, N-1) if SIDE = 'R' On entry, the (m - 1) x n matrix C2 if SIDE = 'L', or the m x (n - 1) matrix C2 if SIDE = 'R'. On exit, rows 2:m of P*C if SIDE = 'L', or columns 2:m of C*P if SIDE = 'R'.
[in]	LDC	LDC is INTEGER The leading dimension of the arrays C1 and C2. LDC >= (1,M).
[out]	WORK	WORK is REAL array, dimension (N) if SIDE = 'L' (M) if SIDE = 'R'

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 150 of file slatzm.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          SIDE
      INTEGER            INCV, LDC, M, N
      REAL               TAU
*     ..
*     .. Array Arguments ..
      REAL               C1( LDC, * ), C2( LDC, * ), V( * ), WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ONE, ZERO
      parameter( one = 1.0e+0, zero = 0.0e+0 )
*     ..
*     .. External Subroutines ..
      EXTERNAL           saxpy, scopy, sgemv, sger
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      EXTERNAL           lsame
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          min
*     ..
*     .. Executable Statements ..
*
      IF( ( min( m, n ).EQ.0 ) .OR. ( tau.EQ.zero ) )
     $   RETURN
*
      IF( lsame( side, 'L' ) ) THEN
*
*        w :=  (C1 + v**T * C2)**T
*
         CALL scopy( n, c1, ldc, work, 1 )
         CALL sgemv( 'Transpose', m-1, n, one, c2, ldc, v, incv, one,
     $               work, 1 )
*
*        [ C1 ] := [ C1 ] - tau* [ 1 ] * w**T
*        [ C2 ]    [ C2 ]        [ v ]
*
         CALL saxpy( n, -tau, work, 1, c1, ldc )
         CALL sger( m-1, n, -tau, v, incv, work, 1, c2, ldc )
*
      ELSE IF( lsame( side, 'R' ) ) THEN
*
*        w := C1 + C2 * v
*
         CALL scopy( m, c1, 1, work, 1 )
         CALL sgemv( 'No transpose', m, n-1, one, c2, ldc, v, incv, one,
     $               work, 1 )
*
*        [ C1, C2 ] := [ C1, C2 ] - tau* w * [ 1 , v**T]
*
         CALL saxpy( m, -tau, work, 1, c1, 1 )
         CALL sger( m, n-1, -tau, work, 1, v, incv, c2, ldc )
      END IF
*
      RETURN
*
*     End of SLATZM
*

Here is the call graph for this function:

Here is the caller graph for this function: