cqrt13.f

Go to the documentation of this file.

*> \brief \b CQRT13
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*  Definition:
*  ===========
*
*       SUBROUTINE CQRT13( SCALE, M, N, A, LDA, NORMA, ISEED )
*
*       .. Scalar Arguments ..
*       INTEGER            LDA, M, N, SCALE
*       REAL               NORMA
*       ..
*       .. Array Arguments ..
*       INTEGER            ISEED( 4 )
*       COMPLEX            A( LDA, * )
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> CQRT13 generates a full-rank matrix that may be scaled to have large
*> or small norm.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] SCALE
*> \verbatim
*>          SCALE is INTEGER
*>          SCALE = 1: normally scaled matrix
*>          SCALE = 2: matrix scaled up
*>          SCALE = 3: matrix scaled down
*> \endverbatim
*>
*> \param[in] M
*> \verbatim
*>          M is INTEGER
*>          The number of rows of the matrix A.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The number of columns of A.
*> \endverbatim
*>
*> \param[out] A
*> \verbatim
*>          A is COMPLEX array, dimension (LDA,N)
*>          The M-by-N matrix A.
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>          The leading dimension of the array A.
*> \endverbatim
*>
*> \param[out] NORMA
*> \verbatim
*>          NORMA is REAL
*>          The one-norm of A.
*> \endverbatim
*>
*> \param[in,out] ISEED
*> \verbatim
*>          ISEED is integer array, dimension (4)
*>          Seed for random number generator
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \ingroup complex_lin
*
*  =====================================================================
      SUBROUTINE cqrt13( SCALE, M, N, A, LDA, NORMA, ISEED )
*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            LDA, M, N, SCALE
      REAL               NORMA
*     ..
*     .. Array Arguments ..
      INTEGER            ISEED( 4 )
      COMPLEX            A( LDA, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ONE
      parameter( one = 1.0e0 )
*     ..
*     .. Local Scalars ..
      INTEGER            INFO, J
      REAL               BIGNUM, SMLNUM
*     ..
*     .. External Functions ..
      REAL               CLANGE, SCASUM, SLAMCH
      EXTERNAL           clange, scasum, slamch
*     ..
*     .. External Subroutines ..
      EXTERNAL           clarnv, clascl, slabad
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          cmplx, real, sign
*     ..
*     .. Local Arrays ..
      REAL               DUMMY( 1 )
*     ..
*     .. Executable Statements ..
*
      IF( m.LE.0 .OR. n.LE.0 )
     $   RETURN
*
*     benign matrix
*
      DO 10 j = 1, n
         CALL clarnv( 2, iseed, m, a( 1, j ) )
         IF( j.LE.m ) THEN
            a( j, j ) = a( j, j ) + cmplx( sign( scasum( m, a( 1, j ),
     $                  1 ), real( a( j, j ) ) ) )
         END IF
   10 CONTINUE
*
*     scaled versions
*
      IF( scale.NE.1 ) THEN
         norma = clange( 'Max', m, n, a, lda, dummy )
         smlnum = slamch( 'Safe minimum' )
         bignum = one / smlnum
         CALL slabad( smlnum, bignum )
         smlnum = smlnum / slamch( 'Epsilon' )
         bignum = one / smlnum
*
         IF( scale.EQ.2 ) THEN
*
*           matrix scaled up
*
            CALL clascl( 'General', 0, 0, norma, bignum, m, n, a, lda,
     $                   info )
         ELSE IF( scale.EQ.3 ) THEN
*
*           matrix scaled down
*
            CALL clascl( 'General', 0, 0, norma, smlnum, m, n, a, lda,
     $                   info )
         END IF
      END IF
*
      norma = clange( 'One-norm', m, n, a, lda, dummy )
      RETURN
*
*     End of CQRT13
*
      END