sort01()

subroutine sort01	(	character	rowcol,
		integer	m,
		integer	n,
		real, dimension( ldu, * )	u,
		integer	ldu,
		real, dimension( * )	work,
		integer	lwork,
		real	resid
	)

SORT01

Purpose:

 SORT01 checks that the matrix U is orthogonal by computing the ratio

    RESID = norm( I - U*U' ) / ( n * EPS ), if ROWCOL = 'R',
 or
    RESID = norm( I - U'*U ) / ( m * EPS ), if ROWCOL = 'C'.

 Alternatively, if there isn't sufficient workspace to form
 I - U*U' or I - U'*U, the ratio is computed as

    RESID = abs( I - U*U' ) / ( n * EPS ), if ROWCOL = 'R',
 or
    RESID = abs( I - U'*U ) / ( m * EPS ), if ROWCOL = 'C'.

 where EPS is the machine precision.  ROWCOL is used only if m = n;
 if m > n, ROWCOL is assumed to be 'C', and if m < n, ROWCOL is
 assumed to be 'R'.

Parameters

[in]	ROWCOL	ROWCOL is CHARACTER Specifies whether the rows or columns of U should be checked for orthogonality. Used only if M = N. = 'R': Check for orthogonal rows of U = 'C': Check for orthogonal columns of U
[in]	M	M is INTEGER The number of rows of the matrix U.
[in]	N	N is INTEGER The number of columns of the matrix U.
[in]	U	U is REAL array, dimension (LDU,N) The orthogonal matrix U. U is checked for orthogonal columns if m > n or if m = n and ROWCOL = 'C'. U is checked for orthogonal rows if m < n or if m = n and ROWCOL = 'R'.
[in]	LDU	LDU is INTEGER The leading dimension of the array U. LDU >= max(1,M).
[out]	WORK	WORK is REAL array, dimension (LWORK)
[in]	LWORK	LWORK is INTEGER The length of the array WORK. For best performance, LWORK should be at least N*(N+1) if ROWCOL = 'C' or M*(M+1) if ROWCOL = 'R', but the test will be done even if LWORK is 0.
[out]	RESID	RESID is REAL RESID = norm( I - U * U' ) / ( n * EPS ), if ROWCOL = 'R', or RESID = norm( I - U' * U ) / ( m * EPS ), if ROWCOL = 'C'.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 115 of file sort01.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          ROWCOL
      INTEGER            LDU, LWORK, M, N
      REAL               RESID
*     ..
*     .. Array Arguments ..
      REAL               U( LDU, * ), WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ZERO, ONE
      parameter( zero = 0.0e+0, one = 1.0e+0 )
*     ..
*     .. Local Scalars ..
      CHARACTER          TRANSU
      INTEGER            I, J, K, LDWORK, MNMIN
      REAL               EPS, TMP
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      REAL               SDOT, SLAMCH, SLANSY
      EXTERNAL           lsame, sdot, slamch, slansy
*     ..
*     .. External Subroutines ..
      EXTERNAL           slaset, ssyrk
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min, real
*     ..
*     .. Executable Statements ..
*
      resid = zero
*
*     Quick return if possible
*
      IF( m.LE.0 .OR. n.LE.0 )
     $   RETURN
*
      eps = slamch( 'Precision' )
      IF( m.LT.n .OR. ( m.EQ.n .AND. lsame( rowcol, 'R' ) ) ) THEN
         transu = 'N'
         k = n
      ELSE
         transu = 'T'
         k = m
      END IF
      mnmin = min( m, n )
*
      IF( ( mnmin+1 )*mnmin.LE.lwork ) THEN
         ldwork = mnmin
      ELSE
         ldwork = 0
      END IF
      IF( ldwork.GT.0 ) THEN
*
*        Compute I - U*U' or I - U'*U.
*
         CALL slaset( 'Upper', mnmin, mnmin, zero, one, work, ldwork )
         CALL ssyrk( 'Upper', transu, mnmin, k, -one, u, ldu, one, work,
     $               ldwork )
*
*        Compute norm( I - U*U' ) / ( K * EPS ) .
*
         resid = slansy( '1', 'Upper', mnmin, work, ldwork,
     $           work( ldwork*mnmin+1 ) )
         resid = ( resid / real( k ) ) / eps
      ELSE IF( transu.EQ.'T' ) THEN
*
*        Find the maximum element in abs( I - U'*U ) / ( m * EPS )
*
         DO 20 j = 1, n
            DO 10 i = 1, j
               IF( i.NE.j ) THEN
                  tmp = zero
               ELSE
                  tmp = one
               END IF
               tmp = tmp - sdot( m, u( 1, i ), 1, u( 1, j ), 1 )
               resid = max( resid, abs( tmp ) )
   10       CONTINUE
   20    CONTINUE
         resid = ( resid / real( m ) ) / eps
      ELSE
*
*        Find the maximum element in abs( I - U*U' ) / ( n * EPS )
*
         DO 40 j = 1, m
            DO 30 i = 1, j
               IF( i.NE.j ) THEN
                  tmp = zero
               ELSE
                  tmp = one
               END IF
               tmp = tmp - sdot( n, u( j, 1 ), ldu, u( i, 1 ), ldu )
               resid = max( resid, abs( tmp ) )
   30       CONTINUE
   40    CONTINUE
         resid = ( resid / real( n ) ) / eps
      END IF
      RETURN
*
*     End of SORT01
*

Here is the call graph for this function:

Here is the caller graph for this function: