sqrt04.f

Go to the documentation of this file.

*> \brief \b SQRT04
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*  Definition:
*  ===========
*
*       SUBROUTINE SQRT04(M,N,NB,RESULT)
*
*       .. Scalar Arguments ..
*       INTEGER M, N, NB, LDT
*       .. Return values ..
*       REAL RESULT(6)
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> SQRT04 tests SGEQRT and SGEMQRT.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] M
*> \verbatim
*>          M is INTEGER
*>          Number of rows in test matrix.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          Number of columns in test matrix.
*> \endverbatim
*>
*> \param[in] NB
*> \verbatim
*>          NB is INTEGER
*>          Block size of test matrix.  NB <= Min(M,N).
*> \endverbatim
*>
*> \param[out] RESULT
*> \verbatim
*>          RESULT is REAL array, dimension (6)
*>          Results of each of the six tests below.
*>
*>          RESULT(1) = | A - Q R |
*>          RESULT(2) = | I - Q^H Q |
*>          RESULT(3) = | Q C - Q C |
*>          RESULT(4) = | Q^H C - Q^H C |
*>          RESULT(5) = | C Q - C Q |
*>          RESULT(6) = | C Q^H - C Q^H |
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \ingroup single_lin
*
*  =====================================================================
      SUBROUTINE sqrt04(M,N,NB,RESULT)
      IMPLICIT NONE
*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER M, N, NB, LDT
*     .. Return values ..
      REAL RESULT(6)
*
*  =====================================================================
*
*     ..
*     .. Local allocatable arrays
      REAL, ALLOCATABLE :: AF(:,:), Q(:,:),
     $  R(:,:), RWORK(:), WORK( : ), T(:,:),
     $  CF(:,:), DF(:,:), A(:,:), C(:,:), D(:,:)
*
*     .. Parameters ..
      REAL ONE, ZERO
      parameter( zero = 0.0, one = 1.0 )
*     ..
*     .. Local Scalars ..
      INTEGER INFO, J, K, L, LWORK
      REAL   ANORM, EPS, RESID, CNORM, DNORM
*     ..
*     .. Local Arrays ..
      INTEGER            ISEED( 4 )
*     ..
*     .. External Subroutine ..
      EXTERNAL sgemm, slacpy, slarnv, sgemqrt, slaset, sgeqrt, ssyrk
*     ..
*     .. External Functions ..
      REAL SLAMCH
      REAL SLANGE, SLANSY
      LOGICAL  LSAME
      EXTERNAL slamch, slange, slansy, lsame
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC  max, min
*     ..
*     .. Data statements ..
      DATA iseed / 1988, 1989, 1990, 1991 /
*
      eps = slamch( 'Epsilon' )
      k = min(m,n)
      l = max(m,n)
      lwork = max(2,l)*max(2,l)*nb
*
*     Dynamically allocate local arrays
*
      ALLOCATE ( a(m,n), af(m,n), q(m,m), r(m,l), rwork(l),
     $           work(lwork), t(nb,n), c(m,n), cf(m,n),
     $           d(n,m), df(n,m) )
*
*     Put random numbers into A and copy to AF
*
      ldt=nb
      DO j=1,n
         CALL slarnv( 2, iseed, m, a( 1, j ) )
      END DO
      CALL slacpy( 'Full', m, n, a, m, af, m )
*
*     Factor the matrix A in the array AF.
*
      CALL sgeqrt( m, n, nb, af, m, t, ldt, work, info )
*
*     Generate the m-by-m matrix Q
*
      CALL slaset( 'Full', m, m, zero, one, q, m )
      CALL sgemqrt( 'R', 'N', m, m, k, nb, af, m, t, ldt, q, m,
     $              work, info )
*
*     Copy R
*
      CALL slaset( 'Full', m, n, zero, zero, r, m )
      CALL slacpy( 'Upper', m, n, af, m, r, m )
*
*     Compute |R - Q'*A| / |A| and store in RESULT(1)
*
      CALL sgemm( 'T', 'N', m, n, m, -one, q, m, a, m, one, r, m )
      anorm = slange( '1', m, n, a, m, rwork )
      resid = slange( '1', m, n, r, m, rwork )
      IF( anorm.GT.zero ) THEN
         result( 1 ) = resid / (eps*max(1,m)*anorm)
      ELSE
         result( 1 ) = zero
      END IF
*
*     Compute |I - Q'*Q| and store in RESULT(2)
*
      CALL slaset( 'Full', m, m, zero, one, r, m )
      CALL ssyrk( 'U', 'C', m, m, -one, q, m, one, r, m )
      resid = slansy( '1', 'Upper', m, r, m, rwork )
      result( 2 ) = resid / (eps*max(1,m))
*
*     Generate random m-by-n matrix C and a copy CF
*
      DO j=1,n
         CALL slarnv( 2, iseed, m, c( 1, j ) )
      END DO
      cnorm = slange( '1', m, n, c, m, rwork)
      CALL slacpy( 'Full', m, n, c, m, cf, m )
*
*     Apply Q to C as Q*C
*
      CALL sgemqrt( 'L', 'N', m, n, k, nb, af, m, t, nb, cf, m,
     $             work, info)
*
*     Compute |Q*C - Q*C| / |C|
*
      CALL sgemm( 'N', 'N', m, n, m, -one, q, m, c, m, one, cf, m )
      resid = slange( '1', m, n, cf, m, rwork )
      IF( cnorm.GT.zero ) THEN
         result( 3 ) = resid / (eps*max(1,m)*cnorm)
      ELSE
         result( 3 ) = zero
      END IF
*
*     Copy C into CF again
*
      CALL slacpy( 'Full', m, n, c, m, cf, m )
*
*     Apply Q to C as QT*C
*
      CALL sgemqrt( 'L', 'T', m, n, k, nb, af, m, t, nb, cf, m,
     $             work, info)
*
*     Compute |QT*C - QT*C| / |C|
*
      CALL sgemm( 'T', 'N', m, n, m, -one, q, m, c, m, one, cf, m )
      resid = slange( '1', m, n, cf, m, rwork )
      IF( cnorm.GT.zero ) THEN
         result( 4 ) = resid / (eps*max(1,m)*cnorm)
      ELSE
         result( 4 ) = zero
      END IF
*
*     Generate random n-by-m matrix D and a copy DF
*
      DO j=1,m
         CALL slarnv( 2, iseed, n, d( 1, j ) )
      END DO
      dnorm = slange( '1', n, m, d, n, rwork)
      CALL slacpy( 'Full', n, m, d, n, df, n )
*
*     Apply Q to D as D*Q
*
      CALL sgemqrt( 'R', 'N', n, m, k, nb, af, m, t, nb, df, n,
     $             work, info)
*
*     Compute |D*Q - D*Q| / |D|
*
      CALL sgemm( 'N', 'N', n, m, m, -one, d, n, q, m, one, df, n )
      resid = slange( '1', n, m, df, n, rwork )
      IF( cnorm.GT.zero ) THEN
         result( 5 ) = resid / (eps*max(1,m)*dnorm)
      ELSE
         result( 5 ) = zero
      END IF
*
*     Copy D into DF again
*
      CALL slacpy( 'Full', n, m, d, n, df, n )
*
*     Apply Q to D as D*QT
*
      CALL sgemqrt( 'R', 'T', n, m, k, nb, af, m, t, nb, df, n,
     $             work, info)
*
*     Compute |D*QT - D*QT| / |D|
*
      CALL sgemm( 'N', 'T', n, m, m, -one, d, n, q, m, one, df, n )
      resid = slange( '1', n, m, df, n, rwork )
      IF( cnorm.GT.zero ) THEN
         result( 6 ) = resid / (eps*max(1,m)*dnorm)
      ELSE
         result( 6 ) = zero
      END IF
*
*     Deallocate all arrays
*
      DEALLOCATE ( a, af, q, r, rwork, work, t, c, d, cf, df)
*
      RETURN
      END